t/aggregate/unit_core_uri_for.t

   1 use strict;
   2 use warnings;
   3 use FindBin qw/$Bin/;
   4 use lib "$FindBin::Bin/../lib";
   5 use Test::More;
   6 use URI;
   7
   8 use_ok('TestApp');
   9
  10 my $request = Catalyst::Request->new( {
  11                 _log => Catalyst::Log->new,
  12                 base => URI->new('http://127.0.0.1/foo')
  13               } );
  14 my $dispatcher = TestApp->dispatcher;
  15 my $context = TestApp->new( {
  16                 request => $request,
  17                 namespace => 'yada',
  18               } );
  19
  20 is(
  21     Catalyst::uri_for( $context, '/bar/baz' )->as_string,
  22     'http://127.0.0.1/foo/bar/baz',
  23     'URI for absolute path'
  24 );
  25
  26 is(
  27     Catalyst::uri_for( $context, 'bar/baz' )->as_string,
  28     'http://127.0.0.1/foo/yada/bar/baz',
  29     'URI for relative path'
  30 );
  31
  32 is(
  33     Catalyst::uri_for( $context, '', 'arg1', 'arg2' )->as_string,
  34     'http://127.0.0.1/foo/yada/arg1/arg2',
  35     'URI for undef action with args'
  36 );
  37
  38
  39 is( Catalyst::uri_for( $context, '../quux' )->as_string,
  40     'http://127.0.0.1/foo/quux', 'URI for relative dot path' );
  41
  42 is(
  43     Catalyst::uri_for( $context, 'quux', { param1 => 'value1' } )->as_string,
  44     'http://127.0.0.1/foo/yada/quux?param1=value1',
  45     'URI for undef action with query params'
  46 );
  47
  48 is (Catalyst::uri_for( $context, '/bar/wibble?' )->as_string,
  49    'http://127.0.0.1/foo/bar/wibble%3F', 'Question Mark gets encoded'
  50 );
  51
  52 is( Catalyst::uri_for( $context, qw/bar wibble?/, 'with space' )->as_string,
  53     'http://127.0.0.1/foo/yada/bar/wibble%3F/with%20space', 'Space gets encoded'
  54 );
  55
  56 is(
  57     Catalyst::uri_for( $context, '/bar', 'with+plus', { 'also' => 'with+plus' })->as_string,
  58     'http://127.0.0.1/foo/bar/with+plus?also=with%2Bplus',
  59     'Plus is not encoded'
  60 );
  61
  62 is(
  63     Catalyst::uri_for( $context, '/bar#fragment', { param1 => 'value1' } )->as_string,
  64     'http://127.0.0.1/foo/bar?param1=value1#fragment',
  65     'URI for path with fragment and query params 1'
  66 );
  67
  68 is(
  69     Catalyst::uri_for( $context, '/bar#fragment^%$', { param1 => 'value1' } )->as_string,
  70     'http://127.0.0.1/foo/bar?param1=value1#fragment^%$',
  71     'URI for path with fragment and query params 3'
  72 );
  73
  74 is(
  75     Catalyst::uri_for( $context, '/foo#bar/baz', { param1 => 'value1' } )->as_string,
  76     'http://127.0.0.1/foo/foo?param1=value1#bar/baz',
  77     'URI for path with fragment and query params 3'
  78 );
  79
  80 # test with utf-8
  81 is(
  82     Catalyst::uri_for( $context, 'quux', { param1 => "\x{2620}" } )->as_string,
  83     'http://127.0.0.1/foo/yada/quux?param1=%E2%98%A0',
  84     'URI for undef action with query params in unicode'
  85 );
  86 is(
  87     Catalyst::uri_for( $context, 'quux', { 'param:1' => "foo" } )->as_string,
  88     'http://127.0.0.1/foo/yada/quux?param%3A1=foo',
  89     'URI for undef action with query params in unicode'
  90 );
  91
  92 # test with object
  93 is(
  94     Catalyst::uri_for( $context, 'quux', { param1 => $request->base } )->as_string,
  95     'http://127.0.0.1/foo/yada/quux?param1=http%3A%2F%2F127.0.0.1%2Ffoo',
  96     'URI for undef action with query param as object'
  97   );
  98
  99 # test with empty arg
 100 {
 101     my @warnings;
 102     local $SIG{__WARN__} = sub { push @warnings, @_ };
 103     is(
 104        Catalyst::uri_for( $context )->as_string,
 105        'http://127.0.0.1/foo/yada',
 106        'URI with no action'
 107       );
 108     is_deeply(\@warnings, [], "No warnings with no path argument");
 109 }
 110
 111 $request->base( URI->new('http://localhost:3000/') );
 112 $request->match( 'orderentry/contract' );
 113 is(
 114     Catalyst::uri_for( $context, '/Orderentry/saveContract' )->as_string,
 115     'http://localhost:3000/Orderentry/saveContract',
 116     'URI for absolute path'
 117 );
 118
 119 {
 120     $request->base( URI->new('http://127.0.0.1/') );
 121
 122     $context->namespace('');
 123
 124     is( Catalyst::uri_for( $context, '/bar/baz' )->as_string,
 125         'http://127.0.0.1/bar/baz', 'URI with no base or match' );
 126
 127     # test "0" as the path
 128     is( Catalyst::uri_for( $context, qw/0 foo/ )->as_string,
 129         'http://127.0.0.1/0/foo', '0 as path is ok'
 130     );
 131
 132 }
 133
 134 # test with undef -- no warnings should be thrown
 135 {
 136     my $warnings = 0;
 137     local $SIG{__WARN__} = sub { $warnings++ };
 138
 139     Catalyst::uri_for( $context, '/bar/baz', { foo => undef } )->as_string,
 140     is( $warnings, 0, "no warnings emitted" );
 141 }
 142
 143 # Test with parameters '/', 'foo', 'bar' - should not generate a //
 144 is( Catalyst::uri_for( $context, qw| / foo bar | )->as_string,
 145     'http://127.0.0.1/foo/bar', 'uri is /foo/bar, not //foo/bar'
 146 );
 147
 148 TODO: {
 149     local $TODO = 'RFCs are for people who, erm - fix this test..';
 150     # Test rfc3986 reserved characters.  These characters should all be escaped
 151     # according to the RFC, but it is a very big feature change so I've removed it
 152     no warnings; # Yes, everything in qw is sane
 153     is(
 154         Catalyst::uri_for( $context, qw|! * ' ( ) ; : @ & = $ / ? % # [ ] ,|, )->as_string,
 155         'http://127.0.0.1/%21/%2A/%27/%2B/%29/%3B/%3A/%40/%26/%3D/%24/%2C/%2F/%3F/%25/%23/%5B/%5D',
 156         'rfc 3986 reserved characters'
 157     );
 158
 159     # jshirley bug - why the hell does only one of these get encoded
 160     #                has been like this forever however.
 161     is(
 162         Catalyst::uri_for( $context, qw|{1} {2}| )->as_string,
 163         'http://127.0.0.1/{1}/{2}',
 164         'not-escaping unreserved characters'
 165     );
 166 }
 167
 168 # make sure caller's query parameter hash isn't messed up
 169 {
 170     my $query_params_base = {test => "one two",
 171                              bar  => ["foo baz", "bar"]};
 172     my $query_params_test = {test => "one two",
 173                              bar  => ["foo baz", "bar"]};
 174     Catalyst::uri_for($context, '/bar/baz', $query_params_test);
 175     is_deeply($query_params_base, $query_params_test,
 176               "uri_for() doesn't mess up query parameter hash in the caller");
 177 }
 178
 179
 180 {
 181     my $path_action = $dispatcher->get_action_by_path(
 182                        '/action/path/six'
 183                      );
 184
 185     # 5.80018 is only encoding the first of the / in the arg.
 186     is(
 187         Catalyst::uri_for( $context, $path_action, 'foo/bar/baz' )->as_string,
 188         'http://127.0.0.1/action/path/six/foo%2Fbar%2Fbaz',
 189         'Escape all forward slashes in args as %2F'
 190     );
 191 }
 192
 193 {
 194     my $index_not_private = $dispatcher->get_action_by_path(
 195                              '/action/chained/argsorder/index'
 196                             );
 197
 198     is(
 199       Catalyst::uri_for( $context, $index_not_private )->as_string,
 200       'http://127.0.0.1/argsorder',
 201       'Return non-DispatchType::Index path for index action with args'
 202     );
 203 }
 204
 205 {
 206     package MyStringThing;
 207
 208     use overload '""' => sub { $_[0]->{string} }, fallback => 1;
 209 }
 210
 211 is(
 212     Catalyst::uri_for( $context, bless( { string => 'test' }, 'MyStringThing' ) ),
 213     'http://127.0.0.1/test',
 214     'overloaded object handled correctly'
 215 );
 216
 217 done_testing;