t/engine/request/uploads.t

   1 #!perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use FindBin;
   7 use lib "$FindBin::Bin/../../lib";
   8
   9 use Test::More no_plan => 1;
  10 use Catalyst::Test 'TestApp';
  11
  12 use Catalyst::Request;
  13 use HTTP::Headers;
  14 use HTTP::Headers::Util 'split_header_words';
  15 use HTTP::Request::Common;
  16
  17 {
  18     my $creq;
  19
  20     my $request = POST( 'http://localhost/dump/request/',
  21         'Content-Type' => 'multipart/form-data',
  22         'Content'      => [
  23             'cookies.t' => [ "$FindBin::Bin/cookies.t" ],
  24             'headers.t' => [ "$FindBin::Bin/headers.t" ],
  25             'uploads.t' => [ "$FindBin::Bin/uploads.t" ],
  26          ]
  27     );
  28
  29     ok( my $response = request($request), 'Request' );
  30     ok( $response->is_success, 'Response Successful 2xx' );
  31     is( $response->content_type, 'text/plain', 'Response Content-Type' );
  32     like( $response->content, qr/^bless\( .* 'Catalyst::Request' \)$/s, 'Content is a serialized Catalyst::Request' );
  33
  34     {
  35         no strict 'refs';
  36         ok( eval '$creq = ' . $response->content, 'Unserialize Catalyst::Request' );
  37     }
  38
  39     isa_ok( $creq, 'Catalyst::Request' );
  40     is( $creq->method, 'POST', 'Catalyst::Request method' );
  41     is( $creq->content_type, 'multipart/form-data', 'Catalyst::Request Content-Type' );
  42     is( $creq->content_length, $request->content_length, 'Catalyst::Request Content-Length' );
  43
  44     for my $part ( $request->parts ) {
  45
  46         my $disposition = $part->header('Content-Disposition');
  47         my %parameters  = @{ ( split_header_words($disposition) )[0] };
  48
  49         my $upload = $creq->uploads->{ $parameters{filename} };
  50
  51         isnt( $upload, undef, 'Upload filename' );
  52         is( $upload->{type}, $part->content_type, 'Upload Content-Type' );
  53         is( $upload->{size}, length( $part->content ), 'Upload Content-Length' );
  54     }
  55
  56     #warn $response->as_string;
  57 }