lib/Catalyst/Utils.pm

   1 package Catalyst::Utils;
   2
   3 use strict;
   4 use File::Spec;
   5 use HTTP::Request;
   6 use Path::Class;
   7 use URI;
   8 use Carp qw/croak/;
   9 use Cwd;
  10 use Class::MOP;
  11 use String::RewritePrefix;
  12 use List::MoreUtils qw/ any /;
  13
  14 use namespace::clean;
  15
  16 =head1 NAME
  17
  18 Catalyst::Utils - The Catalyst Utils
  19
  20 =head1 SYNOPSIS
  21
  22 See L<Catalyst>.
  23
  24 =head1 DESCRIPTION
  25
  26 Catalyst Utilities.
  27
  28 =head1 METHODS
  29
  30 =head2 appprefix($class)
  31
  32     MyApp::Foo becomes myapp_foo
  33
  34 =cut
  35
  36 sub appprefix {
  37     my $class = shift;
  38     $class =~ s/::/_/g;
  39     $class = lc($class);
  40     return $class;
  41 }
  42
  43 =head2 class2appclass($class);
  44
  45     MyApp::Controller::Foo::Bar becomes MyApp
  46     My::App::Controller::Foo::Bar becomes My::App
  47
  48 =cut
  49
  50 sub class2appclass {
  51     my $class = shift || '';
  52     my $appname = '';
  53     if ( $class =~ /^(.+?)::([MVC]|Model|View|Controller)::.+$/ ) {
  54         $appname = $1;
  55     }
  56     return $appname;
  57 }
  58
  59 =head2 class2classprefix($class);
  60
  61     MyApp::Controller::Foo::Bar becomes MyApp::Controller
  62     My::App::Controller::Foo::Bar becomes My::App::Controller
  63
  64 =cut
  65
  66 sub class2classprefix {
  67     my $class = shift || '';
  68     my $prefix;
  69     if ( $class =~ /^(.+?::([MVC]|Model|View|Controller))::.+$/ ) {
  70         $prefix = $1;
  71     }
  72     return $prefix;
  73 }
  74
  75 =head2 class2classsuffix($class);
  76
  77     MyApp::Controller::Foo::Bar becomes Controller::Foo::Bar
  78
  79 =cut
  80
  81 sub class2classsuffix {
  82     my $class = shift || '';
  83     my $prefix = class2appclass($class) || '';
  84     $class =~ s/$prefix\:://;
  85     return $class;
  86 }
  87
  88 =head2 class2env($class);
  89
  90 Returns the environment name for class.
  91
  92     MyApp becomes MYAPP
  93     My::App becomes MY_APP
  94
  95 =cut
  96
  97 sub class2env {
  98     my $class = shift || '';
  99     $class =~ s/::/_/g;
 100     return uc($class);
 101 }
 102
 103 =head2 class2prefix( $class, $case );
 104
 105 Returns the uri prefix for a class. If case is false the prefix is converted to lowercase.
 106
 107     My::App::Controller::Foo::Bar becomes foo/bar
 108
 109 =cut
 110
 111 sub class2prefix {
 112     my $class = shift || '';
 113     my $case  = shift || 0;
 114     my $prefix;
 115     if ( $class =~ /^.+?::([MVC]|Model|View|Controller)::(.+)$/ ) {
 116         $prefix = $case ? $2 : lc $2;
 117         $prefix =~ s{::}{/}g;
 118     }
 119     return $prefix;
 120 }
 121
 122 =head2 class2tempdir( $class [, $create ] );
 123
 124 Returns a tempdir for a class. If create is true it will try to create the path.
 125
 126     My::App becomes /tmp/my/app
 127     My::App::Controller::Foo::Bar becomes /tmp/my/app/c/foo/bar
 128
 129 =cut
 130
 131 sub class2tempdir {
 132     my $class  = shift || '';
 133     my $create = shift || 0;
 134     my @parts = split '::', lc $class;
 135
 136     my $tmpdir = dir( File::Spec->tmpdir, @parts )->cleanup;
 137
 138     if ( $create && !-e $tmpdir ) {
 139
 140         eval { $tmpdir->mkpath };
 141
 142         if ($@) {
 143             # don't load Catalyst::Exception as a BEGIN in Utils,
 144             # because Utils often gets loaded before MyApp.pm, and if
 145             # Catalyst::Exception is loaded before MyApp.pm, it does
 146             # not honor setting
 147             # $Catalyst::Exception::CATALYST_EXCEPTION_CLASS in
 148             # MyApp.pm
 149             require Catalyst::Exception;
 150             Catalyst::Exception->throw(
 151                 message => qq/Couldn't create tmpdir '$tmpdir', "$@"/ );
 152         }
 153     }
 154
 155     return $tmpdir->stringify;
 156 }
 157
 158 =head2 dist_indicator_file_list
 159
 160 Returns a list of files which can be tested to check if you're inside a checkout
 161
 162 =cut
 163
 164 sub dist_indicator_file_list {
 165     qw/ Makefile.PL Build.PL dist.init /;
 166 }
 167
 168 =head2 home($class)
 169
 170 Returns home directory for given class.
 171
 172 Note that the class must be loaded for the home directory to be found using this function.
 173
 174 =cut
 175
 176 sub home {
 177     my $class = shift;
 178
 179     # make an $INC{ $key } style string from the class name
 180     (my $file = "$class.pm") =~ s{::}{/}g;
 181
 182     if ( my $inc_entry = $INC{$file} ) {
 183         {
 184             # look for an uninstalled Catalyst app
 185
 186             # find the @INC entry in which $file was found
 187             (my $path = $inc_entry) =~ s/$file$//;
 188             my $home = find_home_unloaded_in_checkout($path);
 189             return $home if $home;
 190         }
 191
 192         {
 193             # look for an installed Catalyst app
 194
 195             # trim the .pm off the thing ( Foo/Bar.pm -> Foo/Bar/ )
 196             ( my $path = $inc_entry) =~ s/\.pm$//;
 197             my $home = dir($path)->absolute->cleanup;
 198
 199             # return if if it's a valid directory
 200             return $home->stringify if -d $home;
 201         }
 202     }
 203
 204     # we found nothing
 205     return 0;
 206 }
 207
 208 =head2 find_home_unloaded_in_checkout ($path)
 209
 210 Tries to determine if C<$path> (or cwd if not supplied)
 211 looks like a checkout. Any leading lib or blib components
 212 will be removed, then the directory produced will be checked
 213 for the existence of a C<< dist_indicator_file_list() >>.
 214
 215 If one is found, the directory will be returned, otherwise false.
 216
 217 =cut
 218
 219 sub find_home_unloaded_in_checkout {
 220     my ($path) = @_;
 221     $path ||= cwd() if !defined $path || !length $path;
 222     my $home = dir($path)->absolute->cleanup;
 223
 224     # pop off /lib and /blib if they're there
 225     $home = $home->parent while $home =~ /b?lib$/;
 226
 227     # only return the dir if it has a Makefile.PL or Build.PL or dist.ini
 228     if (any { $_ } map { -f $home->file($_) } dist_indicator_file_list()) {
 229
 230         # clean up relative path:
 231         # MyApp/script/.. -> MyApp
 232
 233         my $dir;
 234         my @dir_list = $home->dir_list();
 235         while (($dir = pop(@dir_list)) && $dir eq '..') {
 236             $home = dir($home)->parent->parent;
 237         }
 238
 239         return $home->stringify;
 240     }
 241
 242 }
 243
 244 =head2 prefix($class, $name);
 245
 246 Returns a prefixed action.
 247
 248     MyApp::Controller::Foo::Bar, yada becomes foo/bar/yada
 249
 250 =cut
 251
 252 sub prefix {
 253     my ( $class, $name ) = @_;
 254     my $prefix = &class2prefix($class);
 255     $name = "$prefix/$name" if $prefix;
 256     return $name;
 257 }
 258
 259 =head2 request($uri)
 260
 261 Returns an L<HTTP::Request> object for a uri.
 262
 263 =cut
 264
 265 sub request {
 266     my $request = shift;
 267     unless ( ref $request ) {
 268         if ( $request =~ m/^http/i ) {
 269             $request = URI->new($request);
 270         }
 271         else {
 272             $request = URI->new( 'http://localhost' . $request );
 273         }
 274     }
 275     unless ( ref $request eq 'HTTP::Request' ) {
 276         $request = HTTP::Request->new( 'GET', $request );
 277     }
 278     return $request;
 279 }
 280
 281 =head2 ensure_class_loaded($class_name, \%opts)
 282
 283 Loads the class unless it already has been loaded.
 284
 285 If $opts{ignore_loaded} is true always tries the require whether the package
 286 already exists or not. Only pass this if you're either (a) sure you know the
 287 file exists on disk or (b) have code to catch the file not found exception
 288 that will result if it doesn't.
 289
 290 =cut
 291
 292 sub ensure_class_loaded {
 293     my $class = shift;
 294     my $opts  = shift;
 295
 296     croak "Malformed class Name $class"
 297         if $class =~ m/(?:\b\:\b|\:{3,})/;
 298
 299     croak "Malformed class Name $class"
 300         if $class =~ m/[^\w:]/;
 301
 302     croak "ensure_class_loaded should be given a classname, not a filename ($class)"
 303         if $class =~ m/\.pm$/;
 304
 305     # $opts->{ignore_loaded} can be set to true, and this causes the class to be required, even
 306     # if it already has symbol table entries. This is to support things like Schema::Loader, which
 307     # part-generate classes in memory, but then also load some of their contents from disk.
 308     return if !$opts->{ ignore_loaded }
 309         && Class::MOP::is_class_loaded($class); # if a symbol entry exists we don't load again
 310
 311     # this hack is so we don't overwrite $@ if the load did not generate an error
 312     my $error;
 313     {
 314         local $@;
 315         my $file = $class . '.pm';
 316         $file =~ s{::}{/}g;
 317         eval { CORE::require($file) };
 318         $error = $@;
 319     }
 320
 321     die $error if $error;
 322
 323     warn "require $class was successful but the package is not defined."
 324         unless Class::MOP::is_class_loaded($class);
 325
 326     return 1;
 327 }
 328
 329 =head2 merge_hashes($hashref, $hashref)
 330
 331 Base code to recursively merge two hashes together with right-hand precedence.
 332
 333 =cut
 334
 335 sub merge_hashes {
 336     my ( $lefthash, $righthash ) = @_;
 337
 338     return $lefthash unless defined $righthash;
 339
 340     my %merged = %$lefthash;
 341     for my $key ( keys %$righthash ) {
 342         my $right_ref = ( ref $righthash->{ $key } || '' ) eq 'HASH';
 343         my $left_ref  = ( ( exists $lefthash->{ $key } && ref $lefthash->{ $key } ) || '' ) eq 'HASH';
 344         if( $right_ref and $left_ref ) {
 345             $merged{ $key } = merge_hashes(
 346                 $lefthash->{ $key }, $righthash->{ $key }
 347             );
 348         }
 349         else {
 350             $merged{ $key } = $righthash->{ $key };
 351         }
 352     }
 353
 354     return \%merged;
 355 }
 356
 357 =head2 env_value($class, $key)
 358
 359 Checks for and returns an environment value. For instance, if $key is
 360 'home', then this method will check for and return the first value it finds,
 361 looking at $ENV{MYAPP_HOME} and $ENV{CATALYST_HOME}.
 362
 363 =cut
 364
 365 sub env_value {
 366     my ( $class, $key ) = @_;
 367
 368     $key = uc($key);
 369     my @prefixes = ( class2env($class), 'CATALYST' );
 370
 371     for my $prefix (@prefixes) {
 372         if ( defined( my $value = $ENV{"${prefix}_${key}"} ) ) {
 373             return $value;
 374         }
 375     }
 376
 377     return;
 378 }
 379
 380 =head2 term_width
 381
 382 Try to guess terminal width to use with formatting of debug output
 383
 384 All you need to get this work, is:
 385
 386 1) Install Term::Size::Any, or
 387
 388 2) Export $COLUMNS from your shell.
 389
 390 (Warning to bash users: 'echo $COLUMNS' may be showing you the bash
 391 variable, not $ENV{COLUMNS}. 'export COLUMNS=$COLUMNS' and you should see
 392 that 'env' now lists COLUMNS.)
 393
 394 As last resort, default value of 80 chars will be used.
 395
 396 =cut
 397
 398 my $_term_width;
 399
 400 sub term_width {
 401     return $_term_width if $_term_width;
 402
 403     my $width = eval '
 404         use Term::Size::Any;
 405         my ($columns, $rows) = Term::Size::Any::chars;
 406         return $columns;
 407     ';
 408
 409     if ($@) {
 410         $width = $ENV{COLUMNS}
 411             if exists($ENV{COLUMNS})
 412             && $ENV{COLUMNS} =~ m/^\d+$/;
 413     }
 414
 415     $width = 80 unless ($width && $width >= 80);
 416     return $_term_width = $width;
 417 }
 418
 419
 420 =head2 resolve_namespace
 421
 422 Method which adds the namespace for plugins and actions.
 423
 424   __PACKAGE__->setup(qw(MyPlugin));
 425
 426   # will load Catalyst::Plugin::MyPlugin
 427
 428 =cut
 429
 430
 431 sub resolve_namespace {
 432     my $appnamespace = shift;
 433     my $namespace = shift;
 434     my @classes = @_;
 435     return String::RewritePrefix->rewrite({
 436         q[]  => qq[${namespace}::],
 437         q[+] => q[],
 438         (defined $appnamespace
 439             ? (q[~] => qq[${appnamespace}::])
 440             : ()
 441         ),
 442     }, @classes);
 443 }
 444
 445
 446 =head1 AUTHORS
 447
 448 Catalyst Contributors, see Catalyst.pm
 449
 450 =head1 COPYRIGHT
 451
 452 This library is free software. You can redistribute it and/or modify it under
 453 the same terms as Perl itself.
 454
 455 =cut
 456
 457 1;