lib/Catalyst/Test.pm

   1 package Catalyst::Test;
   2
   3 use strict;
   4 use warnings;
   5 use Test::More ();
   6
   7 use Catalyst::Exception;
   8 use Catalyst::Utils;
   9 use Class::MOP;
  10 use Sub::Exporter;
  11
  12 my $build_exports = sub {
  13     my ($self, $meth, $args, $defaults) = @_;
  14
  15     my $request;
  16     my $class = $args->{class};
  17
  18     if ( $ENV{CATALYST_SERVER} ) {
  19         $request = sub { remote_request(@_) };
  20     } elsif (! $class) {
  21         $request = sub { Catalyst::Exception->throw("Must specify a test app: use Catalyst::Test 'TestApp'") };
  22     } else {
  23         unless (Class::MOP::is_class_loaded($class)) {
  24             Class::MOP::load_class($class);
  25         }
  26         $class->import;
  27
  28         $request = sub { local_request( $class, @_ ) };
  29     }
  30
  31     my $get = sub { $request->(@_)->content };
  32
  33     my $ctx_request = sub {
  34         my $me = ref $self || $self;
  35
  36         ### throw an exception if ctx_request is being used against a remote
  37         ### server
  38         Catalyst::Exception->throw("$me only works with local requests, not remote")
  39             if $ENV{CATALYST_SERVER};
  40
  41         ### check explicitly for the class here, or the Cat->meta call will blow
  42         ### up in our face
  43         Catalyst::Exception->throw("Must specify a test app: use Catalyst::Test 'TestApp'") unless $class;
  44
  45         ### place holder for $c after the request finishes; reset every time
  46         ### requests are done.
  47         my $c;
  48
  49         ### hook into 'dispatch' -- the function gets called after all plugins
  50         ### have done their work, and it's an easy place to capture $c.
  51
  52         my $meta = Class::MOP::get_metaclass_by_name($class);
  53         $meta->make_mutable;
  54         $meta->add_around_method_modifier( "prepare", sub {
  55                 my $orig = shift;
  56                 my $self = shift;
  57
  58                 $c = $self->$orig(@_);
  59         });
  60         $meta->make_immutable( replace_constructor => 1 );
  61         Class::C3::reinitialize(); # Fixes RT#46459, I've failed to write a test for how/why, but it does.
  62         ### do the request; C::T::request will know about the class name, and
  63         ### we've already stopped it from doing remote requests above.
  64         my $res = $request->( @_ );
  65
  66         ### return both values
  67         return ( $res, $c );
  68     };
  69
  70     return {
  71         request      => $request,
  72         get          => $get,
  73         ctx_request  => $ctx_request,
  74         content_like => sub {
  75             my $action = shift;
  76             return Test::More->builder->like($get->($action),@_);
  77         },
  78         action_ok => sub {
  79             my $action = shift;
  80             return Test::More->builder->ok($request->($action)->is_success, @_);
  81         },
  82         action_redirect => sub {
  83             my $action = shift;
  84             return Test::More->builder->ok($request->($action)->is_redirect,@_);
  85         },
  86         action_notfound => sub {
  87             my $action = shift;
  88             return Test::More->builder->is_eq($request->($action)->code,404,@_);
  89         },
  90         contenttype_is => sub {
  91             my $action = shift;
  92             my $res = $request->($action);
  93             return Test::More->builder->is_eq(scalar($res->content_type),@_);
  94         },
  95     };
  96 };
  97
  98 our $default_host;
  99
 100 {
 101     my $import = Sub::Exporter::build_exporter({
 102         groups => [ all => $build_exports ],
 103         into_level => 1,
 104     });
 105
 106
 107     sub import {
 108         my ($self, $class, $opts) = @_;
 109         $import->($self, '-all' => { class => $class });
 110         $opts = {} unless ref $opts eq 'HASH';
 111         $default_host = $opts->{default_host} if exists $opts->{default_host};
 112         return 1;
 113     }
 114 }
 115
 116 =head1 NAME
 117
 118 Catalyst::Test - Test Catalyst Applications
 119
 120 =head1 SYNOPSIS
 121
 122     # Helper
 123     script/test.pl
 124
 125     # Tests
 126     use Catalyst::Test 'TestApp';
 127     my $content  = get('index.html');           # Content as string
 128     my $response = request('index.html');       # HTTP::Response object
 129     my($res, $c) = ctx_request('index.html');      # HTTP::Response & context object
 130
 131     use HTTP::Request::Common;
 132     my $response = request POST '/foo', [
 133         bar => 'baz',
 134         something => 'else'
 135     ];
 136
 137     # Run tests against a remote server
 138     CATALYST_SERVER='http://localhost:3000/' prove -r -l lib/ t/
 139
 140     use Catalyst::Test 'TestApp';
 141     use Test::More tests => 1;
 142
 143     ok( get('/foo') =~ /bar/ );
 144
 145     # mock virtual hosts
 146     use Catalyst::Test 'MyApp', { default_host => 'myapp.com' };
 147     like( get('/whichhost'), qr/served by myapp.com/ );
 148     like( get( '/whichhost', { host => 'yourapp.com' } ), qr/served by yourapp.com/ );
 149     {
 150         local $Catalyst::Test::default_host = 'otherapp.com';
 151         like( get('/whichhost'), qr/served by otherapp.com/ );
 152     }
 153
 154 =head1 DESCRIPTION
 155
 156 This module allows you to make requests to a Catalyst application either without
 157 a server, by simulating the environment of an HTTP request using
 158 L<HTTP::Request::AsCGI> or remotely if you define the CATALYST_SERVER
 159 environment variable. This module also adds a few Catalyst-specific
 160 testing methods as displayed in the method section.
 161
 162 The L<get|/"$content = get( ... )"> and L<request|/"$res = request( ... );">
 163 functions take either a URI or an L<HTTP::Request> object.
 164
 165 =head1 INLINE TESTS WILL NO LONGER WORK
 166
 167 While it used to be possible to inline a whole testapp into a C<.t> file for a
 168 distribution, this will no longer work.
 169
 170 The convention is to place your L<Catalyst> test apps into C<t/lib> in your
 171 distribution. E.g.: C<t/lib/TestApp.pm>, C<t/lib/TestApp/Controller/Root.pm>,
 172 etc..  Multiple test apps can be used in this way.
 173
 174 Then write your C<.t> files like so:
 175
 176     use strict;
 177     use warnings;
 178     use FindBin '$Bin';
 179     use lib "$Bin/lib";
 180     use Test::More tests => 6;
 181     use Catalyst::Test 'TestApp';
 182
 183 =head1 METHODS
 184
 185 =head2 $content = get( ... )
 186
 187 Returns the content.
 188
 189     my $content = get('foo/bar?test=1');
 190
 191 Note that this method doesn't follow redirects, so to test for a
 192 correctly redirecting page you'll need to use a combination of this
 193 method and the L<request|/"$res = request( ... );"> method below:
 194
 195     my $res = request('/'); # redirects to /y
 196     warn $res->header('location');
 197     use URI;
 198     my $uri = URI->new($res->header('location'));
 199     is ( $uri->path , '/y');
 200     my $content = get($uri->path);
 201
 202 =head2 $res = request( ... );
 203
 204 Returns an L<HTTP::Response> object. Accepts an optional hashref for request
 205 header configuration; currently only supports setting 'host' value.
 206
 207     my $res = request('foo/bar?test=1');
 208     my $virtual_res = request('foo/bar?test=1', {host => 'virtualhost.com'});
 209
 210 =head1 FUNCTIONS
 211
 212 =head2 ($res, $c) = ctx_request( ... );
 213
 214 Works exactly like L<request|/"$res = request( ... );">, except it also returns the Catalyst context object,
 215 C<$c>. Note that this only works for local requests.
 216
 217 =head2 $res = Catalyst::Test::local_request( $AppClass, $url );
 218
 219 Simulate a request using L<HTTP::Request::AsCGI>.
 220
 221 =cut
 222
 223 sub local_request {
 224     my $class = shift;
 225
 226     require HTTP::Request::AsCGI;
 227
 228     my $request = Catalyst::Utils::request( shift(@_) );
 229     _customize_request($request, @_);
 230     my $cgi     = HTTP::Request::AsCGI->new( $request, %ENV )->setup;
 231
 232     $class->handle_request( env => \%ENV );
 233
 234     my $response = $cgi->restore->response;
 235     $response->request( $request );
 236     return $response;
 237 }
 238
 239 my $agent;
 240
 241 =head2 $res = Catalyst::Test::remote_request( $url );
 242
 243 Do an actual remote request using LWP.
 244
 245 =cut
 246
 247 sub remote_request {
 248
 249     require LWP::UserAgent;
 250
 251     my $request = Catalyst::Utils::request( shift(@_) );
 252     my $server  = URI->new( $ENV{CATALYST_SERVER} );
 253
 254     _customize_request($request, @_);
 255
 256     if ( $server->path =~ m|^(.+)?/$| ) {
 257         my $path = $1;
 258         $server->path("$path") if $path;    # need to be quoted
 259     }
 260
 261     # the request path needs to be sanitised if $server is using a
 262     # non-root path due to potential overlap between request path and
 263     # response path.
 264     if ($server->path) {
 265         # If request path is '/', we have to add a trailing slash to the
 266         # final request URI
 267         my $add_trailing = $request->uri->path eq '/';
 268
 269         my @sp = split '/', $server->path;
 270         my @rp = split '/', $request->uri->path;
 271         shift @sp;shift @rp; # leading /
 272         if (@rp) {
 273             foreach my $sp (@sp) {
 274                 $sp eq $rp[0] ? shift @rp : last
 275             }
 276         }
 277         $request->uri->path(join '/', @rp);
 278
 279         if ( $add_trailing ) {
 280             $request->uri->path( $request->uri->path . '/' );
 281         }
 282     }
 283
 284     $request->uri->scheme( $server->scheme );
 285     $request->uri->host( $server->host );
 286     $request->uri->port( $server->port );
 287     $request->uri->path( $server->path . $request->uri->path );
 288
 289     unless ($agent) {
 290
 291         $agent = LWP::UserAgent->new(
 292             keep_alive   => 1,
 293             max_redirect => 0,
 294             timeout      => 60,
 295
 296             # work around newer LWP max_redirect 0 bug
 297             # http://rt.cpan.org/Ticket/Display.html?id=40260
 298             requests_redirectable => [],
 299         );
 300
 301         $agent->env_proxy;
 302     }
 303
 304     return $agent->request($request);
 305 }
 306
 307 sub _customize_request {
 308     my $request = shift;
 309     my $opts = pop(@_) || {};
 310     $opts = {} unless ref($opts) eq 'HASH';
 311     if ( my $host = exists $opts->{host} ? $opts->{host} : $default_host  ) {
 312         $request->header( 'Host' => $host );
 313     }
 314 }
 315
 316 =head2 action_ok
 317
 318 Fetches the given URL and checks that the request was successful.
 319
 320 =head2 action_redirect
 321
 322 Fetches the given URL and checks that the request was a redirect.
 323
 324 =head2 action_notfound
 325
 326 Fetches the given URL and checks that the request was not found.
 327
 328 =head2 content_like( $url, $regexp [, $test_name] )
 329
 330 Fetches the given URL and returns whether the content matches the regexp.
 331
 332 =head2 contenttype_is
 333
 334 Check for given MIME type.
 335
 336 =head1 SEE ALSO
 337
 338 L<Catalyst>, L<Test::WWW::Mechanize::Catalyst>,
 339 L<Test::WWW::Selenium::Catalyst>, L<Test::More>, L<HTTP::Request::Common>
 340
 341 =head1 AUTHORS
 342
 343 Catalyst Contributors, see Catalyst.pm
 344
 345 =head1 COPYRIGHT
 346
 347 This library is free software. You can redistribute it and/or modify it under
 348 the same terms as Perl itself.
 349
 350 =cut
 351
 352 1;