Merge 'trunk' into 'better_scripts'

diff --git a/Makefile.PL b/Makefile.PL

index 6fae99a..1bede30 100644 (file)
--- a/Makefile.PL
+++ b/Makefile.PL
@@ -16,6 +16,7 @@ all_from 'lib/Catalyst/Runtime.pm';
 requires 'List::MoreUtils';
 requires 'namespace::autoclean';
 requires 'namespace::clean';
+requires 'namespace::autoclean';
 requires 'B::Hooks::EndOfScope' => '0.08';
 requires 'MooseX::Emulate::Class::Accessor::Fast' => '0.00801';
 requires 'Class::MOP' => '0.83';
@@ -44,10 +45,10 @@ requires 'URI' => '1.35';
 requires 'Task::Weaken';
 requires 'Text::Balanced'; # core in 5.8.x but mentioned for completeness
 requires 'MRO::Compat';
+requires 'MooseX::Getopt';
+requires 'MooseX::Types';
 requires 'String::RewritePrefix' => '0.004'; # Catalyst::Utils::resolve_namespace
 
-recommends 'B::Hooks::OP::Check::StashChange';
-
 test_requires 'Class::Data::Inheritable';
 test_requires 'Test::Exception';
 
diff --git a/TODO.scripts b/TODO.scripts

new file mode 100644 (file)

index 0000000..f6a69c0
--- /dev/null
+++ b/TODO.scripts
@@ -0,0 +1,6 @@
+* Fix the fucking help to be consistent again!
+* Documentation
+* Proper test of all the options on all the scripts
+* ScriptRunner tests for MyApp::Script::DoesNotCompile
+
+* Tests for Scripts / Role
diff --git a/lib/Catalyst.pm b/lib/Catalyst.pm

index f616ba8..56f0f93 100644 (file)
--- a/lib/Catalyst.pm
+++ b/lib/Catalyst.pm
@@ -2786,6 +2786,8 @@ David Naughton, C<naughton@umn.edu>
 
 David E. Wheeler
 
+dhoss: Devin Austin <dhoss@cpan.org>
+
 dkubb: Dan Kubb <dan.kubb-cpan@onautopilot.com>
 
 Drew Taylor
diff --git a/lib/Catalyst/ROADMAP.pod b/lib/Catalyst/ROADMAP.pod

index e872e5e..9c29d1d 100644 (file)
--- a/lib/Catalyst/ROADMAP.pod
+++ b/lib/Catalyst/ROADMAP.pod
@@ -8,11 +8,6 @@ in the the catalyst trunk, currently at
 
 Make sure you get it from there to ensure you have the latest version.
 
-=head2 5.80000 1st Quarter 2009
-
-Next major planned release, ports Catalyst to Moose, and does some refactoring
-to help app/ctx.
-
 =head2 5.81000 
 
 =over
diff --git a/lib/Catalyst/Script/CGI.pm b/lib/Catalyst/Script/CGI.pm

new file mode 100644 (file)

index 0000000..c37dfdc
--- /dev/null
+++ b/lib/Catalyst/Script/CGI.pm
@@ -0,0 +1,31 @@
+package Catalyst::Script::CGI;
+use Moose;
+BEGIN { $ENV{CATALYST_ENGINE} ||= 'CGI' }
+use namespace::autoclean;
+
+with 'Catalyst::ScriptRole';
+
+__PACKAGE__->meta->make_immutable;
+
+=head1 NAME
+
+Catalyst::Script::CGI - The CGI Catalyst Script
+
+=head1 SYNOPSIS
+
+See L<Catalyst>.
+
+=head1 DESCRIPTION
+
+This is a script to run the Catalyst engine specialized for the CGI environment.
+
+=head1 AUTHORS
+
+Catalyst Contributors, see Catalyst.pm
+
+=head1 COPYRIGHT
+
+This library is free software. You can redistribute it and/or modify it under
+the same terms as Perl itself.
+
+=cut
diff --git a/lib/Catalyst/Script/Create.pm b/lib/Catalyst/Script/Create.pm

new file mode 100644 (file)

