t/lib/TestApp.pm

   1 package TestApp;
   2 use Moose;
   3
   4 use Catalyst qw/
   5     Test::MangleDollarUnderScore
   6     Test::Errors
   7     Test::Headers
   8     Test::Plugin
   9     Test::Inline
  10     +TestApp::Plugin::FullyQualified
  11     +TestApp::Plugin::AddDispatchTypes
  12     +TestApp::Role
  13 /;
  14 extends 'Catalyst';
  15 use Catalyst::Utils;
  16
  17 use namespace::autoclean;
  18
  19 # -----------
  20 # t/aggregate/unit_core_ctx_attr.t pukes until lazy is true
  21 package Greeting;
  22 use Moose;
  23 sub hello_notlazy { 'hello there' }
  24 sub hello_lazy    { 'hello there' }
  25
  26 package TestApp;
  27 has 'my_greeting_obj_notlazy' => (
  28    is      => 'ro',
  29    isa     => 'Greeting',
  30    default => sub { Greeting->new() },
  31    handles => [ qw( hello_notlazy ) ],
  32    lazy    => 0,
  33 );
  34 has 'my_greeting_obj_lazy' => (
  35    is      => 'ro',
  36    isa     => 'Greeting',
  37    default => sub { Greeting->new() },
  38    handles => [ qw( hello_lazy ) ],
  39    lazy    => 1,
  40 );
  41 # -----------
  42
  43 our $VERSION = '0.01';
  44
  45 TestApp->config(
  46     name => 'TestApp',
  47     root => '/some/dir',
  48     use_request_uri_for_path => 1,
  49     'Controller::Action::Action' => {
  50         action_args => {
  51             action_action_nine => { another_extra_arg => 13 }
  52         }
  53     }
  54 );
  55
  56 # Test bug found when re-adjusting the metaclass compat code in Moose
  57 # in 292360. Test added to Moose in 4b760d6, but leave this attribute
  58 # above ->setup so we have some generated methods to be double sure.
  59 has an_attribute_before_we_change_base_classes => ( is => 'ro');
  60
  61 if ($::setup_leakchecker && eval { Class::MOP::load_class('CatalystX::LeakChecker'); 1 }) {
  62     with 'CatalystX::LeakChecker';
  63
  64     has leaks => (
  65         is      => 'ro',
  66         default => sub { [] },
  67     );
  68 }
  69
  70 sub found_leaks {
  71     my ($ctx, @leaks) = @_;
  72     push @{ $ctx->leaks }, @leaks;
  73 }
  74
  75 sub count_leaks {
  76     my ($ctx) = @_;
  77     return scalar @{ $ctx->leaks };
  78 }
  79
  80 TestApp->setup;
  81
  82 sub execute {
  83     my $c      = shift;
  84     my $class  = ref( $c->component( $_[0] ) ) || $_[0];
  85     my $action = $_[1]->reverse;
  86
  87     my $method;
  88
  89     if ( $action =~ /->(\w+)$/ ) {
  90         $method = $1;
  91     }
  92     elsif ( $action =~ /\/(\w+)$/ ) {
  93         $method = $1;
  94     }
  95     elsif ( $action =~ /^(\w+)$/ ) {
  96         $method = $action;
  97     }
  98
  99     if ( $class && $method && $method !~ /^_/ ) {
 100         my $executed = sprintf( "%s->%s", $class, $method );
 101         my @executed = $c->response->headers->header('X-Catalyst-Executed');
 102         push @executed, $executed;
 103         $c->response->headers->header(
 104             'X-Catalyst-Executed' => join ', ',
 105             @executed
 106         );
 107     }
 108     no warnings 'recursion';
 109     return $c->SUPER::execute(@_);
 110 }
 111
 112 # Replace the very large HTML error page with
 113 # useful info if something crashes during a test
 114 sub finalize_error {
 115     my $c = shift;
 116
 117     $c->next::method(@_);
 118
 119     $c->res->status(500);
 120     $c->res->body( 'FATAL ERROR: ' . join( ', ', @{ $c->error } ) );
 121 }
 122
 123 {
 124     no warnings 'redefine';
 125     sub Catalyst::Log::error { }
 126 }
 127
 128 # Pretend to be Plugin::Session and hook finalize_headers to send a header
 129
 130 sub finalize_headers {
 131     my $c = shift;
 132
 133     $c->res->header('X-Test-Header', 'valid');
 134
 135     my $call_count = $c->stash->{finalize_headers_call_count} || 0;
 136     $call_count++;
 137     $c->stash(finalize_headers_call_count => $call_count);
 138     $c->res->header('X-Test-Header-Call-Count' => $call_count);
 139
 140     return $c->maybe::next::method(@_);
 141 }
 142
 143 # Make sure we can load Inline plugins.
 144
 145 package Catalyst::Plugin::Test::Inline;
 146
 147 use strict;
 148
 149 use base qw/Class::Data::Inheritable/;
 150
 151 1;