lib/Catalyst/Test.pm

   1 package Catalyst::Test;
   2
   3 use strict;
   4 use warnings;
   5 use Test::More ();
   6
   7 use Catalyst::Exception;
   8 use Catalyst::Utils;
   9 use Class::MOP;
  10 use Sub::Exporter;
  11
  12 my $build_exports = sub {
  13     my ($self, $meth, $args, $defaults) = @_;
  14
  15     my $request;
  16     my $class = $args->{class};
  17
  18     if ( $ENV{CATALYST_SERVER} ) {
  19         $request = sub { remote_request(@_) };
  20     } elsif (! $class) {
  21         $request = sub { Catalyst::Exception->throw("Must specify a test app: use Catalyst::Test 'TestApp'") };
  22     } else {
  23         unless (Class::MOP::is_class_loaded($class)) {
  24             Class::MOP::load_class($class);
  25         }
  26         $class->import;
  27
  28         $request = sub { local_request( $class, @_ ) };
  29     }
  30
  31     my $get = sub { $request->(@_)->content };
  32
  33     my $ctx_request = sub {
  34         my $me = ref $self || $self;
  35
  36         ### throw an exception if ctx_request is being used against a remote
  37         ### server
  38         Catalyst::Exception->throw("$me only works with local requests, not remote")
  39             if $ENV{CATALYST_SERVER};
  40
  41         ### check explicitly for the class here, or the Cat->meta call will blow
  42         ### up in our face
  43         Catalyst::Exception->throw("Must specify a test app: use Catalyst::Test 'TestApp'") unless $class;
  44
  45         ### place holder for $c after the request finishes; reset every time
  46         ### requests are done.
  47         my $c;
  48
  49         ### hook into 'dispatch' -- the function gets called after all plugins
  50         ### have done their work, and it's an easy place to capture $c.
  51
  52         my $meta = Class::MOP::get_metaclass_by_name($class);
  53         $meta->make_mutable;
  54         $meta->add_after_method_modifier( "dispatch", sub {
  55             $c = shift;
  56         });
  57         $meta->make_immutable( replace_constructor => 1 );
  58         Class::C3::reinitialize(); # Fixes RT#46459, I've failed to write a test for how/why, but it does.
  59         ### do the request; C::T::request will know about the class name, and
  60         ### we've already stopped it from doing remote requests above.
  61         my $res = $request->( @_ );
  62
  63         ### return both values
  64         return ( $res, $c );
  65     };
  66
  67     return {
  68         request      => $request,
  69         get          => $get,
  70         ctx_request  => $ctx_request,
  71         content_like => sub {
  72             my $action = shift;
  73             return Test::More->builder->like($get->($action),@_);
  74         },
  75         action_ok => sub {
  76             my $action = shift;
  77             return Test::More->builder->ok($request->($action)->is_success, @_);
  78         },
  79         action_redirect => sub {
  80             my $action = shift;
  81             return Test::More->builder->ok($request->($action)->is_redirect,@_);
  82         },
  83         action_notfound => sub {
  84             my $action = shift;
  85             return Test::More->builder->is_eq($request->($action)->code,404,@_);
  86         },
  87         contenttype_is => sub {
  88             my $action = shift;
  89             my $res = $request->($action);
  90             return Test::More->builder->is_eq(scalar($res->content_type),@_);
  91         },
  92     };
  93 };
  94
  95 our $default_host;
  96
  97 {
  98     my $import = Sub::Exporter::build_exporter({
  99         groups => [ all => $build_exports ],
 100         into_level => 1,
 101     });
 102
 103
 104     sub import {
 105         my ($self, $class, $opts) = @_;
 106         Carp::carp(
 107 qq{Importing Catalyst::Test without an application name is deprecated:\n
 108 Instead of saying: use Catalyst::Test;
 109 say: use Catalyst::Test (); # If you don't want to import a test app right now.
 110 or say: use Catalyst::Test 'MyApp'; # If you do want to import a test app.\n\n})
 111         unless $class;
 112         $import->($self, '-all' => { class => $class });
 113         $opts = {} unless ref $opts eq 'HASH';
 114         $default_host = $opts->{default_host} if exists $opts->{default_host};
 115         return 1;
 116     }
 117 }
 118
 119 =head1 NAME
 120
 121 Catalyst::Test - Test Catalyst Applications
 122
 123 =head1 SYNOPSIS
 124
 125     # Helper
 126     script/test.pl
 127
 128     # Tests
 129     use Catalyst::Test 'TestApp';
 130     my $content  = get('index.html');           # Content as string
 131     my $response = request('index.html');       # HTTP::Response object
 132     my($res, $c) = ctx_request('index.html');      # HTTP::Response & context object
 133
 134     use HTTP::Request::Common;
 135     my $response = request POST '/foo', [
 136         bar => 'baz',
 137         something => 'else'
 138     ];
 139
 140     # Run tests against a remote server
 141     CATALYST_SERVER='http://localhost:3000/' prove -r -l lib/ t/
 142
 143     use Catalyst::Test 'TestApp';
 144     use Test::More tests => 1;
 145
 146     ok( get('/foo') =~ /bar/ );
 147
 148     # mock virtual hosts
 149     use Catalyst::Test 'MyApp', { default_host => 'myapp.com' };
 150     like( get('/whichhost'), qr/served by myapp.com/ );
 151     like( get( '/whichhost', { host => 'yourapp.com' } ), qr/served by yourapp.com/ );
 152     {
 153         local $Catalyst::Test::default_host = 'otherapp.com';
 154         like( get('/whichhost'), qr/served by otherapp.com/ );
 155     }
 156
 157 =head1 DESCRIPTION
 158
 159 This module allows you to make requests to a Catalyst application either without
 160 a server, by simulating the environment of an HTTP request using
 161 L<HTTP::Request::AsCGI> or remotely if you define the CATALYST_SERVER
 162 environment variable. This module also adds a few Catalyst-specific
 163 testing methods as displayed in the method section.
 164
 165 The L<get|/"$content = get( ... )"> and L<request|/"$res = request( ... );">
 166 functions take either a URI or an L<HTTP::Request> object.
 167
 168 =head1 INLINE TESTS WILL NO LONGER WORK
 169
 170 While it used to be possible to inline a whole testapp into a C<.t> file for a
 171 distribution, this will no longer work.
 172
 173 The convention is to place your L<Catalyst> test apps into C<t/lib> in your
 174 distribution. E.g.: C<t/lib/TestApp.pm>, C<t/lib/TestApp/Controller/Root.pm>,
 175 etc..  Multiple test apps can be used in this way.
 176
 177 Then write your C<.t> files like so:
 178
 179     use strict;
 180     use warnings;
 181     use FindBin '$Bin';
 182     use lib "$Bin/lib";
 183     use Test::More tests => 6;
 184     use Catalyst::Test 'TestApp';
 185
 186 =head1 METHODS
 187
 188 =head2 $content = get( ... )
 189
 190 Returns the content.
 191
 192     my $content = get('foo/bar?test=1');
 193
 194 Note that this method doesn't follow redirects, so to test for a
 195 correctly redirecting page you'll need to use a combination of this
 196 method and the L<request|/"$res = request( ... );"> method below:
 197
 198     my $res = request('/'); # redirects to /y
 199     warn $res->header('location');
 200     use URI;
 201     my $uri = URI->new($res->header('location'));
 202     is ( $uri->path , '/y');
 203     my $content = get($uri->path);
 204
 205 Note also that the content is returned as raw bytes, without any attempt
 206 to decode it into characters.
 207
 208 =head2 $res = request( ... );
 209
 210 Returns an L<HTTP::Response> object. Accepts an optional hashref for request
 211 header configuration; currently only supports setting 'host' value.
 212
 213     my $res = request('foo/bar?test=1');
 214     my $virtual_res = request('foo/bar?test=1', {host => 'virtualhost.com'});
 215
 216 =head1 FUNCTIONS
 217
 218 =head2 ($res, $c) = ctx_request( ... );
 219
 220 Works exactly like L<request|/"$res = request( ... );">, except it also returns the Catalyst context object,
 221 C<$c>. Note that this only works for local requests.
 222
 223 =head2 $res = Catalyst::Test::local_request( $AppClass, $url );
 224
 225 Simulate a request using L<HTTP::Request::AsCGI>.
 226
 227 =cut
 228
 229 sub local_request {
 230     my $class = shift;
 231
 232     require HTTP::Request::AsCGI;
 233
 234     my $request = Catalyst::Utils::request( shift(@_) );
 235     _customize_request($request, @_);
 236     my $cgi     = HTTP::Request::AsCGI->new( $request, %ENV )->setup;
 237
 238     $class->handle_request( env => \%ENV );
 239
 240     my $response = $cgi->restore->response;
 241     $response->request( $request );
 242
 243     # HTML head parsing based on LWP::UserAgent
 244
 245     require HTML::HeadParser;
 246
 247     my $parser = HTML::HeadParser->new();
 248     $parser->xml_mode(1) if $response->content_is_xhtml;
 249     $parser->utf8_mode(1) if $] >= 5.008 && $HTML::Parser::VERSION >= 3.40;
 250
 251     $parser->parse( $response->content );
 252     my $h = $parser->header;
 253     for my $f ( $h->header_field_names ) {
 254         $response->init_header( $f, [ $h->header($f) ] );
 255     }
 256
 257     return $response;
 258 }
 259
 260 my $agent;
 261
 262 =head2 $res = Catalyst::Test::remote_request( $url );
 263
 264 Do an actual remote request using LWP.
 265
 266 =cut
 267
 268 sub remote_request {
 269
 270     require LWP::UserAgent;
 271
 272     my $request = Catalyst::Utils::request( shift(@_) );
 273     my $server  = URI->new( $ENV{CATALYST_SERVER} );
 274
 275     _customize_request($request, @_);
 276
 277     if ( $server->path =~ m|^(.+)?/$| ) {
 278         my $path = $1;
 279         $server->path("$path") if $path;    # need to be quoted
 280     }
 281
 282     # the request path needs to be sanitised if $server is using a
 283     # non-root path due to potential overlap between request path and
 284     # response path.
 285     if ($server->path) {
 286         # If request path is '/', we have to add a trailing slash to the
 287         # final request URI
 288         my $add_trailing = $request->uri->path eq '/';
 289
 290         my @sp = split '/', $server->path;
 291         my @rp = split '/', $request->uri->path;
 292         shift @sp;shift @rp; # leading /
 293         if (@rp) {
 294             foreach my $sp (@sp) {
 295                 $sp eq $rp[0] ? shift @rp : last
 296             }
 297         }
 298         $request->uri->path(join '/', @rp);
 299
 300         if ( $add_trailing ) {
 301             $request->uri->path( $request->uri->path . '/' );
 302         }
 303     }
 304
 305     $request->uri->scheme( $server->scheme );
 306     $request->uri->host( $server->host );
 307     $request->uri->port( $server->port );
 308     $request->uri->path( $server->path . $request->uri->path );
 309
 310     unless ($agent) {
 311
 312         $agent = LWP::UserAgent->new(
 313             keep_alive   => 1,
 314             max_redirect => 0,
 315             timeout      => 60,
 316
 317             # work around newer LWP max_redirect 0 bug
 318             # http://rt.cpan.org/Ticket/Display.html?id=40260
 319             requests_redirectable => [],
 320         );
 321
 322         $agent->env_proxy;
 323     }
 324
 325     return $agent->request($request);
 326 }
 327
 328 sub _customize_request {
 329     my $request = shift;
 330     my $opts = pop(@_) || {};
 331     $opts = {} unless ref($opts) eq 'HASH';
 332     if ( my $host = exists $opts->{host} ? $opts->{host} : $default_host  ) {
 333         $request->header( 'Host' => $host );
 334     }
 335 }
 336
 337 =head2 action_ok
 338
 339 Fetches the given URL and checks that the request was successful.
 340
 341 =head2 action_redirect
 342
 343 Fetches the given URL and checks that the request was a redirect.
 344
 345 =head2 action_notfound
 346
 347 Fetches the given URL and checks that the request was not found.
 348
 349 =head2 content_like( $url, $regexp [, $test_name] )
 350
 351 Fetches the given URL and returns whether the content matches the regexp.
 352
 353 =head2 contenttype_is
 354
 355 Check for given MIME type.
 356
 357 =head1 SEE ALSO
 358
 359 L<Catalyst>, L<Test::WWW::Mechanize::Catalyst>,
 360 L<Test::WWW::Selenium::Catalyst>, L<Test::More>, L<HTTP::Request::Common>
 361
 362 =head1 AUTHORS
 363
 364 Catalyst Contributors, see Catalyst.pm
 365
 366 =head1 COPYRIGHT
 367
 368 This library is free software. You can redistribute it and/or modify it under
 369 the same terms as Perl itself.
 370
 371 =cut
 372
 373 1;