index 0000000..575f9e7
--- /dev/null
+++ b/lib/Catalyst/Script/Create.pm
@@ -0,0 +1,94 @@
+package Catalyst::Script::Create;
+use Moose;
+use Catalyst::Helper;
+use MooseX::Types::Moose qw/Bool/;
+use namespace::autoclean;
+
+with 'Catalyst::ScriptRole';
+
+has force => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'nonew',
+    isa => Bool,
+    is => 'ro',
+    documentation => 'Force new scripts',
+);
+
+has debug => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'd',
+    isa => Bool,
+    is => 'ro',
+    documentation => 'Force debug mode',
+);
+
+has mechanize => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'mech',
+    isa => Bool,
+    is => 'ro',
+    documentation => 'use WWW::Mechanize',
+);
+
+sub run {
+    my ($self) = @_;
+
+    $self->_display_help if ( !$ARGV[0] );
+
+    my $helper = Catalyst::Helper->new( { '.newfiles' => !$self->force, mech => $self->mech } );
+
+    $self->_display_help unless $helper->mk_component( $self->app, @ARGV );
+
+}
+
+__PACKAGE__->meta->make_immutable;
+1;
+
+=head1 NAME
+
+Catalyst::Script::Create - Create a new Catalyst Component
+
+=head1 SYNOPSIS
+
+ myapp_create.pl [options] model|view|controller name [helper] [options]
+
+ Options:
+   -force        don't create a .new file where a file to be created exists
+   -mechanize    use Test::WWW::Mechanize::Catalyst for tests if available
+   -help         display this help and exits
+
+ Examples:
+   myapp_create.pl controller My::Controller
+   myapp_create.pl controller My::Controller BindLex
+   myapp_create.pl -mechanize controller My::Controller
+   myapp_create.pl view My::View
+   myapp_create.pl view MyView TT
+   myapp_create.pl view TT TT
+   myapp_create.pl model My::Model
+   myapp_create.pl model SomeDB DBIC::Schema MyApp::Schema create=dynamic\
+   dbi:SQLite:/tmp/my.db
+   myapp_create.pl model AnotherDB DBIC::Schema MyApp::Schema create=static\
+   dbi:Pg:dbname=foo root 4321
+
+ See also:
+   perldoc Catalyst::Manual
+   perldoc Catalyst::Manual::Intro
+
+=head1 DESCRIPTION
+
+Create a new Catalyst Component.
+
+Existing component files are not overwritten.  If any of the component files
+to be created already exist the file will be written with a '.new' suffix.
+This behavior can be suppressed with the C<-force> option.
+
+=head1 AUTHORS
+
+Catalyst Contributors, see Catalyst.pm
+
+=head1 COPYRIGHT
+
+This library is free software, you can redistribute it and/or modify
+it under the same terms as Perl itself.
+
+=cut
diff --git a/lib/Catalyst/Script/FastCGI.pm b/lib/Catalyst/Script/FastCGI.pm

new file mode 100644 (file)

index 0000000..edfcea0
--- /dev/null
+++ b/lib/Catalyst/Script/FastCGI.pm
@@ -0,0 +1,103 @@
+package Catalyst::Script::FastCGI;
+
+BEGIN { $ENV{CATALYST_ENGINE} ||= 'FastCGI' }
+use Moose;
+use MooseX::Types::Moose qw/Str Bool Int/;
+use namespace::autoclean;
+
+with 'Catalyst::ScriptRole';
+
+has listen => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'l',
+    isa => Int,
+    is => 'ro',
+    documentation => 'Specify a listening port/socket',
+);
+
+has pidfile => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'pid',
+    isa => Str,
+    is => 'ro',
+    documentation => 'Specify a pidfile',
+);
+
+has daemon => (
+    traits => [qw(Getopt)],
+    isa => Bool,   
+    is => 'ro', 
+    cmd_aliases => 'd', 
+    documentation => 'Daemonize',
+);
+
+has manager => (
+    traits => [qw(Getopt)],
+    isa => Str,    
+    is => 'ro',
+    cmd_aliases => 'm',
+    documentation => 'Use a different FastCGI manager', # FIXME
+);
+
+has keep_stderr => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'std', 
+    isa => Bool,   
+    is => 'ro',  
+    documentation => 'Log STDERR',
+);
+
+has nproc => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'np',  
+    isa => Int,
+    is => 'ro',  
+    documentation => 'Specify an nproc', # FIXME
+);
+
+has detach => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'det', 
+    isa => Bool,   
+    is => 'ro',  
+    documentation => 'Detach this FastCGI process',
+);
+
+sub _application_args {
+    my ($self) = shift;
+    return (
+        $self->listen,
+        {
+            nproc   => $self->nproc,
+            pidfile => $self->pidfile,
+            manager => $self->manager,
+            detach  => $self->detach,
+            keep_stderr => $self->keep_stderr,
+        }
+    );
+}
+
+__PACKAGE__->meta->make_immutable;
+
+=head1 NAME
+
+Catalyst::Script::FastCGI - The FastCGI Catalyst Script
+
+=head1 SYNOPSIS
+
+See L<Catalyst>.
+
+=head1 DESCRIPTION
+
+FIXME
+
+=head1 AUTHORS
+
+Catalyst Contributors, see Catalyst.pm
+
+=head1 COPYRIGHT
+
+This library is free software. You can redistribute it and/or modify it under
+the same terms as Perl itself.
+
+=cut
diff --git a/lib/Catalyst/Script/Server.pm b/lib/Catalyst/Script/Server.pm

