X-Git-Url: http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=catagits%2FCatalyst-Runtime.git;a=blobdiff_plain;f=lib%2FCatalyst%2FLog.pm;h=de7a447afc3a5ea8afca8f584fc40b4320638201;hp=4ae49a011fce536ed2d5f44bfdf694fce061f707;hb=0ba80bce27a56d366c8d44c254332dd83f9ba0f9;hpb=1db849bca74f33b8daa85b694fffb8b92d03ecd6

diff --git a/lib/Catalyst/Log.pm b/lib/Catalyst/Log.pm
index 4ae49a0..de7a447 100644
--- a/lib/Catalyst/Log.pm
+++ b/lib/Catalyst/Log.pm
@@ -4,7 +4,96 @@ use strict;
 use base 'Class::Accessor::Fast';
 use Data::Dumper;
 
-$Data::Dumper::Terse = 1;
+our %LEVELS = ();
+
+__PACKAGE__->mk_accessors('level');
+__PACKAGE__->mk_accessors('body');
+__PACKAGE__->mk_accessors('abort');
+
+{
+    my @levels = qw[ debug info warn error fatal ];
+
+    for ( my $i = 0 ; $i < @levels ; $i++ ) {
+
+        my $name  = $levels[$i];
+        my $level = 1 << $i;
+
+        $LEVELS{$name} = $level;
+
+        no strict 'refs';
+
+        *{$name} = sub {
+            my $self = shift;
+
+            if ( $self->{level} & $level ) {
+                $self->_log( $name, @_ );
+            }
+        };
+
+        *{"is_$name"} = sub {
+            my $self = shift;
+            return $self->{level} & $level;
+        };
+    }
+}
+
+sub new {
+    my $class = shift;
+    my $self  = $class->SUPER::new;
+    $self->levels( scalar(@_) ? @_ : keys %LEVELS );
+    return $self;
+}
+
+sub levels {
+    my ( $self, @levels ) = @_;
+    $self->level(0);
+    $self->enable(@levels);
+}
+
+sub enable {
+    my ( $self, @levels ) = @_;
+    $self->{level} |= $_ for map { $LEVELS{$_} } @levels;
+}
+
+sub disable {
+    my ( $self, @levels ) = @_;
+    $self->{level} &= ~$_ for map { $LEVELS{$_} } @levels;
+}
+
+sub _dump {
+    my $self = shift;
+    local $Data::Dumper::Terse = 1;
+    $self->info( Dumper( @_ ) );
+}
+
+sub _log {
+    my $self    = shift;
+    my $level   = shift;
+    my $time    = localtime(time);
+    my $message = join( "\n", @_ );
+    $self->{body} .=
+      sprintf( "[%s] [catalyst] [%s] %s\n", $time, $level, $message );
+}
+
+sub _flush {
+    my $self = shift;
+    if ( $self->abort || !$self->body ) {
+        $self->abort(undef);
+    }
+    else {
+        $self->_send_to_log( $self->body );
+    }
+    $self->body(undef);
+}
+
+sub _send_to_log {
+    my $self = shift;
+    print STDERR @_;
+}
+
+1;
+
+__END__
 
 =head1 NAME
 
@@ -13,70 +102,113 @@ Catalyst::Log - Catalyst Log Class
 =head1 SYNOPSIS
 
     $log = $c->log;
-    $log->debug(@message);
-    $log->error(@message);
-    $log->info(@message);
-    $log->warn(@message);
+    $log->debug($message);
+    $log->info($message);
+    $log->warn($message);
+    $log->error($message);
+    $log->fatal($message);
+
+    if ( $log->is_debug ) {
+         # expensive debugging
+    }
+
 
 See L<Catalyst>.
 
 =head1 DESCRIPTION
 
 This module provides the default, simple logging functionality for Catalyst.
-If you want something different set C<$c->log> in your application module, e.g.:
+If you want something different set C<< $c->log >> in your application module,
+e.g.:
 
     $c->log( MyLogger->new );
 
 Your logging object is expected to provide the interface described here.
 
+=head1 LOG LEVELS
+
+=head2 debug
+
+    $log->is_debug;
+    $log->debug($message);
+
+=head2 info
+
+    $log->is_info;
+    $log->info($message);
+
+=head2 warn
+
+    $log->is_warn;
+    $log->warn($message);
+
+=head2 error
+
+    $log->is_error;
+    $log->error($message);
+
+=head2 fatal
+
+    $log->is_fatal;
+    $log->fatal($message);
 
 =head1 METHODS
 
-=over 4
+=head2 new
 
-=item $log->debug(@message)
+Constructor. Defaults to enable all levels unless levels are provided in
+arguments.
 
-Logs a debugging message.
+    $log = Catalyst::Log->new;
+    $log = Catalyst::Log->new( 'warn', 'error' );
 
-=cut
+=head2 levels
 
-sub debug { shift->_format( 'debug', @_ ) }
+Set log levels
 
-sub dump { shift->_format( 'dump', Dumper( $_[1] ) ) }
+    $log->levels( 'warn', 'error', 'fatal' );
 
-=item $log->error(@message)
+=head2 enable
 
-Logs an error message.
+Enable log levels
 
-=cut
+    $log->enable( 'warn', 'error' );
 
-sub error { shift->_format( 'error', @_ ) }
+=head2 disable
 
-=item $log->info(@message)
+Disable log levels
 
-Logs an informational message.
+    $log->disable( 'warn', 'error' );
 
-=cut
+=head2 is_debug
 
-sub info { shift->_format( 'info', @_ ) }
+=head2 is_error
 
-=item $log->warn(@message)
+=head2 is_fatal
 
-Logs a warning message.
+=head2 is_info
 
-=cut
+=head2 is_warn
 
-sub warn { shift->_format( 'warn', @_ ) }
+Is the log level active?
 
-sub _format {
-    my $class   = shift;
-    my $level   = shift;
-    my $time    = localtime(time);
-    my $message = join( "\n", @_ );
-    printf( STDERR "[%s] [catalyst] [%s] %s\n", $time, $level, $message );
-}
+=head2 abort
+
+Should Catalyst emit logs for this request? Will be reset at the end of 
+each request. 
+
+*NOTE* This method is not compatible with other log apis, so if you plan
+to use Log4Perl or another logger, you should call it like this:
+
+    $c->log->abort(1) if $c->log->can('abort');
+
+=head2 _send_to_log
+
+ $log->_send_to_log( @messages );
 
-=back
+This protected method is what actually sends the log information to STDERR.
+You may subclass this module and override this method to get finer control
+over the log output.
 
 =head1 SEE ALSO
 
@@ -85,11 +217,13 @@ L<Catalyst>.
 =head1 AUTHOR
 
 Sebastian Riedel, C<sri@cpan.org>
+Marcus Ramberg, C<mramberg@cpan.org>
+Christian Hansen, C<ch@ngmedia.com>
 
 =head1 COPYRIGHT
 
-This program is free software, you can redistribute it and/or modify it under
-the same terms as Perl itself.
+This program is free software, you can redistribute it and/or modify
+it under the same terms as Perl itself.
 
 =cut