t/aggregate/unit_core_uri_for.t

   1 use strict;
   2 use warnings;
   3 use FindBin qw/$Bin/;
   4 use lib "$FindBin::Bin/../lib";
   5 use Test::More;
   6 use URI;
   7
   8 use_ok('TestApp');
   9
  10 my $request = Catalyst::Request->new( {
  11                 _log => Catalyst::Log->new,
  12                 base => URI->new('http://127.0.0.1/foo')
  13               } );
  14 my $dispatcher = TestApp->dispatcher;
  15 my $context = TestApp->new( {
  16                 request => $request,
  17                 namespace => 'yada',
  18               } );
  19
  20 is(
  21     Catalyst::uri_for( $context, '/bar/baz' )->as_string,
  22     'http://127.0.0.1/foo/bar/baz',
  23     'URI for absolute path'
  24 );
  25
  26 is(
  27     Catalyst::uri_for( $context, 'bar/baz' )->as_string,
  28     'http://127.0.0.1/foo/yada/bar/baz',
  29     'URI for relative path'
  30 );
  31
  32 is(
  33     Catalyst::uri_for( $context, '', 'arg1', 'arg2' )->as_string,
  34     'http://127.0.0.1/foo/yada/arg1/arg2',
  35     'URI for undef action with args'
  36 );
  37
  38
  39 is( Catalyst::uri_for( $context, '../quux' )->as_string,
  40     'http://127.0.0.1/foo/quux', 'URI for relative dot path' );
  41
  42 is(
  43     Catalyst::uri_for( $context, 'quux', { param1 => 'value1' } )->as_string,
  44     'http://127.0.0.1/foo/yada/quux?param1=value1',
  45     'URI for undef action with query params'
  46 );
  47
  48 is (Catalyst::uri_for( $context, '/bar/wibble?' )->as_string,
  49    'http://127.0.0.1/foo/bar/wibble%3F', 'Question Mark gets encoded'
  50 );
  51
  52 is( Catalyst::uri_for( $context, qw/bar wibble?/, 'with space' )->as_string,
  53     'http://127.0.0.1/foo/yada/bar/wibble%3F/with%20space', 'Space gets encoded'
  54 );
  55
  56 is(
  57     Catalyst::uri_for( $context, '/bar', 'with+plus', { 'also' => 'with+plus' })->as_string,
  58     'http://127.0.0.1/foo/bar/with+plus?also=with%2Bplus',
  59     'Plus is not encoded'
  60 );
  61
  62 TODO: {
  63     local $TODO = 'broken by 5.7008';
  64     is(
  65         Catalyst::uri_for( $context, '/bar#fragment', { param1 => 'value1' } )->as_string,
  66         'http://127.0.0.1/foo/bar?param1=value1#fragment',
  67         'URI for path with fragment and query params'
  68     );
  69 }
  70
  71 # test with utf-8
  72 is(
  73     Catalyst::uri_for( $context, 'quux', { param1 => "\x{2620}" } )->as_string,
  74     'http://127.0.0.1/foo/yada/quux?param1=%E2%98%A0',
  75     'URI for undef action with query params in unicode'
  76 );
  77 is(
  78     Catalyst::uri_for( $context, 'quux', { 'param:1' => "foo" } )->as_string,
  79     'http://127.0.0.1/foo/yada/quux?param%3A1=foo',
  80     'URI for undef action with query params in unicode'
  81 );
  82
  83 # test with object
  84 is(
  85     Catalyst::uri_for( $context, 'quux', { param1 => $request->base } )->as_string,
  86     'http://127.0.0.1/foo/yada/quux?param1=http%3A%2F%2F127.0.0.1%2Ffoo',
  87     'URI for undef action with query param as object'
  88 );
  89
  90 $request->base( URI->new('http://localhost:3000/') );
  91 $request->match( 'orderentry/contract' );
  92 is(
  93     Catalyst::uri_for( $context, '/Orderentry/saveContract' )->as_string,
  94     'http://localhost:3000/Orderentry/saveContract',
  95     'URI for absolute path'
  96 );
  97
  98 {
  99     $request->base( URI->new('http://127.0.0.1/') );
 100
 101     $context->namespace('');
 102
 103     is( Catalyst::uri_for( $context, '/bar/baz' )->as_string,
 104         'http://127.0.0.1/bar/baz', 'URI with no base or match' );
 105
 106     # test "0" as the path
 107     is( Catalyst::uri_for( $context, qw/0 foo/ )->as_string,
 108         'http://127.0.0.1/0/foo', '0 as path is ok'
 109     );
 110
 111 }
 112
 113 # test with undef -- no warnings should be thrown
 114 {
 115     my $warnings = 0;
 116     local $SIG{__WARN__} = sub { $warnings++ };
 117
 118     Catalyst::uri_for( $context, '/bar/baz', { foo => undef } )->as_string,
 119     is( $warnings, 0, "no warnings emitted" );
 120 }
 121
 122 # Test with parameters '/', 'foo', 'bar' - should not generate a //
 123 is( Catalyst::uri_for( $context, qw| / foo bar | )->as_string,
 124     'http://127.0.0.1/foo/bar', 'uri is /foo/bar, not //foo/bar'
 125 );
 126
 127 TODO: {
 128     local $TODO = 'RFCs are for people who, erm - fix this test..';
 129     # Test rfc3986 reserved characters.  These characters should all be escaped
 130     # according to the RFC, but it is a very big feature change so I've removed it
 131     no warnings; # Yes, everything in qw is sane
 132     is(
 133         Catalyst::uri_for( $context, qw|! * ' ( ) ; : @ & = $ / ? % # [ ] ,|, )->as_string,
 134         'http://127.0.0.1/%21/%2A/%27/%2B/%29/%3B/%3A/%40/%26/%3D/%24/%2C/%2F/%3F/%25/%23/%5B/%5D',
 135         'rfc 3986 reserved characters'
 136     );
 137
 138     # jshirley bug - why the hell does only one of these get encoded
 139     #                has been like this forever however.
 140     is(
 141         Catalyst::uri_for( $context, qw|{1} {2}| )->as_string,
 142         'http://127.0.0.1/{1}/{2}',
 143         'not-escaping unreserved characters'
 144     );
 145 }
 146
 147 # make sure caller's query parameter hash isn't messed up
 148 {
 149     my $query_params_base = {test => "one two",
 150                              bar  => ["foo baz", "bar"]};
 151     my $query_params_test = {test => "one two",
 152                              bar  => ["foo baz", "bar"]};
 153     Catalyst::uri_for($context, '/bar/baz', $query_params_test);
 154     is_deeply($query_params_base, $query_params_test,
 155               "uri_for() doesn't mess up query parameter hash in the caller");
 156 }
 157
 158
 159 {
 160     my $path_action = $dispatcher->get_action_by_path(
 161                        '/action/path/six'
 162                      );
 163
 164     # 5.80018 is only encoding the first of the / in the arg.
 165     is(
 166         Catalyst::uri_for( $context, $path_action, 'foo/bar/baz' )->as_string,
 167         'http://127.0.0.1/action/path/six/foo%2Fbar%2Fbaz',
 168         'Escape all forward slashes in args as %2F'
 169     );
 170 }
 171
 172 {
 173     my $index_not_private = $dispatcher->get_action_by_path(
 174                              '/action/chained/argsorder/index'
 175                             );
 176
 177     is(
 178       Catalyst::uri_for( $context, $index_not_private )->as_string,
 179       'http://127.0.0.1/argsorder',
 180       'Return non-DispatchType::Index path for index action with args'
 181     );
 182 }
 183
 184 done_testing;
 185