new file mode 100644 (file)

index 0000000..1c3cf99
--- /dev/null
+++ b/lib/Catalyst/Script/Server.pm
@@ -0,0 +1,236 @@
+package Catalyst::Script::Server;
+
+BEGIN {
+    $ENV{CATALYST_ENGINE} ||= 'HTTP';
+    require Catalyst::Engine::HTTP;
+}
+
+use Moose;
+use Catalyst::Restarter;
+use MooseX::Types::Moose qw/ArrayRef Str Bool Int/;
+use namespace::autoclean;
+
+with 'Catalyst::ScriptRole';
+
+has debug => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'd',
+    isa => Bool,
+    is => 'ro',
+    documentation => q{Force debug mode},
+);
+
+has host => (
+    traits => [qw(Getopt)],
+    isa => Str,
+    is => 'ro',
+    default => 'localhost',
+    documentation => 'Specify a host for the server to run on',
+);
+
+has fork => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'f',
+    isa => Bool,
+    is => 'ro',
+    documentation => 'Fork the server',
+);
+
+has listen => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'l',
+    isa => Int,
+    is => 'ro',
+    default => 3000,
+    documentation => 'Specify a different listening port',
+);
+
+has pidfile => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'pid',
+    isa => Str,
+    is => 'ro',
+    documentation => 'Specify a pidfile',
+);
+
+has keepalive => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'k',
+    isa => Bool,
+    is => 'ro',
+    documentation => 'Server keepalive',
+
+);
+
+has background => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'bg',
+    isa => Bool,
+    is => 'ro',
+    documentation => 'Run in the background',
+);
+
+has restart => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'r',
+    isa => Bool,
+    is => 'ro',
+    documentation => 'use Catalyst::Restarter to detect code changes',
+);
+
+has restart_directory => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'rdir',
+    isa => ArrayRef[Str],
+    is  => 'ro',
+    predicate => '_has_restart_directory',
+    documentation => 'Restarter directory to watch',
+);
+
+has restart_delay => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'rdel',
+    isa => Int,
+    is => 'ro',
+    predicate => '_has_restart_delay',
+    documentation => 'Set a restart delay',
+);
+
+has restart_regex => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'rxp',
+    isa => Str,
+    is => 'ro',
+    predicate => '_has_restart_regex',
+    documentation => 'Restart regex',
+);
+
+has follow_symlinks => (
+    traits => [qw(Getopt)],
+    cmd_aliases => 'sym',
+    isa => Bool,
+    is => 'ro',
+    predicate => '_has_follow_symlinks',
+    documentation => 'Follow symbolic links',
+
+);
+
+sub run {
+    my ($self) = shift;
+
+    if ( $self->debug ) {
+        $ENV{CATALYST_DEBUG} = 1;
+    }
+
+    # If we load this here, then in the case of a restarter, it does not
+    # need to be reloaded for each restart.
+    require Catalyst;
+
+    # If this isn't done, then the Catalyst::Devel tests for the restarter
+    # fail.
+    $| = 1 if $ENV{HARNESS_ACTIVE};
+
+    if ( $self->restart ) {
+        die "Cannot run in the background and also watch for changed files.\n"
+            if $self->background;
+
+        require Catalyst::Restarter;
+
+        my $subclass = Catalyst::Restarter->pick_subclass;
+
+        my %args;
+        $args{follow_symlinks} = $self->follow_symlinks
+            if $self->_has_follow_symlinks;
+        $args{directories}     = $self->restart_directory
+            if $self->_has_restart_directory;
+        $args{sleep_interval}  = $self->restart_delay
+            if $self->_has_restart_delay;
+        $args{filter} = qr/$self->restart_regex/
+            if $self->_has_restart_regex;
+
+        my $restarter = $subclass->new(
+            %args,
+            start_sub => sub { $self->_run },
+            argv      => \$self->ARGV,
+        );
+
+        $restarter->run_and_watch;
+    }
+    else {
+        $self->_run_application;
+    }
+
+
+}
+
+sub _application_args {
+    my ($self) = shift;
+    return (
+        $self->listen,
+        $self->host,
+        {
+           map { $_ => $self->$_ } qw/
+                fork
+                keepalive
+                background
+                pidfile
+                keepalive
+                follow_symlinks
+            /,
+        },
+    );
+}
+
+__PACKAGE__->meta->make_immutable;
+
+1;
+
+=head1 NAME
+
+Catalyst::Script::Server - Catalyst test server
+
+=head1 SYNOPSIS
+
+ myapp_server.pl [options]
+
+ Options:
+   -d     --debug          force debug mode
+   -f     --fork           handle each request in a new process
+                      (defaults to false)
+   -h     --help           display this help and exits
+          --host           host (defaults to all)
+   -p     --port           port (defaults to 3000)
+   -k     --keepalive      enable keep-alive connections
+   -r     --restart        restart when files get modified
+                       (defaults to false)
+   --rd   --restartdelay  delay between file checks
+                      (ignored if you have Linux::Inotify2 installed)
+   --rr   --restartregex  regex match files that trigger
+                      a restart when modified
+                      (defaults to '\.yml$|\.yaml$|\.conf|\.pm$')
+   --rdir --restartdirectory  the directory to search for
+                      modified files, can be set mulitple times
+                      (defaults to '[SCRIPT_DIR]/..')
+   --sym  --follow_symlinks   follow symlinks in search directories
+                      (defaults to false. this is a no-op on Win32)
+   --bg   --background        run the process in the background
+   --pid  --pidfile           specify filename for pid file
+
+ See also:
+   perldoc Catalyst::Manual
+   perldoc Catalyst::Manual::Intro
+
+=head1 DESCRIPTION
+
+Run a Catalyst test server for this application.
+
+=head1 AUTHORS
+
+Catalyst Contributors, see Catalyst.pm
+
+=head1 COPYRIGHT
+
+This library is free software. You can redistribute it and/or modify
+it under the same terms as Perl itself.
+
+=cut
diff --git a/lib/Catalyst/Script/Test.pm b/lib/Catalyst/Script/Test.pm

