lib/Catalyst/Test.pm

   1 package Catalyst::Test;
   2
   3 use strict;
   4 use UNIVERSAL::require;
   5
   6 $ENV{CATALYST_ENGINE} = 'Test';
   7
   8 =head1 NAME
   9
  10 Catalyst::Test - Test Catalyst applications
  11
  12 =head1 SYNOPSIS
  13
  14     # Helper
  15     script/test.pl
  16
  17     # Tests
  18     use Catalyst::Test 'TestApp';
  19     request('index.html');
  20     get('index.html');
  21
  22     # Run tests against a remote server
  23     CATALYST_SERVER='http://localhost:3000/' prove -l lib/ t/
  24
  25     # Tests with inline apps need to use Catalyst::Engine::Test
  26     package TestApp;
  27
  28     use Catalyst qw[-Engine=Test];
  29
  30     __PACKAGE__->action(
  31         foo => sub {
  32             my ( $self, $c ) = @_;
  33             $c->res->output('bar');
  34         }
  35     );
  36
  37     package main;
  38
  39     use Test::More tests => 1;
  40     use Catalyst::Test 'TestApp';
  41
  42     ok( get('/foo') =~ /bar/ );
  43
  44 =head1 DESCRIPTION
  45
  46 Test Catalyst applications.
  47
  48 =head2 METHODS
  49
  50 =over 4
  51
  52 =item get
  53
  54 Returns the content.
  55
  56     my $content = get('foo/bar?test=1');
  57
  58 =item request
  59
  60 Returns a C<HTTP::Response> object.
  61
  62     my $res =request('foo/bar?test=1');
  63
  64 =cut
  65
  66 sub import {
  67     my $self  = shift;
  68     my $class = shift;
  69
  70     my ( $get, $request );
  71
  72     if ( $ENV{CATALYST_SERVER} ) {
  73         $request = sub { remote_request(@_) };
  74         $get     = sub { remote_request(@_)->content };
  75     }
  76
  77     else {
  78         $class->require;
  79
  80         unless ( $INC{'Test/Builder.pm'} ) {
  81             die qq/Couldn't load "$class", "$@"/ if $@;
  82         }
  83
  84         $class->import;
  85
  86         $request = sub { $class->run(@_) };
  87         $get     = sub { $class->run(@_)->content };
  88     }
  89
  90     no strict 'refs';
  91     my $caller = caller(0);
  92     *{"$caller\::request"} = $request;
  93     *{"$caller\::get"}     = $get;
  94 }
  95
  96 my $agent;
  97
  98 =item remote_request
  99
 100 Do an actual remote rquest using LWP.
 101
 102 =cut
 103
 104 sub remote_request {
 105     my $request = shift;
 106
 107     require LWP::UserAgent;
 108
 109     unless ( ref $request ) {
 110
 111         my $uri = ( $request =~ m/http/i )
 112           ? URI->new($request)
 113           : URI->new( 'http://localhost' . $request );
 114
 115         $request = $uri->canonical;
 116     }
 117
 118     unless ( ref $request eq 'HTTP::Request' ) {
 119         $request = HTTP::Request->new( 'GET', $request );
 120     }
 121
 122     my $server = URI->new( $ENV{CATALYST_SERVER} );
 123
 124     if ( $server->path =~ m|^(.+)?/$| ) {
 125         $server->path("$1"); # need to be quoted
 126     }
 127
 128     $request->uri->scheme( $server->scheme );
 129     $request->uri->host( $server->host );
 130     $request->uri->port( $server->port );
 131     $request->uri->path( $server->path . $request->uri->path );
 132
 133     unless ($agent) {
 134         $agent = LWP::UserAgent->new(
 135          #  cookie_jar   => {},
 136             keep_alive   => 1,
 137             max_redirect => 0,
 138             timeout      => 60,
 139         );
 140         $agent->env_proxy;
 141     }
 142
 143     return $agent->request($request);
 144 }
 145
 146 =back
 147
 148 =head1 SEE ALSO
 149
 150 L<Catalyst>.
 151
 152 =head1 AUTHOR
 153
 154 Sebastian Riedel, C<sri@cpan.org>
 155
 156 =head1 COPYRIGHT
 157
 158 This program is free software, you can redistribute it and/or modify it under
 159 the same terms as Perl itself.
 160
 161 =cut
 162
 163 1;