t/unit_core_mvc.t

   1 use Test::More tests => 46;
   2 use strict;
   3 use warnings;
   4
   5 use_ok('Catalyst');
   6
   7 my @complist =
   8   map { "MyApp::$_"; }
   9   qw/C::Controller M::Model V::View Controller::C Model::M View::V Controller::Model::Dummy::Model Model::Dummy::Model/;
  10
  11 {
  12
  13     package MyApp;
  14
  15     use base qw/Catalyst/;
  16
  17     __PACKAGE__->components( { map { ( ref($_)||$_ , $_ ) } @complist } );
  18
  19     my $thingie={};
  20     bless $thingie, 'Some::Test::Object';
  21     __PACKAGE__->components->{'MyApp::Model::Test::Object'} = $thingie;
  22
  23     # allow $c->log->warn to work
  24     __PACKAGE__->setup_log;
  25 }
  26
  27 is( MyApp->view('View'), 'MyApp::V::View', 'V::View ok' );
  28
  29 is( MyApp->controller('Controller'),
  30     'MyApp::C::Controller', 'C::Controller ok' );
  31
  32 is( MyApp->model('Model'), 'MyApp::M::Model', 'M::Model ok' );
  33
  34 is( MyApp->model('Dummy::Model'), 'MyApp::Model::Dummy::Model', 'Model::Dummy::Model ok' );
  35
  36 isa_ok( MyApp->model('Test::Object'), 'Some::Test::Object', 'Test::Object ok' );
  37
  38 is( MyApp->controller('Model::Dummy::Model'), 'MyApp::Controller::Model::Dummy::Model', 'Controller::Model::Dummy::Model ok' );
  39
  40 is( MyApp->view('V'), 'MyApp::View::V', 'View::V ok' );
  41
  42 is( MyApp->controller('C'), 'MyApp::Controller::C', 'Controller::C ok' );
  43
  44 is( MyApp->model('M'), 'MyApp::Model::M', 'Model::M ok' );
  45
  46 # failed search
  47 {
  48     is( MyApp->model('DNE'), undef, 'undef for invalid search' );
  49 }
  50
  51 is_deeply( [ sort MyApp->views ],
  52            [ qw/V View/ ],
  53            'views ok' );
  54
  55 is_deeply( [ sort MyApp->controllers ],
  56            [ qw/C Controller Model::Dummy::Model/ ],
  57            'controllers ok');
  58
  59 is_deeply( [ sort MyApp->models ],
  60            [ qw/Dummy::Model M Model Test::Object/ ],
  61            'models ok');
  62
  63 {
  64     my $warnings = 0;
  65     no warnings 'redefine';
  66     local *Catalyst::Log::warn = sub { $warnings++ };
  67
  68     like (MyApp->view , qr/^MyApp\::(V|View)\::/ , 'view() with no defaults returns *something*');
  69     ok( $warnings, 'view() w/o a default is random, warnings thrown' );
  70 }
  71
  72 is ( bless ({stash=>{current_view=>'V'}}, 'MyApp')->view , 'MyApp::View::V', 'current_view ok');
  73
  74 my $view = bless {} , 'MyApp::View::V';
  75 is ( bless ({stash=>{current_view_instance=> $view }}, 'MyApp')->view , $view, 'current_view_instance ok');
  76
  77 is ( bless ({stash=>{current_view_instance=> $view, current_view=>'MyApp::V::View' }}, 'MyApp')->view , $view,
  78   'current_view_instance precedes current_view ok');
  79
  80 {
  81     my $warnings = 0;
  82     no warnings 'redefine';
  83     local *Catalyst::Log::warn = sub { $warnings++ };
  84
  85     ok( my $model = MyApp->model );
  86
  87     ok( (($model =~ /^MyApp\::(M|Model)\::/) ||
  88         $model->isa('Some::Test::Object')),
  89         'model() with no defaults returns *something*' );
  90
  91     ok( $warnings, 'model() w/o a default is random, warnings thrown' );
  92 }
  93
  94 is ( bless ({stash=>{current_model=>'M'}}, 'MyApp')->model , 'MyApp::Model::M', 'current_model ok');
  95
  96 my $model = bless {} , 'MyApp::Model::M';
  97 is ( bless ({stash=>{current_model_instance=> $model }}, 'MyApp')->model , $model, 'current_model_instance ok');
  98
  99 is ( bless ({stash=>{current_model_instance=> $model, current_model=>'MyApp::M::Model' }}, 'MyApp')->model , $model,
 100   'current_model_instance precedes current_model ok');
 101
 102 MyApp->config->{default_view} = 'V';
 103 is ( bless ({stash=>{}}, 'MyApp')->view , 'MyApp::View::V', 'default_view ok');
 104 is ( MyApp->view , 'MyApp::View::V', 'default_view in class method ok');
 105
 106 MyApp->config->{default_model} = 'M';
 107 is ( bless ({stash=>{}}, 'MyApp')->model , 'MyApp::Model::M', 'default_model ok');
 108 is ( MyApp->model , 'MyApp::Model::M', 'default_model in class method ok');
 109
 110 # regexp behavior tests
 111 {
 112     # is_deeply is used because regexp behavior means list context
 113     is_deeply( [ MyApp->view( qr{^V[ie]+w$} ) ], [ 'MyApp::V::View' ], 'regexp view ok' );
 114     is_deeply( [ MyApp->controller( qr{Dummy\::Model$} ) ], [ 'MyApp::Controller::Model::Dummy::Model' ], 'regexp controller ok' );
 115     is_deeply( [ MyApp->model( qr{Dum{2}y} ) ], [ 'MyApp::Model::Dummy::Model' ], 'regexp model ok' );
 116
 117     # object w/ qr{}
 118     is_deeply( [ MyApp->model( qr{Test} ) ], [ MyApp->components->{'MyApp::Model::Test::Object'} ], 'Object returned' );
 119
 120     {
 121         my $warnings = 0;
 122         no warnings 'redefine';
 123         local *Catalyst::Log::warn = sub { $warnings++ };
 124
 125         # object w/ regexp fallback
 126         is_deeply( [ MyApp->model( 'Test' ) ], [ MyApp->components->{'MyApp::Model::Test::Object'} ], 'Object returned' );
 127         ok( $warnings, 'regexp fallback warnings' );
 128     }
 129
 130     is_deeply( [ MyApp->view('MyApp::V::View$') ], [ 'MyApp::V::View' ], 'Explicit return ok');
 131     is_deeply( [ MyApp->controller('MyApp::C::Controller$') ], [ 'MyApp::C::Controller' ], 'Explicit return ok');
 132     is_deeply( [ MyApp->model('MyApp::M::Model$') ], [ 'MyApp::M::Model' ], 'Explicit return ok');
 133 }
 134
 135 {
 136     my @expected = qw( MyApp::C::Controller MyApp::Controller::C );
 137     is_deeply( [ sort MyApp->controller( qr{^C} ) ], \@expected, 'multiple controller returns from regexp search' );
 138 }
 139
 140 {
 141     my @expected = qw( MyApp::V::View MyApp::View::V );
 142     is_deeply( [ sort MyApp->view( qr{^V} ) ], \@expected, 'multiple view returns from regexp search' );
 143 }
 144
 145 {
 146     my @expected = qw( MyApp::M::Model MyApp::Model::M );
 147     is_deeply( [ sort MyApp->model( qr{^M} ) ], \@expected, 'multiple model returns from regexp search' );
 148 }
 149
 150 # failed search
 151 {
 152     is( scalar MyApp->controller( qr{DNE} ), 0, '0 results for failed search' );
 153 }
 154
 155 #checking @args passed to ACCEPT_CONTEXT
 156 {
 157     my $args;
 158
 159     {
 160         no warnings 'once';
 161         *MyApp::Model::M::ACCEPT_CONTEXT = sub { my ($self, $c, @args) = @_; $args= \@args};
 162         *MyApp::View::V::ACCEPT_CONTEXT = sub { my ($self, $c, @args) = @_; $args= \@args};
 163     }
 164
 165     my $c = bless {}, 'MyApp';
 166
 167     # test accept-context with class rather than instance
 168     MyApp->model('M', qw/foo bar/);
 169     is_deeply($args, [qw/foo bar/], 'MyApp->model args passed to ACCEPT_CONTEXT ok');
 170
 171
 172     $c->model('M', qw/foo bar/);
 173     is_deeply($args, [qw/foo bar/], '$c->model args passed to ACCEPT_CONTEXT ok');
 174
 175     my $x = $c->view('V', qw/foo2 bar2/);
 176     is_deeply($args, [qw/foo2 bar2/], '$c->view args passed to ACCEPT_CONTEXT ok');
 177
 178     # regexp fallback
 179     $c->view('::View::V', qw/foo3 bar3/);
 180     is_deeply($args, [qw/foo3 bar3/], 'args passed to ACCEPT_CONTEXT ok');
 181
 182
 183 }