t/aggregate/unit_core_uri_for.t

   1 use strict;
   2 use warnings;
   3 use FindBin qw/$Bin/;
   4 use lib "$FindBin::Bin/../lib";
   5 use Test::More;
   6 use URI;
   7
   8 use_ok('TestApp');
   9
  10 my $request = Catalyst::Request->new( {
  11                 base => URI->new('http://127.0.0.1/foo')
  12               } );
  13 my $dispatcher = TestApp->dispatcher;
  14 my $context = TestApp->new( {
  15                 request => $request,
  16                 namespace => 'yada',
  17               } );
  18
  19 is(
  20     Catalyst::uri_for( $context, '/bar/baz' )->as_string,
  21     'http://127.0.0.1/foo/bar/baz',
  22     'URI for absolute path'
  23 );
  24
  25 is(
  26     Catalyst::uri_for( $context, 'bar/baz' )->as_string,
  27     'http://127.0.0.1/foo/yada/bar/baz',
  28     'URI for relative path'
  29 );
  30
  31 is(
  32     Catalyst::uri_for( $context, '', 'arg1', 'arg2' )->as_string,
  33     'http://127.0.0.1/foo/yada/arg1/arg2',
  34     'URI for undef action with args'
  35 );
  36
  37
  38 is( Catalyst::uri_for( $context, '../quux' )->as_string,
  39     'http://127.0.0.1/foo/quux', 'URI for relative dot path' );
  40
  41 is(
  42     Catalyst::uri_for( $context, 'quux', { param1 => 'value1' } )->as_string,
  43     'http://127.0.0.1/foo/yada/quux?param1=value1',
  44     'URI for undef action with query params'
  45 );
  46
  47 is (Catalyst::uri_for( $context, '/bar/wibble?' )->as_string,
  48    'http://127.0.0.1/foo/bar/wibble%3F', 'Question Mark gets encoded'
  49 );
  50
  51 is( Catalyst::uri_for( $context, qw/bar wibble?/, 'with space' )->as_string,
  52     'http://127.0.0.1/foo/yada/bar/wibble%3F/with%20space', 'Space gets encoded'
  53 );
  54
  55 is(
  56     Catalyst::uri_for( $context, '/bar', 'with+plus', { 'also' => 'with+plus' })->as_string,
  57     'http://127.0.0.1/foo/bar/with+plus?also=with%2Bplus',
  58     'Plus is not encoded'
  59 );
  60
  61 # test with utf-8
  62 is(
  63     Catalyst::uri_for( $context, 'quux', { param1 => "\x{2620}" } )->as_string,
  64     'http://127.0.0.1/foo/yada/quux?param1=%E2%98%A0',
  65     'URI for undef action with query params in unicode'
  66 );
  67 is(
  68     Catalyst::uri_for( $context, 'quux', { 'param:1' => "foo" } )->as_string,
  69     'http://127.0.0.1/foo/yada/quux?param%3A1=foo',
  70     'URI for undef action with query params in unicode'
  71 );
  72
  73 # test with object
  74 is(
  75     Catalyst::uri_for( $context, 'quux', { param1 => $request->base } )->as_string,
  76     'http://127.0.0.1/foo/yada/quux?param1=http%3A%2F%2F127.0.0.1%2Ffoo',
  77     'URI for undef action with query param as object'
  78 );
  79
  80 $request->base( URI->new('http://localhost:3000/') );
  81 $request->match( 'orderentry/contract' );
  82 is(
  83     Catalyst::uri_for( $context, '/Orderentry/saveContract' )->as_string,
  84     'http://localhost:3000/Orderentry/saveContract',
  85     'URI for absolute path'
  86 );
  87
  88 {
  89     $request->base( URI->new('http://127.0.0.1/') );
  90
  91     $context->namespace('');
  92
  93     is( Catalyst::uri_for( $context, '/bar/baz' )->as_string,
  94         'http://127.0.0.1/bar/baz', 'URI with no base or match' );
  95
  96     # test "0" as the path
  97     is( Catalyst::uri_for( $context, qw/0 foo/ )->as_string,
  98         'http://127.0.0.1/0/foo', '0 as path is ok'
  99     );
 100
 101 }
 102
 103 # test with undef -- no warnings should be thrown
 104 {
 105     my $warnings = 0;
 106     local $SIG{__WARN__} = sub { $warnings++ };
 107
 108     Catalyst::uri_for( $context, '/bar/baz', { foo => undef } )->as_string,
 109     is( $warnings, 0, "no warnings emitted" );
 110 }
 111
 112 # Test with parameters '/', 'foo', 'bar' - should not generate a //
 113 is( Catalyst::uri_for( $context, qw| / foo bar | )->as_string,
 114     'http://127.0.0.1/foo/bar', 'uri is /foo/bar, not //foo/bar'
 115 );
 116
 117 TODO: {
 118     local $TODO = 'RFCs are for people who, erm - fix this test..';
 119     # Test rfc3986 reserved characters.  These characters should all be escaped
 120     # according to the RFC, but it is a very big feature change so I've removed it
 121     no warnings; # Yes, everything in qw is sane
 122     is(
 123         Catalyst::uri_for( $context, qw|! * ' ( ) ; : @ & = $ / ? % # [ ] ,|, )->as_string,
 124         'http://127.0.0.1/%21/%2A/%27/%2B/%29/%3B/%3A/%40/%26/%3D/%24/%2C/%2F/%3F/%25/%23/%5B/%5D',
 125         'rfc 3986 reserved characters'
 126     );
 127
 128     # jshirley bug - why the hell does only one of these get encoded
 129     #                has been like this forever however.
 130     is(
 131         Catalyst::uri_for( $context, qw|{1} {2}| )->as_string,
 132         'http://127.0.0.1/{1}/{2}',
 133         'not-escaping unreserved characters'
 134     );
 135 }
 136
 137 # make sure caller's query parameter hash isn't messed up
 138 {
 139     my $query_params_base = {test => "one two",
 140                              bar  => ["foo baz", "bar"]};
 141     my $query_params_test = {test => "one two",
 142                              bar  => ["foo baz", "bar"]};
 143     Catalyst::uri_for($context, '/bar/baz', $query_params_test);
 144     is_deeply($query_params_base, $query_params_test,
 145               "uri_for() doesn't mess up query parameter hash in the caller");
 146 }
 147
 148
 149 {
 150     my $path_action = $dispatcher->get_action_by_path(
 151                        '/action/path/six'
 152                      );
 153
 154     # 5.80018 is only encoding the first of the / in the arg.
 155     is(
 156         Catalyst::uri_for( $context, $path_action, 'foo/bar/baz' )->as_string,
 157         'http://127.0.0.1/action/path/six/foo%2Fbar%2Fbaz',
 158         'Escape all forward slashes in args as %2F'
 159     );
 160 }
 161
 162
 163 done_testing;
 164