new file mode 100644 (file)

index 0000000..f3da4e1
--- /dev/null
+++ b/lib/Catalyst/Script/Test.pm
@@ -0,0 +1,41 @@
+package Catalyst::Script::Test;
+use Moose;
+use namespace::autoclean;
+
+with 'Catalyst::ScriptRole';
+
+sub run {
+    my $self = shift;
+
+    Class::MOP::load_class("Catalyst::Test");
+    Catalyst::Test->import($self->app);
+
+    print request($ARGV[1])->content  . "\n";
+
+}
+
+
+__PACKAGE__->meta->make_immutable;
+
+=head1 NAME
+
+Catalyst::Script::Test - Test Catalyst application on the command line
+
+=head1 SYNOPSIS
+
+See L<Catalyst>.
+
+=head1 DESCRIPTION
+
+FIXME
+
+=head1 AUTHORS
+
+Catalyst Contributors, see Catalyst.pm
+
+=head1 COPYRIGHT
+
+This library is free software. You can redistribute it and/or modify it under
+the same terms as Perl itself.
+
+=cut
diff --git a/lib/Catalyst/ScriptRole.pm b/lib/Catalyst/ScriptRole.pm

new file mode 100644 (file)

index 0000000..aa319f3
--- /dev/null
+++ b/lib/Catalyst/ScriptRole.pm
@@ -0,0 +1,75 @@
+package Catalyst::ScriptRole;
+use Moose::Role;
+use MooseX::Types::Moose qw/Str Bool/;
+use Pod::Usage;
+use namespace::autoclean;
+
+with 'MooseX::Getopt';
+
+has application_name => (
+    traits => ['NoGetopt'],
+    isa => Str,
+    is => 'ro',
+    required => 1,
+);
+
+has help => (
+    traits => ['Getopt'],
+    cmd_aliases => 'h',
+    isa => Bool,
+    is => 'ro',
+    documentation => q{Display this help and exit},
+);
+
+sub _display_help {
+    my $self = shift;
+    pod2usage();
+    exit 0;
+}
+
+before run => sub {
+    my $self = shift;
+    $self->_display_help if $self->help;
+};
+
+sub run {
+    my $self = shift;
+    $self->_run_application;
+}
+
+sub _application_args {
+    ()
+}
+
+sub _run_application {
+    my $self = shift;
+    my $app = $self->application_name;
+    Class::MOP::load_class($app);
+    $app->run($self->_application_args);
+}
+
+1;
+
+=head1 NAME
+
+Catalyst::ScriptRole - Common functionality for Catalyst scripts.
+
+=head1 SYNOPSIS
+
+    FIXME
+    
+=head1 DESCRIPTION
+
+    FIXME    
+
+=head1 AUTHORS
+
+Catalyst Contributors, see Catalyst.pm
+
+=head1 COPYRIGHT
+
+This library is free software, you can redistribute it and/or modify
+it under the same terms as Perl itself.
+
+=cut
+    
\ No newline at end of file
diff --git a/lib/Catalyst/ScriptRunner.pm b/lib/Catalyst/ScriptRunner.pm

