t/live/component/controller/action/default.t

   1 #!perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use FindBin;
   7 use lib "$FindBin::Bin/../../../lib";
   8
   9 our $iters;
  10
  11 BEGIN { $iters = $ENV{CAT_BENCH_ITERS} || 2; }
  12
  13 use Test::More tests => 12*$iters;
  14 use Catalyst::Test 'TestApp';
  15
  16 if ( $ENV{CAT_BENCHMARK} ) {
  17     require Benchmark;
  18     Benchmark::timethis( $iters, \&run_tests );
  19 }
  20 else {
  21     for ( 1 .. $iters ) {
  22         run_tests();
  23     }
  24 }
  25
  26 sub run_tests {
  27     {
  28         my @expected = qw[
  29           TestApp::Controller::Action::Default->begin
  30           TestApp::Controller::Action::Default->default
  31           TestApp::View::Dump::Request->process
  32         ];
  33
  34         my $expected = join( ", ", @expected );
  35
  36         ok( my $response = request('http://localhost/action/default'),
  37             'Request' );
  38         ok( $response->is_success, 'Response Successful 2xx' );
  39         is( $response->content_type, 'text/plain', 'Response Content-Type' );
  40         is( $response->header('X-Catalyst-Action'), 'default', 'Test Action' );
  41         is(
  42             $response->header('X-Test-Class'),
  43             'TestApp::Controller::Action::Default',
  44             'Test Class'
  45         );
  46         is( $response->header('X-Catalyst-Executed'),
  47             $expected, 'Executed actions' );
  48         like(
  49             $response->content,
  50             qr/^bless\( .* 'Catalyst::Request' \)$/s,
  51             'Content is a serialized Catalyst::Request'
  52         );
  53
  54         ok( $response = request('http://localhost/foo/bar/action'), 'Request' );
  55         is( $response->code, 404, 'Invalid URI returned 404' );
  56     }
  57
  58     # test that args are passed properly to default
  59     {
  60         my $creq;
  61         my $expected = [ qw/action default arg1 arg2/ ];
  62
  63         ok( my $response = request('http://localhost/action/default/arg1/arg2'), 'Request' );
  64         ok( eval '$creq = ' . $response->content, 'Unserialize Catalyst::Request' );
  65         is_deeply( $creq->{arguments}, $expected, 'Arguments ok' );
  66     }
  67 }