lib/Catalyst/Utils.pm

   1 package Catalyst::Utils;
   2
   3 use strict;
   4 use Catalyst::Exception;
   5 use File::Spec;
   6 use HTTP::Request;
   7 use Path::Class;
   8 use URI;
   9 use Class::Inspector;
  10
  11 =head1 NAME
  12
  13 Catalyst::Utils - The Catalyst Utils
  14
  15 =head1 SYNOPSIS
  16
  17 See L<Catalyst>.
  18
  19 =head1 DESCRIPTION
  20
  21 =head1 METHODS
  22
  23 =head2 appprefix($class)
  24
  25         MyApp::Foo becomes myapp_foo
  26
  27 =cut
  28
  29 sub appprefix {
  30     my $class = shift;
  31     $class =~ s/\:\:/_/g;
  32     $class = lc($class);
  33     return $class;
  34 }
  35
  36 =head2 class2appclass($class);
  37
  38     MyApp::C::Foo::Bar becomes MyApp
  39     My::App::C::Foo::Bar becomes My::App
  40
  41 =cut
  42
  43 sub class2appclass {
  44     my $class = shift || '';
  45     my $appname = '';
  46     if ( $class =~ /^(.*)::([MVC]|Model|View|Controller)?::.*$/ ) {
  47         $appname = $1;
  48     }
  49     return $appname;
  50 }
  51
  52 =head2 class2classprefix($class);
  53
  54     MyApp::C::Foo::Bar becomes MyApp::C
  55     My::App::C::Foo::Bar becomes My::App::C
  56
  57 =cut
  58
  59 sub class2classprefix {
  60     my $class = shift || '';
  61     my $prefix;
  62     if ( $class =~ /^(.*::[MVC]|Model|View|Controller)?::.*$/ ) {
  63         $prefix = $1;
  64     }
  65     return $prefix;
  66 }
  67
  68 =head2 class2classsuffix($class);
  69
  70     MyApp::C::Foo::Bar becomes C::Foo::Bar
  71
  72 =cut
  73
  74 sub class2classsuffix {
  75     my $class = shift || '';
  76     my $prefix = class2appclass($class) || '';
  77     $class =~ s/$prefix\:\://;
  78     return $class;
  79 }
  80
  81 =head2 class2env($class);
  82
  83 Returns the environment name for class.
  84
  85     MyApp becomes MYAPP
  86     My::App becomes MY_APP
  87
  88 =cut
  89
  90 sub class2env {
  91     my $class = shift || '';
  92     $class =~ s/\:\:/_/g;
  93     return uc($class);
  94 }
  95
  96 =head2 class2prefix( $class, $case );
  97
  98 Returns the uri prefix for a class. If case is false the prefix is converted to lowercase.
  99
 100     My::App::C::Foo::Bar becomes foo/bar
 101
 102 =cut
 103
 104 sub class2prefix {
 105     my $class = shift || '';
 106     my $case  = shift || 0;
 107     my $prefix;
 108     if ( $class =~ /^.*::([MVC]|Model|View|Controller)?::(.*)$/ ) {
 109         $prefix = $case ? $2 : lc $2;
 110         $prefix =~ s/\:\:/\//g;
 111     }
 112     return $prefix;
 113 }
 114
 115 =head2 class2tempdir( $class [, $create ] );
 116
 117 Returns a tempdir for a class. If create is true it will try to create the path.
 118
 119     My::App becomes /tmp/my/app
 120     My::App::C::Foo::Bar becomes /tmp/my/app/c/foo/bar
 121
 122 =cut
 123
 124 sub class2tempdir {
 125     my $class  = shift || '';
 126     my $create = shift || 0;
 127     my @parts = split '::', lc $class;
 128
 129     my $tmpdir = dir( File::Spec->tmpdir, @parts )->cleanup;
 130
 131     if ( $create && !-e $tmpdir ) {
 132
 133         eval { $tmpdir->mkpath };
 134
 135         if ($@) {
 136             Catalyst::Exception->throw(
 137                 message => qq/Couldn't create tmpdir '$tmpdir', "$@"/ );
 138         }
 139     }
 140
 141     return $tmpdir->stringify;
 142 }
 143
 144 =head2 home($class)
 145
 146 Returns home directory for given class.
 147
 148 =cut
 149
 150 sub home {
 151     my $name = shift;
 152     $name =~ s/\:\:/\//g;
 153     my $home = 0;
 154     if ( my $path = $INC{"$name.pm"} ) {
 155         $home = file($path)->absolute->dir;
 156         $name =~ /(\w+)$/;
 157         my $append = $1;
 158         my $subdir = dir($home)->subdir($append);
 159         for ( split '/', $name ) { $home = dir($home)->parent }
 160         if ( $home =~ /blib$/ ) { $home = dir($home)->parent }
 161         elsif (!-f file( $home, 'Makefile.PL' )
 162             && !-f file( $home, 'Build.PL' ) )
 163         {
 164             $home = $subdir;
 165         }
 166
 167         # clean up relative path:
 168         # MyApp/script/.. -> MyApp
 169         my ($lastdir) = $home->dir_list( -1, 1 );
 170         if ( $lastdir eq '..' ) {
 171             $home = dir($home)->parent->parent;
 172         }
 173     }
 174     return $home;
 175 }
 176
 177 =head2 prefix($class, $name);
 178
 179 Returns a prefixed action.
 180
 181     MyApp::C::Foo::Bar, yada becomes foo/bar/yada
 182
 183 =cut
 184
 185 sub prefix {
 186     my ( $class, $name ) = @_;
 187     my $prefix = &class2prefix($class);
 188     $name = "$prefix/$name" if $prefix;
 189     return $name;
 190 }
 191
 192 =head2 request($uri)
 193
 194 Returns an L<HTTP::Request> object for a uri.
 195
 196 =cut
 197
 198 sub request {
 199     my $request = shift;
 200     unless ( ref $request ) {
 201         if ( $request =~ m/^http/i ) {
 202             $request = URI->new($request)->canonical;
 203         }
 204         else {
 205             $request = URI->new( 'http://localhost' . $request )->canonical;
 206         }
 207     }
 208     unless ( ref $request eq 'HTTP::Request' ) {
 209         $request = HTTP::Request->new( 'GET', $request );
 210     }
 211     return $request;
 212 }
 213
 214 =head2 ensure_class_loaded($class_name)
 215
 216 Loads the class unless it already has been loaded.
 217
 218 =cut
 219
 220 sub ensure_class_loaded {
 221     my $class = shift;
 222
 223     return if Class::Inspector->loaded( $class ); # if a symbol entry exists we don't load again
 224
 225     # this hack is so we don't overwrite $@ if the load did not generate an error
 226     my $error;
 227     {
 228         local $@;
 229         eval "require $class";
 230         $error = $@;
 231     }
 232     die $error if $error;
 233 }
 234
 235
 236 =head1 AUTHOR
 237
 238 Sebastian Riedel, C<sri@cpan.org>
 239 Yuval Kogman, C<nothingmuch@woobling.org>
 240
 241 =head1 COPYRIGHT
 242
 243 This program is free software, you can redistribute it and/or modify it under
 244 the same terms as Perl itself.
 245
 246 =cut
 247
 248 1;