new file mode 100644 (file)

index 0000000..08fd66e
--- /dev/null
+++ b/lib/Catalyst/ScriptRunner.pm
@@ -0,0 +1,50 @@
+package Catalyst::ScriptRunner;
+use Moose;
+use FindBin;
+use lib;
+use File::Spec;
+use namespace::autoclean;
+
+sub run {
+    my ($self, $class, $scriptclass) = @_;
+    my $classtoload = "${class}::Script::$scriptclass";
+
+    lib->import(File::Spec->catdir($FindBin::Bin, '..', 'lib'));
+
+    # FIXME - Error handling / reporting
+    if ( eval { Class::MOP::load_class($classtoload) } ) {
+    }
+    else {
+        $classtoload = "Catalyst::Script::$scriptclass";
+        Class::MOP::load_class($classtoload);
+    }
+    $classtoload->new_with_options( application_name => $class )->run;
+}
+
+__PACKAGE__->meta->make_immutable;
+
+=head1 NAME
+
+Catalyst::ScriptRunner - The Catalyst Framework script runner
+
+=head1 SYNOPSIS
+
+    # Will run MyApp::Script::Server if it exists, otherwise
+    # will run Catalyst::Script::Server.
+    Catalyst::ScriptRunner->run('MyApp', 'Server');
+
+=head1 DESCRIPTION
+
+This class is responsible for running scripts, either in the application specific namespace
+(e.g. C<MyApp::Script::Server>), or the Catalyst namespace (e.g. C<Catalyst::Script::Server>)
+
+=head1 AUTHORS
+
+Catalyst Contributors, see Catalyst.pm
+
+=head1 COPYRIGHT
+
+This library is free software. You can redistribute it and/or modify it under
+the same terms as Perl itself.
+
+=cut
diff --git a/t/lib/Catalyst/Script/Bar.pm b/t/lib/Catalyst/Script/Bar.pm

new file mode 100644 (file)

index 0000000..18e699c
--- /dev/null
+++ b/t/lib/Catalyst/Script/Bar.pm
@@ -0,0 +1,9 @@
+package Catalyst::Script::Bar;
+use Moose;
+use namespace::autoclean;
+
+with 'Catalyst::ScriptRole';
+
+sub run { __PACKAGE__ }
+
+1;
diff --git a/t/lib/Catalyst/Script/Baz.pm b/t/lib/Catalyst/Script/Baz.pm

