fixed bugs in type constraints and cored some extensibility features

[catagits/Catalyst-Runtime.git] / lib / Catalyst / Utils.pm

diff --git a/lib/Catalyst/Utils.pm b/lib/Catalyst/Utils.pm
index 1bccecb..babcfa3 100644 (file)
--- a/lib/Catalyst/Utils.pm
+++ b/lib/Catalyst/Utils.pm
@@ -11,6 +11,7 @@ use Class::Load 'is_class_loaded';
 use String::RewritePrefix;
 use Class::Load ();
 use namespace::clean;
+use Devel::InnerPackage;
 
 =head1 NAME
 
@@ -502,7 +503,78 @@ sub apply_registered_middleware {
     return $new_psgi;
 }
 
+=head2 inject_component
 
+Used to add components at runtime:
+
+    into        The Catalyst package to inject into (e.g. My::App)
+    component   The component package to inject
+    as          An optional moniker to use as the package name for the derived component
+
+For example:
+
+    Catalyst::Utils::inject_component( into => My::App, component => Other::App::Controller::Apple )
+
+        The above will create 'My::App::Controller::Other::App::Controller::Apple'
+
+    Catalyst::Utils::inject_component( into => My::App, component => Other::App::Controller::Apple, as => Apple )
+
+        The above will create 'My::App::Controller::Apple'
+
+    Catalyst::Utils::inject_component( into => $myapp, component => 'MyRootV', as => 'Controller::Root' );
+
+Will inject Controller, Model, and View components into your Catalyst application
+at setup (run)time. It does this by creating a new package on-the-fly, having that
+package extend the given component, and then having Catalyst setup the new component
+(via $app->setup_component).
+
+B<NOTE:> This is basically a core version of L<CatalystX::InjectComponent>.  If you were using that
+you can now use this safely instead.  Going forward changes required to make this work will be
+synchronized with the core method.
+
+=cut
+
+sub inject_component {
+    my %given = @_;
+    my ($into, $component, $as) = @given{qw/into component as/};
+
+    croak "No Catalyst (package) given" unless $into;
+    croak "No component (package) given" unless $component;
+
+    Class::Load::load_class($component);
+
+    $as ||= $component;
+    unless ( $as =~ m/^(?:Controller|Model|View)::/ || $given{skip_mvc_renaming} ) {
+        my $category;
+        for (qw/ Controller Model View /) {
+            if ( $component->isa( "Catalyst::$_" ) ) {
+                $category = $_;
+                last;
+            }
+        }
+        croak "Don't know what kind of component \"$component\" is" unless $category;
+        $as = "${category}::$as";
+    }
+    my $component_package = join '::', $into, $as;
+
+    unless ( Class::Load::is_class_loaded $component_package ) {
+        eval "package $component_package; use base qw/$component/; 1;" or
+            croak "Unable to build component package for \"$component_package\": $@";
+        (my $file = "$component_package.pm") =~ s{::}{/}g;
+        $INC{$file} ||= 1;    
+    }
+
+    my $_setup_component = sub {
+      my $into = shift;
+      my $component_package = shift;
+      $into->components->{$component_package} = $into->setup_component( $component_package );
+    };
+
+    $_setup_component->( $into, $component_package );
+    for my $inner_component_package ( Devel::InnerPackage::list_packages( $component_package ) ) {
+        $_setup_component->( $into, $inner_component_package );
+    }
+}
 
 =head1 PSGI Helpers