t/optional_lighttpd-fastcgi-non-root.t

   1 #!perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Path;
   7 use FindBin;
   8 use IO::Socket;
   9 use Test::More;
  10
  11 plan skip_all => 'set TEST_LIGHTTPD to enable this test'
  12     unless $ENV{TEST_LIGHTTPD};
  13
  14 eval "use FCGI";
  15 plan skip_all => 'FCGI required' if $@;
  16
  17 eval "use Catalyst::Devel 1.0";
  18 plan skip_all => 'Catalyst::Devel required' if $@;
  19
  20 eval "use File::Copy::Recursive";
  21 plan skip_all => 'File::Copy::Recursive required' if $@;
  22
  23 eval "use Test::Harness";
  24 plan skip_all => 'Test::Harness required' if $@;
  25
  26 my $lighttpd_bin = $ENV{LIGHTTPD_BIN} || `which lighttpd`;
  27 chomp $lighttpd_bin;
  28
  29 plan skip_all => 'Please set LIGHTTPD_BIN to the path to lighttpd'
  30     unless $lighttpd_bin && -x $lighttpd_bin;
  31
  32 plan tests => 1;
  33
  34 # clean up
  35 rmtree "$FindBin::Bin/../t/tmp" if -d "$FindBin::Bin/../t/tmp";
  36
  37 # create a TestApp and copy the test libs into it
  38 mkdir "$FindBin::Bin/../t/tmp";
  39 chdir "$FindBin::Bin/../t/tmp";
  40 system "perl -I$FindBin::Bin/../lib $FindBin::Bin/../script/catalyst.pl TestApp";
  41 chdir "$FindBin::Bin/..";
  42 File::Copy::Recursive::dircopy( 't/lib', 't/tmp/TestApp/lib' );
  43
  44 # remove TestApp's tests
  45 rmtree 't/tmp/TestApp/t';
  46
  47 # Create a temporary lighttpd config
  48 my $docroot = "$FindBin::Bin/../t/tmp";
  49 my $port    = 8529;
  50
  51 # Clean up docroot path
  52 $docroot =~ s{/t/..}{};
  53
  54 my $conf = <<"END";
  55 # basic lighttpd config file for testing fcgi+catalyst
  56 server.modules = (
  57     "mod_access",
  58     "mod_fastcgi",
  59     "mod_rewrite",
  60     "mod_accesslog"
  61 )
  62
  63 server.document-root = "$docroot"
  64
  65 server.errorlog    = "$docroot/error.log"
  66 accesslog.filename = "$docroot/access.log"
  67
  68 server.bind = "127.0.0.1"
  69 server.port = $port
  70
  71 # Work around inability to hit http://localhost/deep/path
  72 # without a trailing slash
  73 url.rewrite = ( "deep/path\$" => "deep/path/" )
  74
  75 # catalyst app specific fcgi setup
  76 fastcgi.server = (
  77     "/deep/path" => (
  78         "FastCgiTest" => (
  79             "socket"       => "$docroot/test.socket",
  80             "check-local"  => "disable",
  81             "bin-path"     => "$docroot/TestApp/script/testapp_fastcgi.pl",
  82             "min-procs"    => 1,
  83             "max-procs"    => 1,
  84             "idle-timeout" => 20
  85         )
  86     )
  87 )
  88 END
  89
  90 open(my $lightconf, '>', "$docroot/lighttpd.conf")
  91   or die "Can't open $docroot/lighttpd.conf: $!";
  92 print {$lightconf} $conf or die "Write error: $!";
  93 close $lightconf;
  94
  95 my $pid = open my $lighttpd, "$lighttpd_bin -D -f $docroot/lighttpd.conf 2>&1 |"
  96     or die "Unable to spawn lighttpd: $!";
  97
  98 # wait for it to start
  99 while ( check_port( 'localhost', $port ) != 1 ) {
 100     diag "Waiting for server to start...";
 101     sleep 1;
 102 }
 103
 104 # run the testsuite against the server
 105 $ENV{CATALYST_SERVER} = "http://localhost:$port/deep/path";
 106
 107 my @tests = (shift) || glob('t/live_*');
 108 eval {
 109     runtests(@tests);
 110 };
 111 ok(!$@, 'lighttpd tests ran OK');
 112
 113 # shut it down
 114 kill 'INT', $pid;
 115 close $lighttpd;
 116
 117 # clean up
 118 rmtree "$FindBin::Bin/../t/tmp" if -d "$FindBin::Bin/../t/tmp";
 119
 120 sub check_port {
 121     my ( $host, $port ) = @_;
 122
 123     my $remote = IO::Socket::INET->new(
 124         Proto    => "tcp",
 125         PeerAddr => $host,
 126         PeerPort => $port
 127     );
 128     if ($remote) {
 129         close $remote;
 130         return 1;
 131     }
 132     else {
 133         return 0;
 134     }
 135 }