t/live_engine_request_parameters.t

   1 #!perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use FindBin;
   7 use lib "$FindBin::Bin/lib";
   8
   9 use Test::More tests => 35;
  10 use Catalyst::Test 'TestApp';
  11
  12 use Catalyst::Request;
  13 use HTTP::Headers;
  14 use HTTP::Request::Common;
  15 use URI;
  16
  17 {
  18     my $creq;
  19
  20     my $parameters = { 'a' => [qw(A b C d E f G)], };
  21
  22     my $query = join( '&', map { 'a=' . $_ } @{ $parameters->{a} } );
  23
  24     ok( my $response = request("http://localhost/dump/request?$query"),
  25         'Request' );
  26     ok( $response->is_success, 'Response Successful 2xx' );
  27     is( $response->content_type, 'text/plain', 'Response Content-Type' );
  28     like(
  29         $response->content,
  30         qr/^bless\( .* 'Catalyst::Request' \)$/s,
  31         'Content is a serialized Catalyst::Request'
  32     );
  33     ok( eval '$creq = ' . $response->content, 'Unserialize Catalyst::Request' );
  34     isa_ok( $creq, 'Catalyst::Request' );
  35     is( $creq->method, 'GET', 'Catalyst::Request method' );
  36     is_deeply( $creq->{parameters}, $parameters,
  37         'Catalyst::Request parameters' );
  38 }
  39
  40 {
  41     my $creq;
  42     ok( my $response = request("http://localhost/dump/request?q=foo%2bbar"),
  43         'Request' );
  44     ok( $response->is_success, 'Response Successful 2xx' );
  45     is( $response->content_type, 'text/plain', 'Response Content-Type' );
  46     ok( eval '$creq = ' . $response->content );
  47     is $creq->{parameters}->{q}, 'foo+bar', '%2b not double decoded';
  48 }
  49
  50 {
  51     my $creq;
  52
  53     my $parameters = {
  54         'a'     => [qw(A b C d E f G)],
  55         '%'     => [ '%', '"', '& - &' ],
  56         'blank' => '',
  57     };
  58
  59     my $request = POST(
  60         'http://localhost/dump/request/a/b?a=1&a=2&a=3',
  61         'Content'      => $parameters,
  62         'Content-Type' => 'application/x-www-form-urlencoded'
  63     );
  64
  65     unshift( @{ $parameters->{a} }, 1, 2, 3 );
  66
  67     ok( my $response = request($request), 'Request' );
  68     ok( $response->is_success, 'Response Successful 2xx' );
  69     is( $response->content_type, 'text/plain', 'Response Content-Type' );
  70     like(
  71         $response->content,
  72         qr/^bless\( .* 'Catalyst::Request' \)$/s,
  73         'Content is a serialized Catalyst::Request'
  74     );
  75     ok( eval '$creq = ' . $response->content, 'Unserialize Catalyst::Request' );
  76     isa_ok( $creq, 'Catalyst::Request' );
  77     is( $creq->method, 'POST', 'Catalyst::Request method' );
  78     is_deeply( $creq->{parameters}, $parameters,
  79         'Catalyst::Request parameters' );
  80     is_deeply( $creq->arguments, [qw(a b)], 'Catalyst::Request arguments' );
  81     is_deeply( $creq->{uploads}, {}, 'Catalyst::Request uploads' );
  82     is_deeply( $creq->cookies,   {}, 'Catalyst::Request cookie' );
  83 }
  84
  85 # http://dev.catalyst.perl.org/ticket/37
  86 # multipart/form-data parameters that contain 'http://'
  87 # was an HTTP::Message bug, but HTTP::Body handles it properly now
  88 {
  89     my $creq;
  90
  91     my $parameters = {
  92         'url'   => 'http://www.google.com',
  93         'blank' => '',
  94     };
  95
  96     my $request = POST( 'http://localhost/dump/request',
  97         'Content-Type' => 'multipart/form-data',
  98         'Content'      => $parameters,
  99     );
 100
 101     ok( my $response = request($request), 'Request' );
 102     ok( eval '$creq = ' . $response->content, 'Unserialize Catalyst::Request' );
 103     is_deeply( $creq->{parameters}, $parameters, 'Catalyst::Request parameters' );
 104 }
 105
 106 # raw query string support
 107 {
 108     my $creq;
 109
 110     my $parameters = {
 111         a     => 1,
 112         blank => '',
 113     };
 114
 115     my $request = POST(
 116         'http://localhost/dump/request/a/b?query+string',
 117         'Content'      => $parameters,
 118         'Content-Type' => 'application/x-www-form-urlencoded'
 119     );
 120
 121     ok( my $response = request($request), 'Request' );
 122     ok( eval '$creq = ' . $response->content, 'Unserialize Catalyst::Request' );
 123     is( $creq->{uri}->query, 'query+string', 'Catalyst::Request POST query_string' );
 124     is( $creq->query_keywords, 'query string', 'Catalyst::Request query_keywords' );
 125     is_deeply( $creq->{parameters}, $parameters, 'Catalyst::Request parameters' );
 126
 127     ok( $response = request('http://localhost/dump/request/a/b?x=1&y=1&z=1'), 'Request' );
 128     ok( eval '$creq = ' . $response->content, 'Unserialize Catalyst::Request' );
 129     is( $creq->{uri}->query, 'x=1&y=1&z=1', 'Catalyst::Request GET query_string' );
 130 }