t/aggregate/live_engine_request_headers.t

   1 use strict;
   2 use warnings;
   3
   4 use FindBin;
   5 use lib "$FindBin::Bin/../lib";
   6
   7 use Test::More tests => 18;
   8 use Catalyst::Test 'TestApp';
   9
  10 use Catalyst::Request;
  11 use HTTP::Headers;
  12 use HTTP::Request::Common;
  13
  14 {
  15     my $creq;
  16
  17     my $request = GET( 'http://localhost/dump/request',
  18         'User-Agent'       => 'MyAgen/1.0',
  19         'X-Whats-Cool'     => 'Catalyst',
  20         'X-Multiple'       => [ 1 .. 5 ],
  21         'X-Forwarded-Host' => 'frontend.server.com',
  22         'X-Forwarded-For'  => '192.168.1.1, 1.2.3.4',
  23         'X-Forwarded-Port' => 443
  24     );
  25
  26     ok( my $response = request($request), 'Request' );
  27     ok( $response->is_success, 'Response Successful 2xx' );
  28     is( $response->content_type, 'text/plain', 'Response Content-Type' );
  29     like( $response->content, qr/^bless\( .* 'Catalyst::Request' \)$/s, 'Content is a serialized Catalyst::Request' );
  30     ok( eval '$creq = ' . $response->content, 'Unserialize Catalyst::Request' ) or fail("Exception deseializing $@ from content " . $response->content);
  31     isa_ok( $creq, 'Catalyst::Request' );
  32     ok( $creq->secure, 'Forwarded port sets secure' );
  33     isa_ok( $creq->headers, 'HTTP::Headers', 'Catalyst::Request->headers' );
  34     is( $creq->header('X-Whats-Cool'), $request->header('X-Whats-Cool'), 'Catalyst::Request->header X-Whats-Cool' );
  35
  36     { # Test that multiple headers are joined as per RFC 2616 4.2 and RFC 3875 4.1.18
  37
  38         my $excpected = '1, 2, 3, 4, 5';
  39         my $got       = $creq->header('X-Multiple'); # HTTP::Headers is context sensitive, "force" scalar context
  40
  41         is( $got, $excpected, 'Multiple message-headers are joined as a comma-separated list' );
  42     }
  43
  44     is( $creq->header('User-Agent'), $request->header('User-Agent'), 'Catalyst::Request->header User-Agent' );
  45
  46     my $host = sprintf( '%s:%d', $request->header('X-Forwarded-Host'), $request->header('X-Forwarded-Port') );
  47     is( $creq->header('Host'), $host, 'Catalyst::Request->header Host' );
  48
  49     SKIP:
  50     {
  51         if ( $ENV{CATALYST_SERVER} && $ENV{CATALYST_SERVER} !~ /127.0.0.1|localhost/ ) {
  52             skip "Using remote server", 2;
  53         }
  54
  55         is( $creq->base->host, 'frontend.server.com', 'Catalyst::Request proxied base' );
  56         is( $creq->address, '1.2.3.4', 'Catalyst::Request proxied address' );
  57     }
  58
  59     SKIP:
  60     {
  61         if ( $ENV{CATALYST_SERVER} ) {
  62             skip "Using remote server", 4;
  63         }
  64         # test that we can ignore the proxy support
  65         TestApp->config->{ignore_frontend_proxy} = 1;
  66         ok( $response = request($request), 'Request' );
  67         ok( eval '$creq = ' . $response->content, 'Unserialize Catalyst::Request' );
  68         is( $creq->base, 'http://localhost/', 'Catalyst::Request non-proxied base' );
  69         is( $creq->address, '127.0.0.1', 'Catalyst::Request non-proxied address' );
  70     }
  71 }