new file mode 100644 (file)

index 0000000..d699fe6
--- /dev/null
+++ b/t/lib/Catalyst/Script/Baz.pm
@@ -0,0 +1,16 @@
+package Catalyst::Script::Baz;
+use Moose;
+use namespace::autoclean;
+
+use Test::More;
+
+with 'Catalyst::ScriptRole';
+
+sub run { __PACKAGE__ }
+
+after new_with_options => sub {
+    my ($self, %args) = @_;
+    is_deeply \%args, { application_name => 'ScriptTestApp' }, 'App name correct';
+};
+
+1;
diff --git a/t/lib/ScriptTestApp/Script/Bar.pm b/t/lib/ScriptTestApp/Script/Bar.pm

new file mode 100644 (file)

index 0000000..1d01fad
--- /dev/null
+++ b/t/lib/ScriptTestApp/Script/Bar.pm
@@ -0,0 +1,9 @@
+package ScriptTestApp::Script::Bar;
+use Moose;
+use namespace::autoclean;
+
+with 'Catalyst::ScriptRole';
+
+sub run { __PACKAGE__ }
+
+1;
\ No newline at end of file
diff --git a/t/lib/ScriptTestApp/Script/Foo.pm b/t/lib/ScriptTestApp/Script/Foo.pm

new file mode 100644 (file)

index 0000000..8d61c63
--- /dev/null
+++ b/t/lib/ScriptTestApp/Script/Foo.pm
@@ -0,0 +1,9 @@
+package ScriptTestApp::Script::Foo;
+use Moose;
+use namespace::autoclean;
+
+with 'Catalyst::ScriptRole';
+
+sub run { __PACKAGE__ }
+
+1;
diff --git a/t/unit_core_scriptrunner.t b/t/unit_core_scriptrunner.t

new file mode 100644 (file)

index 0000000..b87afeb
--- /dev/null
+++ b/t/unit_core_scriptrunner.t
@@ -0,0 +1,16 @@
+use strict;
+use warnings;
+use Test::More tests => 5;
+use FindBin qw/$Bin/;
+use lib "$Bin/lib";
+
+use_ok('Catalyst::ScriptRunner');
+
+is Catalyst::ScriptRunner->run('ScriptTestApp', 'Foo'), 'ScriptTestApp::Script::Foo',
+    'Script existing only in app';
+is Catalyst::ScriptRunner->run('ScriptTestApp', 'Bar'), 'ScriptTestApp::Script::Bar',
+    'Script existing in both app and Catalyst - prefers app';
+is Catalyst::ScriptRunner->run('ScriptTestApp', 'Baz'), 'Catalyst::Script::Baz',
+    'Script existing only in Catalyst';
+# +1 test for the params passed to new_with_options in t/lib/Catalyst/Script/Baz.pm
+
Makefile.PL		patch \| blob \| blame \| history
TODO.scripts	[new file with mode: 0644]	patch \| blob
lib/Catalyst.pm		patch \| blob \| blame \| history
lib/Catalyst/ROADMAP.pod		patch \| blob \| blame \| history
lib/Catalyst/Script/CGI.pm	[new file with mode: 0644]	patch \| blob
lib/Catalyst/Script/Create.pm	[new file with mode: 0644]	patch \| blob
lib/Catalyst/Script/FastCGI.pm	[new file with mode: 0644]	patch \| blob
lib/Catalyst/Script/Server.pm	[new file with mode: 0644]	patch \| blob
lib/Catalyst/Script/Test.pm	[new file with mode: 0644]	patch \| blob
lib/Catalyst/ScriptRole.pm	[new file with mode: 0644]	patch \| blob
lib/Catalyst/ScriptRunner.pm	[new file with mode: 0644]	patch \| blob
t/lib/Catalyst/Script/Bar.pm	[new file with mode: 0644]	patch \| blob
t/lib/Catalyst/Script/Baz.pm	[new file with mode: 0644]	patch \| blob
t/lib/ScriptTestApp/Script/Bar.pm	[new file with mode: 0644]	patch \| blob
t/lib/ScriptTestApp/Script/Foo.pm	[new file with mode: 0644]	patch \| blob
t/unit_core_scriptrunner.t	[new file with mode: 0644]	patch \| blob