t/lib/TestApp.pm

   1 package TestApp;
   2 use strict;
   3 use Catalyst qw/
   4     Test::MangleDollarUnderScore
   5     Test::Errors
   6     Test::Headers
   7     Test::Plugin
   8     Test::Inline
   9     +TestApp::Plugin::FullyQualified
  10     +TestApp::Plugin::AddDispatchTypes
  11     +TestApp::Role
  12 /;
  13 use Catalyst::Utils;
  14
  15 use Moose;
  16 use namespace::autoclean;
  17
  18 # -----------
  19 # t/aggregate/unit_core_ctx_attr.t pukes until lazy is true
  20 package Greeting;
  21 use Moose;
  22 sub hello_notlazy { 'hello there' }
  23 sub hello_lazy    { 'hello there' }
  24
  25 package TestApp;
  26 has 'my_greeting_obj_notlazy' => (
  27    is      => 'ro',
  28    isa     => 'Greeting',
  29    default => sub { Greeting->new() },
  30    handles => [ qw( hello_notlazy ) ],
  31    lazy    => 0,
  32 );
  33 has 'my_greeting_obj_lazy' => (
  34    is      => 'ro',
  35    isa     => 'Greeting',
  36    default => sub { Greeting->new() },
  37    handles => [ qw( hello_lazy ) ],
  38    lazy    => 1,
  39 );
  40 # -----------
  41
  42 our $VERSION = '0.01';
  43
  44 TestApp->config(
  45     name => 'TestApp',
  46     root => '/some/dir',
  47     use_request_uri_for_path => 1,
  48     'Controller::Action::Action' => {
  49         action_args => {
  50             action_action_nine => { another_extra_arg => 13 }
  51         }
  52     },
  53 );
  54
  55 # Test bug found when re-adjusting the metaclass compat code in Moose
  56 # in 292360. Test added to Moose in 4b760d6, but leave this attribute
  57 # above ->setup so we have some generated methods to be double sure.
  58 has an_attribute_before_we_change_base_classes => ( is => 'ro');
  59
  60 if ($::setup_leakchecker && eval { Class::MOP::load_class('CatalystX::LeakChecker'); 1 }) {
  61     with 'CatalystX::LeakChecker';
  62
  63     has leaks => (
  64         is      => 'ro',
  65         default => sub { [] },
  66     );
  67 }
  68
  69 sub found_leaks {
  70     my ($ctx, @leaks) = @_;
  71     push @{ $ctx->leaks }, @leaks;
  72 }
  73
  74 sub count_leaks {
  75     my ($ctx) = @_;
  76     return scalar @{ $ctx->leaks };
  77 }
  78
  79 TestApp->setup;
  80
  81 sub execute {
  82     my $c      = shift;
  83     my $class  = ref( $c->component( $_[0] ) ) || $_[0];
  84     my $action = $_[1]->reverse;
  85
  86     my $method;
  87
  88     if ( $action =~ /->(\w+)$/ ) {
  89         $method = $1;
  90     }
  91     elsif ( $action =~ /\/(\w+)$/ ) {
  92         $method = $1;
  93     }
  94     elsif ( $action =~ /^(\w+)$/ ) {
  95         $method = $action;
  96     }
  97
  98     if ( $class && $method && $method !~ /^_/ ) {
  99         my $executed = sprintf( "%s->%s", $class, $method );
 100         my @executed = $c->response->headers->header('X-Catalyst-Executed');
 101         push @executed, $executed;
 102         $c->response->headers->header(
 103             'X-Catalyst-Executed' => join ', ',
 104             @executed
 105         );
 106     }
 107     no warnings 'recursion';
 108     return $c->SUPER::execute(@_);
 109 }
 110
 111 # Replace the very large HTML error page with
 112 # useful info if something crashes during a test
 113 sub finalize_error {
 114     my $c = shift;
 115
 116     $c->next::method(@_);
 117
 118     $c->res->status(500);
 119     $c->res->body( 'FATAL ERROR: ' . join( ', ', @{ $c->error } ) );
 120 }
 121
 122 {
 123     no warnings 'redefine';
 124     sub Catalyst::Log::error { }
 125 }
 126
 127 # Pretend to be Plugin::Session and hook finalize_headers to send a header
 128
 129 sub finalize_headers {
 130     my $c = shift;
 131
 132     $c->res->header('X-Test-Header', 'valid');
 133
 134     my $call_count = $c->stash->{finalize_headers_call_count} || 0;
 135     $call_count++;
 136     $c->stash(finalize_headers_call_count => $call_count);
 137     $c->res->header('X-Test-Header-Call-Count' => $call_count);
 138
 139     return $c->maybe::next::method(@_);
 140 }
 141
 142 # Make sure we can load Inline plugins.
 143
 144 package Catalyst::Plugin::Test::Inline;
 145
 146 use strict;
 147
 148 use base qw/Class::Data::Inheritable/;
 149
 150 1;