lib/Catalyst/Utils.pm

   1 package Catalyst::Utils;
   2
   3 use strict;
   4 use File::Spec;
   5 use HTTP::Request;
   6 use Path::Class;
   7 use URI;
   8 use Carp qw/croak/;
   9 use FindBin qw/ $Bin /;
  10 use Class::MOP;
  11 use String::RewritePrefix;
  12 use List::MoreUtils qw/ any /;
  13
  14 use namespace::clean;
  15
  16 =head1 NAME
  17
  18 Catalyst::Utils - The Catalyst Utils
  19
  20 =head1 SYNOPSIS
  21
  22 See L<Catalyst>.
  23
  24 =head1 DESCRIPTION
  25
  26 Catalyst Utilities.
  27
  28 =head1 METHODS
  29
  30 =head2 appprefix($class)
  31
  32     MyApp::Foo becomes myapp_foo
  33
  34 =cut
  35
  36 sub appprefix {
  37     my $class = shift;
  38     $class =~ s/::/_/g;
  39     $class = lc($class);
  40     return $class;
  41 }
  42
  43 =head2 class2appclass($class);
  44
  45     MyApp::Controller::Foo::Bar becomes MyApp
  46     My::App::Controller::Foo::Bar becomes My::App
  47
  48 =cut
  49
  50 sub class2appclass {
  51     my $class = shift || '';
  52     my $appname = '';
  53     if ( $class =~ /^(.+?)::([MVC]|Model|View|Controller)::.+$/ ) {
  54         $appname = $1;
  55     }
  56     return $appname;
  57 }
  58
  59 =head2 class2classprefix($class);
  60
  61     MyApp::Controller::Foo::Bar becomes MyApp::Controller
  62     My::App::Controller::Foo::Bar becomes My::App::Controller
  63
  64 =cut
  65
  66 sub class2classprefix {
  67     my $class = shift || '';
  68     my $prefix;
  69     if ( $class =~ /^(.+?::([MVC]|Model|View|Controller))::.+$/ ) {
  70         $prefix = $1;
  71     }
  72     return $prefix;
  73 }
  74
  75 =head2 class2classsuffix($class);
  76
  77     MyApp::Controller::Foo::Bar becomes Controller::Foo::Bar
  78
  79 =cut
  80
  81 sub class2classsuffix {
  82     my $class = shift || '';
  83     my $prefix = class2appclass($class) || '';
  84     $class =~ s/$prefix\:://;
  85     return $class;
  86 }
  87
  88 =head2 class2env($class);
  89
  90 Returns the environment name for class.
  91
  92     MyApp becomes MYAPP
  93     My::App becomes MY_APP
  94
  95 =cut
  96
  97 sub class2env {
  98     my $class = shift || '';
  99     $class =~ s/::/_/g;
 100     return uc($class);
 101 }
 102
 103 =head2 class2prefix( $class, $case );
 104
 105 Returns the uri prefix for a class. If case is false the prefix is converted to lowercase.
 106
 107     My::App::Controller::Foo::Bar becomes foo/bar
 108
 109 =cut
 110
 111 sub class2prefix {
 112     my $class = shift || '';
 113     my $case  = shift || 0;
 114     my $prefix;
 115     if ( $class =~ /^.+?::([MVC]|Model|View|Controller)::(.+)$/ ) {
 116         $prefix = $case ? $2 : lc $2;
 117         $prefix =~ s{::}{/}g;
 118     }
 119     return $prefix;
 120 }
 121
 122 =head2 class2tempdir( $class [, $create ] );
 123
 124 Returns a tempdir for a class. If create is true it will try to create the path.
 125
 126     My::App becomes /tmp/my/app
 127     My::App::Controller::Foo::Bar becomes /tmp/my/app/c/foo/bar
 128
 129 =cut
 130
 131 sub class2tempdir {
 132     my $class  = shift || '';
 133     my $create = shift || 0;
 134     my @parts = split '::', lc $class;
 135
 136     my $tmpdir = dir( File::Spec->tmpdir, @parts )->cleanup;
 137
 138     if ( $create && !-e $tmpdir ) {
 139
 140         eval { $tmpdir->mkpath };
 141
 142         if ($@) {
 143             # don't load Catalyst::Exception as a BEGIN in Utils,
 144             # because Utils often gets loaded before MyApp.pm, and if
 145             # Catalyst::Exception is loaded before MyApp.pm, it does
 146             # not honor setting
 147             # $Catalyst::Exception::CATALYST_EXCEPTION_CLASS in
 148             # MyApp.pm
 149             require Catalyst::Exception;
 150             Catalyst::Exception->throw(
 151                 message => qq/Couldn't create tmpdir '$tmpdir', "$@"/ );
 152         }
 153     }
 154
 155     return $tmpdir->stringify;
 156 }
 157
 158 =head2 dist_indicator_file_list
 159
 160 Returns a list of files which can be tested to check if you're inside a checkout
 161
 162 =cut
 163
 164 sub dist_indicator_file_list {
 165     qw/ Makefile.PL Build.PL dist.ini /;
 166 }
 167
 168 =head2 home($class)
 169
 170 Returns home directory for given class.
 171
 172 Note that the class must be loaded for the home directory to be found using this function.
 173
 174 =cut
 175
 176 sub home {
 177     my $class = shift;
 178
 179     # make an $INC{ $key } style string from the class name
 180     (my $file = "$class.pm") =~ s{::}{/}g;
 181
 182     if ( my $inc_entry = $INC{$file} ) {
 183         {
 184             # look for an uninstalled Catalyst app
 185
 186             # find the @INC entry in which $file was found
 187             (my $path = $inc_entry) =~ s/$file$//;
 188             my $home = find_home_unloaded_in_checkout($path);
 189             return $home if $home;
 190         }
 191
 192         {
 193             # look for an installed Catalyst app
 194
 195             # trim the .pm off the thing ( Foo/Bar.pm -> Foo/Bar/ )
 196             ( my $path = $inc_entry) =~ s/\.pm$//;
 197             my $home = dir($path)->absolute->cleanup;
 198
 199             # return if if it's a valid directory
 200             return $home->stringify if -d $home;
 201         }
 202     }
 203
 204     # we found nothing
 205     return 0;
 206 }
 207
 208 =head2 find_home_unloaded_in_checkout ($path)
 209
 210 Tries to determine if C<$path> (or $FindBin::Bin if not supplied)
 211 looks like a checkout. Any leading lib, script or blib components
 212 will be removed, then the directory produced will be checked
 213 for the existence of a C<< dist_indicator_file_list() >>.
 214
 215 If one is found, the directory will be returned, otherwise false.
 216
 217 =cut
 218
 219 sub find_home_unloaded_in_checkout {
 220     my ($path) = @_;
 221     $path ||= $Bin if !defined $path || !length $path;
 222     my $home = dir($path)->absolute->cleanup;
 223
 224     # pop off /lib and /blib if they're there
 225     $home = $home->parent while $home =~ /b?lib$/;
 226     # pop off /script if it's there.
 227     $home = $home->parent while $home =~ /b?script$/;
 228
 229     # only return the dir if it has a Makefile.PL or Build.PL or dist.ini
 230     if (any { $_ } map { -f $home->file($_) } dist_indicator_file_list()) {
 231
 232         # clean up relative path:
 233         # MyApp/script/.. -> MyApp
 234
 235         my $dir;
 236         my @dir_list = $home->dir_list();
 237         while (($dir = pop(@dir_list)) && $dir eq '..') {
 238             $home = dir($home)->parent->parent;
 239         }
 240
 241         return $home->stringify;
 242     }
 243
 244 }
 245
 246 =head2 prefix($class, $name);
 247
 248 Returns a prefixed action.
 249
 250     MyApp::Controller::Foo::Bar, yada becomes foo/bar/yada
 251
 252 =cut
 253
 254 sub prefix {
 255     my ( $class, $name ) = @_;
 256     my $prefix = &class2prefix($class);
 257     $name = "$prefix/$name" if $prefix;
 258     return $name;
 259 }
 260
 261 =head2 request($uri)
 262
 263 Returns an L<HTTP::Request> object for a uri.
 264
 265 =cut
 266
 267 sub request {
 268     my $request = shift;
 269     unless ( ref $request ) {
 270         if ( $request =~ m/^http/i ) {
 271             $request = URI->new($request);
 272         }
 273         else {
 274             $request = URI->new( 'http://localhost' . $request );
 275         }
 276     }
 277     unless ( ref $request eq 'HTTP::Request' ) {
 278         $request = HTTP::Request->new( 'GET', $request );
 279     }
 280     return $request;
 281 }
 282
 283 =head2 ensure_class_loaded($class_name, \%opts)
 284
 285 Loads the class unless it already has been loaded.
 286
 287 If $opts{ignore_loaded} is true always tries the require whether the package
 288 already exists or not. Only pass this if you're either (a) sure you know the
 289 file exists on disk or (b) have code to catch the file not found exception
 290 that will result if it doesn't.
 291
 292 =cut
 293
 294 sub ensure_class_loaded {
 295     my $class = shift;
 296     my $opts  = shift;
 297
 298     croak "Malformed class Name $class"
 299         if $class =~ m/(?:\b\:\b|\:{3,})/;
 300
 301     croak "Malformed class Name $class"
 302         if $class =~ m/[^\w:]/;
 303
 304     croak "ensure_class_loaded should be given a classname, not a filename ($class)"
 305         if $class =~ m/\.pm$/;
 306
 307     # $opts->{ignore_loaded} can be set to true, and this causes the class to be required, even
 308     # if it already has symbol table entries. This is to support things like Schema::Loader, which
 309     # part-generate classes in memory, but then also load some of their contents from disk.
 310     return if !$opts->{ ignore_loaded }
 311         && Class::MOP::is_class_loaded($class); # if a symbol entry exists we don't load again
 312
 313     # this hack is so we don't overwrite $@ if the load did not generate an error
 314     my $error;
 315     {
 316         local $@;
 317         my $file = $class . '.pm';
 318         $file =~ s{::}{/}g;
 319         eval { CORE::require($file) };
 320         $error = $@;
 321     }
 322
 323     die $error if $error;
 324
 325     warn "require $class was successful but the package is not defined."
 326         unless Class::MOP::is_class_loaded($class);
 327
 328     return 1;
 329 }
 330
 331 =head2 merge_hashes($hashref, $hashref)
 332
 333 Base code to recursively merge two hashes together with right-hand precedence.
 334
 335 =cut
 336
 337 sub merge_hashes {
 338     my ( $lefthash, $righthash ) = @_;
 339
 340     return $lefthash unless defined $righthash;
 341
 342     my %merged = %$lefthash;
 343     for my $key ( keys %$righthash ) {
 344         my $right_ref = ( ref $righthash->{ $key } || '' ) eq 'HASH';
 345         my $left_ref  = ( ( exists $lefthash->{ $key } && ref $lefthash->{ $key } ) || '' ) eq 'HASH';
 346         if( $right_ref and $left_ref ) {
 347             $merged{ $key } = merge_hashes(
 348                 $lefthash->{ $key }, $righthash->{ $key }
 349             );
 350         }
 351         else {
 352             $merged{ $key } = $righthash->{ $key };
 353         }
 354     }
 355
 356     return \%merged;
 357 }
 358
 359 =head2 env_value($class, $key)
 360
 361 Checks for and returns an environment value. For instance, if $key is
 362 'home', then this method will check for and return the first value it finds,
 363 looking at $ENV{MYAPP_HOME} and $ENV{CATALYST_HOME}.
 364
 365 =cut
 366
 367 sub env_value {
 368     my ( $class, $key ) = @_;
 369
 370     $key = uc($key);
 371     my @prefixes = ( class2env($class), 'CATALYST' );
 372
 373     for my $prefix (@prefixes) {
 374         if ( defined( my $value = $ENV{"${prefix}_${key}"} ) ) {
 375             return $value;
 376         }
 377     }
 378
 379     return;
 380 }
 381
 382 =head2 term_width
 383
 384 Try to guess terminal width to use with formatting of debug output
 385
 386 All you need to get this work, is:
 387
 388 1) Install Term::Size::Any, or
 389
 390 2) Export $COLUMNS from your shell.
 391
 392 (Warning to bash users: 'echo $COLUMNS' may be showing you the bash
 393 variable, not $ENV{COLUMNS}. 'export COLUMNS=$COLUMNS' and you should see
 394 that 'env' now lists COLUMNS.)
 395
 396 As last resort, default value of 80 chars will be used.
 397
 398 =cut
 399
 400 my $_term_width;
 401
 402 sub term_width {
 403     return $_term_width if $_term_width;
 404
 405     my $width = eval '
 406         use Term::Size::Any;
 407         my ($columns, $rows) = Term::Size::Any::chars;
 408         return $columns;
 409     ';
 410
 411     if ($@) {
 412         $width = $ENV{COLUMNS}
 413             if exists($ENV{COLUMNS})
 414             && $ENV{COLUMNS} =~ m/^\d+$/;
 415     }
 416
 417     $width = 80 unless ($width && $width >= 80);
 418     return $_term_width = $width;
 419 }
 420
 421
 422 =head2 resolve_namespace
 423
 424 Method which adds the namespace for plugins and actions.
 425
 426   __PACKAGE__->setup(qw(MyPlugin));
 427
 428   # will load Catalyst::Plugin::MyPlugin
 429
 430 =cut
 431
 432
 433 sub resolve_namespace {
 434     my $appnamespace = shift;
 435     my $namespace = shift;
 436     my @classes = @_;
 437     return String::RewritePrefix->rewrite({
 438         q[]  => qq[${namespace}::],
 439         q[+] => q[],
 440         (defined $appnamespace
 441             ? (q[~] => qq[${appnamespace}::])
 442             : ()
 443         ),
 444     }, @classes);
 445 }
 446
 447
 448 =head1 AUTHORS
 449
 450 Catalyst Contributors, see Catalyst.pm
 451
 452 =head1 COPYRIGHT
 453
 454 This library is free software. You can redistribute it and/or modify it under
 455 the same terms as Perl itself.
 456
 457 =cut
 458
 459 1;