t/aggregate/unit_core_uri_for.t

   1 use strict;
   2 use warnings;
   3 use FindBin qw/$Bin/;
   4 use lib "$FindBin::Bin/../lib";
   5 use Test::More;
   6 use URI;
   7
   8 use_ok('TestApp');
   9
  10 my $request = Catalyst::Request->new( {
  11                 _log => Catalyst::Log->new,
  12                 base => URI->new('http://127.0.0.1/foo')
  13               } );
  14 my $dispatcher = TestApp->dispatcher;
  15 my $context = TestApp->new( {
  16                 request => $request,
  17                 namespace => 'yada',
  18               } );
  19
  20 is(
  21     Catalyst::uri_for( $context, '/bar/baz' )->as_string,
  22     'http://127.0.0.1/foo/bar/baz',
  23     'URI for absolute path'
  24 );
  25
  26 is(
  27     Catalyst::uri_for( $context, 'bar/baz' )->as_string,
  28     'http://127.0.0.1/foo/yada/bar/baz',
  29     'URI for relative path'
  30 );
  31
  32 is(
  33     Catalyst::uri_for( $context, '', 'arg1', 'arg2' )->as_string,
  34     'http://127.0.0.1/foo/yada/arg1/arg2',
  35     'URI for undef action with args'
  36 );
  37
  38
  39 is( Catalyst::uri_for( $context, '../quux' )->as_string,
  40     'http://127.0.0.1/foo/quux', 'URI for relative dot path' );
  41
  42 is(
  43     Catalyst::uri_for( $context, 'quux', { param1 => 'value1' } )->as_string,
  44     'http://127.0.0.1/foo/yada/quux?param1=value1',
  45     'URI for undef action with query params'
  46 );
  47
  48 is (Catalyst::uri_for( $context, '/bar/wibble?' )->as_string,
  49    'http://127.0.0.1/foo/bar/wibble%3F', 'Question Mark gets encoded'
  50 );
  51
  52 is( Catalyst::uri_for( $context, qw/bar wibble?/, 'with space' )->as_string,
  53     'http://127.0.0.1/foo/yada/bar/wibble%3F/with%20space', 'Space gets encoded'
  54 );
  55
  56 is(
  57     Catalyst::uri_for( $context, '/bar', 'with+plus', { 'also' => 'with+plus' })->as_string,
  58     'http://127.0.0.1/foo/bar/with+plus?also=with%2Bplus',
  59     'Plus is not encoded'
  60 );
  61
  62 is(
  63     Catalyst::uri_for( $context, '/bar#fragment', { param1 => 'value1' } )->as_string,
  64     'http://127.0.0.1/foo/bar?param1=value1#fragment',
  65     'URI for path with fragment and query params 1'
  66 );
  67
  68 is(
  69     Catalyst::uri_for( $context, '0#fragment', { param1 => 'value1' } )->as_string,
  70     'http://127.0.0.1/foo/yada/0?param1=value1#fragment',
  71     'URI for path 0 with fragment and query params 1'
  72 );
  73
  74 is(
  75     Catalyst::uri_for( $context, '/bar#fragment^%$', { param1 => 'value1' } )->as_string,
  76     'http://127.0.0.1/foo/bar?param1=value1#fragment^%$',
  77     'URI for path with fragment and query params 3'
  78 );
  79
  80 is(
  81     Catalyst::uri_for( $context, '/foo#bar/baz', { param1 => 'value1' } )->as_string,
  82     'http://127.0.0.1/foo/foo?param1=value1#bar/baz',
  83     'URI for path with fragment and query params 3'
  84 );
  85
  86 # test with utf-8
  87 is(
  88     Catalyst::uri_for( $context, 'quux', { param1 => "\x{2620}" } )->as_string,
  89     'http://127.0.0.1/foo/yada/quux?param1=%E2%98%A0',
  90     'URI for undef action with query params in unicode'
  91 );
  92 is(
  93     Catalyst::uri_for( $context, 'quux', { 'param:1' => "foo" } )->as_string,
  94     'http://127.0.0.1/foo/yada/quux?param%3A1=foo',
  95     'URI for undef action with query params in unicode'
  96 );
  97
  98 # test with object
  99 is(
 100     Catalyst::uri_for( $context, 'quux', { param1 => $request->base } )->as_string,
 101     'http://127.0.0.1/foo/yada/quux?param1=http%3A%2F%2F127.0.0.1%2Ffoo',
 102     'URI for undef action with query param as object'
 103   );
 104
 105 # test with empty arg
 106 {
 107     my @warnings;
 108     local $SIG{__WARN__} = sub { push @warnings, @_ };
 109     is(
 110        Catalyst::uri_for( $context )->as_string,
 111        'http://127.0.0.1/foo/yada',
 112        'URI with no action'
 113       );
 114
 115     is(
 116        Catalyst::uri_for( $context, 0 )->as_string,
 117        'http://127.0.0.1/foo/yada/0',
 118        'URI with 0 path'
 119       );
 120
 121     is_deeply(\@warnings, [], "No warnings with no path argument");
 122 }
 123
 124 $request->base( URI->new('http://localhost:3000/') );
 125 $request->match( 'orderentry/contract' );
 126 is(
 127     Catalyst::uri_for( $context, '/Orderentry/saveContract' )->as_string,
 128     'http://localhost:3000/Orderentry/saveContract',
 129     'URI for absolute path'
 130 );
 131
 132 {
 133     $request->base( URI->new('http://127.0.0.1/') );
 134
 135     $context->namespace('');
 136
 137     is( Catalyst::uri_for( $context, '/bar/baz' )->as_string,
 138         'http://127.0.0.1/bar/baz', 'URI with no base or match' );
 139
 140     # test "0" as the path
 141     is( Catalyst::uri_for( $context, qw/0 foo/ )->as_string,
 142         'http://127.0.0.1/0/foo', '0 as path is ok'
 143     );
 144
 145 }
 146
 147 # test with undef -- no warnings should be thrown
 148 {
 149     my $warnings = 0;
 150     local $SIG{__WARN__} = sub { $warnings++ };
 151
 152     Catalyst::uri_for( $context, '/bar/baz', { foo => undef } )->as_string,
 153     is( $warnings, 0, "no warnings emitted" );
 154 }
 155
 156 # Test with parameters '/', 'foo', 'bar' - should not generate a //
 157 is( Catalyst::uri_for( $context, qw| / foo bar | )->as_string,
 158     'http://127.0.0.1/foo/bar', 'uri is /foo/bar, not //foo/bar'
 159 );
 160
 161 TODO: {
 162     local $TODO = 'RFCs are for people who, erm - fix this test..';
 163     # Test rfc3986 reserved characters.  These characters should all be escaped
 164     # according to the RFC, but it is a very big feature change so I've removed it
 165     no warnings; # Yes, everything in qw is sane
 166     is(
 167         Catalyst::uri_for( $context, qw|! * ' ( ) ; : @ & = $ / ? % # [ ] ,|, )->as_string,
 168         'http://127.0.0.1/%21/%2A/%27/%2B/%29/%3B/%3A/%40/%26/%3D/%24/%2C/%2F/%3F/%25/%23/%5B/%5D',
 169         'rfc 3986 reserved characters'
 170     );
 171
 172     # jshirley bug - why the hell does only one of these get encoded
 173     #                has been like this forever however.
 174     is(
 175         Catalyst::uri_for( $context, qw|{1} {2}| )->as_string,
 176         'http://127.0.0.1/{1}/{2}',
 177         'not-escaping unreserved characters'
 178     );
 179 }
 180
 181 # make sure caller's query parameter hash isn't messed up
 182 {
 183     my $query_params_base = {test => "one two",
 184                              bar  => ["foo baz", "bar"]};
 185     my $query_params_test = {test => "one two",
 186                              bar  => ["foo baz", "bar"]};
 187     Catalyst::uri_for($context, '/bar/baz', $query_params_test);
 188     is_deeply($query_params_base, $query_params_test,
 189               "uri_for() doesn't mess up query parameter hash in the caller");
 190 }
 191
 192
 193 {
 194     my $path_action = $dispatcher->get_action_by_path(
 195                        '/action/path/six'
 196                      );
 197
 198     # 5.80018 is only encoding the first of the / in the arg.
 199     is(
 200         Catalyst::uri_for( $context, $path_action, 'foo/bar/baz' )->as_string,
 201         'http://127.0.0.1/action/path/six/foo%2Fbar%2Fbaz',
 202         'Escape all forward slashes in args as %2F'
 203     );
 204 }
 205
 206 {
 207     my $index_not_private = $dispatcher->get_action_by_path(
 208                              '/action/chained/argsorder/index'
 209                             );
 210
 211     is(
 212       Catalyst::uri_for( $context, $index_not_private )->as_string,
 213       'http://127.0.0.1/argsorder',
 214       'Return non-DispatchType::Index path for index action with args'
 215     );
 216 }
 217
 218 {
 219     package MyStringThing;
 220
 221     use overload '""' => sub { $_[0]->{string} }, fallback => 1;
 222 }
 223
 224 is(
 225     Catalyst::uri_for( $context, bless( { string => 'test' }, 'MyStringThing' ) ),
 226     'http://127.0.0.1/test',
 227     'overloaded object handled correctly'
 228 );
 229
 230 done_testing;