t/aggregate/unit_core_uri_for.t

   1 use strict;
   2 use warnings;
   3 use FindBin qw/$Bin/;
   4 use lib "$FindBin::Bin/../lib";
   5 use Test::More;
   6 use URI;
   7
   8 use_ok('TestApp');
   9
  10 my $request = Catalyst::Request->new( {
  11                 _log => Catalyst::Log->new,
  12                 base => URI->new('http://127.0.0.1/foo')
  13               } );
  14 my $dispatcher = TestApp->dispatcher;
  15 my $context = TestApp->new( {
  16                 request => $request,
  17                 namespace => 'yada',
  18               } );
  19
  20 is(
  21     Catalyst::uri_for( $context, '/bar/baz' )->as_string,
  22     'http://127.0.0.1/foo/bar/baz',
  23     'URI for absolute path'
  24 );
  25
  26 is(
  27     Catalyst::uri_for( $context, 'bar/baz' )->as_string,
  28     'http://127.0.0.1/foo/yada/bar/baz',
  29     'URI for relative path'
  30 );
  31
  32 is(
  33     Catalyst::uri_for( $context, '', 'arg1', 'arg2' )->as_string,
  34     'http://127.0.0.1/foo/yada/arg1/arg2',
  35     'URI for undef action with args'
  36 );
  37
  38
  39 is( Catalyst::uri_for( $context, '../quux' )->as_string,
  40     'http://127.0.0.1/foo/quux', 'URI for relative dot path' );
  41
  42 is(
  43     Catalyst::uri_for( $context, 'quux', { param1 => 'value1' } )->as_string,
  44     'http://127.0.0.1/foo/yada/quux?param1=value1',
  45     'URI for undef action with query params'
  46 );
  47
  48 is (Catalyst::uri_for( $context, '/bar/wibble?' )->as_string,
  49    'http://127.0.0.1/foo/bar/wibble%3F', 'Question Mark gets encoded'
  50 );
  51
  52 is( Catalyst::uri_for( $context, qw/bar wibble?/, 'with space' )->as_string,
  53     'http://127.0.0.1/foo/yada/bar/wibble%3F/with%20space', 'Space gets encoded'
  54 );
  55
  56 is(
  57     Catalyst::uri_for( $context, '/bar', 'with+plus', { 'also' => 'with+plus' })->as_string,
  58     'http://127.0.0.1/foo/bar/with+plus?also=with%2Bplus',
  59     'Plus is not encoded'
  60 );
  61
  62 is(
  63     Catalyst::uri_for( 'TestApp', '/bar/baz' )->as_string,
  64     '/bar/baz',
  65     'URI for absolute path, called with only class name'
  66 );
  67
  68 ## relative action (or path) doesn't make sense when calling as class method
  69 # is(
  70 #     Catalyst::uri_for( 'TestApp', 'bar/baz' )->as_string,
  71 #     '/yada/bar/baz',
  72 #     'URI for relative path, called with only class name'
  73 # );
  74
  75 is(
  76     Catalyst::uri_for( 'TestApp', '/', 'arg1', 'arg2' )->as_string,
  77     '/arg1/arg2',
  78     'URI for root action with args, called with only class name'
  79 );
  80
  81 ## relative action (or path) doesn't make sense when calling as class method
  82 # is( Catalyst::uri_for( 'TestApp', '../quux' )->as_string,
  83 #     '/quux', 'URI for relative dot path, called with only class name' );
  84
  85 is(
  86     Catalyst::uri_for( 'TestApp', '/quux', { param1 => 'value1' } )->as_string,
  87     '/quux?param1=value1',
  88     'URI for quux action with query params, called with only class name'
  89 );
  90
  91 is (Catalyst::uri_for( 'TestApp', '/bar/wibble?' )->as_string,
  92    '/bar/wibble%3F', 'Question Mark gets encoded, called with only class name'
  93 );
  94
  95 ## relative action (or path) doesn't make sense when calling as class method
  96 # is( Catalyst::uri_for( 'TestApp', qw/bar wibble?/, 'with space' )->as_string,
  97 #     '/yada/bar/wibble%3F/with%20space', 'Space gets encoded, called with only class name'
  98 # );
  99
 100 is(
 101     Catalyst::uri_for( 'TestApp', '/bar', 'with+plus', { 'also' => 'with+plus' })->as_string,
 102     '/bar/with+plus?also=with%2Bplus',
 103     'Plus is not encoded, called with only class name'
 104 );
 105
 106 TODO: {
 107     local $TODO = 'broken by 5.7008';
 108     is(
 109         Catalyst::uri_for( $context, '/bar#fragment', { param1 => 'value1' } )->as_string,
 110         'http://127.0.0.1/foo/bar?param1=value1#fragment',
 111         'URI for path with fragment and query params'
 112     );
 113 }
 114
 115 # test with utf-8
 116 is(
 117     Catalyst::uri_for( $context, 'quux', { param1 => "\x{2620}" } )->as_string,
 118     'http://127.0.0.1/foo/yada/quux?param1=%E2%98%A0',
 119     'URI for undef action with query params in unicode'
 120 );
 121 is(
 122     Catalyst::uri_for( $context, 'quux', { 'param:1' => "foo" } )->as_string,
 123     'http://127.0.0.1/foo/yada/quux?param%3A1=foo',
 124     'URI for undef action with query params in unicode'
 125 );
 126
 127 # test with object
 128 is(
 129     Catalyst::uri_for( $context, 'quux', { param1 => $request->base } )->as_string,
 130     'http://127.0.0.1/foo/yada/quux?param1=http%3A%2F%2F127.0.0.1%2Ffoo',
 131     'URI for undef action with query param as object'
 132 );
 133
 134 $request->base( URI->new('http://localhost:3000/') );
 135 $request->match( 'orderentry/contract' );
 136 is(
 137     Catalyst::uri_for( $context, '/Orderentry/saveContract' )->as_string,
 138     'http://localhost:3000/Orderentry/saveContract',
 139     'URI for absolute path'
 140 );
 141
 142 {
 143     $request->base( URI->new('http://127.0.0.1/') );
 144
 145     $context->namespace('');
 146
 147     is( Catalyst::uri_for( $context, '/bar/baz' )->as_string,
 148         'http://127.0.0.1/bar/baz', 'URI with no base or match' );
 149
 150     # test "0" as the path
 151     is( Catalyst::uri_for( $context, qw/0 foo/ )->as_string,
 152         'http://127.0.0.1/0/foo', '0 as path is ok'
 153     );
 154
 155 }
 156
 157 # test with undef -- no warnings should be thrown
 158 {
 159     my $warnings = 0;
 160     local $SIG{__WARN__} = sub { $warnings++ };
 161
 162     Catalyst::uri_for( $context, '/bar/baz', { foo => undef } )->as_string,
 163     is( $warnings, 0, "no warnings emitted" );
 164 }
 165
 166 # Test with parameters '/', 'foo', 'bar' - should not generate a //
 167 is( Catalyst::uri_for( $context, qw| / foo bar | )->as_string,
 168     'http://127.0.0.1/foo/bar', 'uri is /foo/bar, not //foo/bar'
 169 );
 170
 171 TODO: {
 172     local $TODO = 'RFCs are for people who, erm - fix this test..';
 173     # Test rfc3986 reserved characters.  These characters should all be escaped
 174     # according to the RFC, but it is a very big feature change so I've removed it
 175     no warnings; # Yes, everything in qw is sane
 176     is(
 177         Catalyst::uri_for( $context, qw|! * ' ( ) ; : @ & = $ / ? % # [ ] ,|, )->as_string,
 178         'http://127.0.0.1/%21/%2A/%27/%2B/%29/%3B/%3A/%40/%26/%3D/%24/%2C/%2F/%3F/%25/%23/%5B/%5D',
 179         'rfc 3986 reserved characters'
 180     );
 181
 182     # jshirley bug - why the hell does only one of these get encoded
 183     #                has been like this forever however.
 184     is(
 185         Catalyst::uri_for( $context, qw|{1} {2}| )->as_string,
 186         'http://127.0.0.1/{1}/{2}',
 187         'not-escaping unreserved characters'
 188     );
 189 }
 190
 191 # make sure caller's query parameter hash isn't messed up
 192 {
 193     my $query_params_base = {test => "one two",
 194                              bar  => ["foo baz", "bar"]};
 195     my $query_params_test = {test => "one two",
 196                              bar  => ["foo baz", "bar"]};
 197     Catalyst::uri_for($context, '/bar/baz', $query_params_test);
 198     is_deeply($query_params_base, $query_params_test,
 199               "uri_for() doesn't mess up query parameter hash in the caller");
 200 }
 201
 202
 203 {
 204     my $path_action = $dispatcher->get_action_by_path(
 205                        '/action/path/six'
 206                      );
 207
 208     # 5.80018 is only encoding the first of the / in the arg.
 209     is(
 210         Catalyst::uri_for( $context, $path_action, 'foo/bar/baz' )->as_string,
 211         'http://127.0.0.1/action/path/six/foo%2Fbar%2Fbaz',
 212         'Escape all forward slashes in args as %2F'
 213     );
 214 }
 215
 216 {
 217     my $index_not_private = $dispatcher->get_action_by_path(
 218                              '/action/chained/argsorder/index'
 219                             );
 220
 221     is(
 222       Catalyst::uri_for( $context, $index_not_private )->as_string,
 223       'http://127.0.0.1/argsorder',
 224       'Return non-DispatchType::Index path for index action with args'
 225     );
 226 }
 227
 228 {
 229     package MyStringThing;
 230
 231     use overload '""' => sub { $_[0]->{string} }, fallback => 1;
 232 }
 233
 234 is(
 235     Catalyst::uri_for( $context, bless( { string => 'test' }, 'MyStringThing' ) ),
 236     'http://127.0.0.1/test',
 237     'overloaded object handled correctly'
 238 );
 239
 240 done_testing;