lib/Catalyst/Test.pm

   1 package Catalyst::Test;
   2
   3 use strict;
   4 use warnings;
   5 use Test::More ();
   6
   7 use Catalyst::Exception;
   8 use Catalyst::Utils;
   9 use Class::MOP;
  10 use Sub::Exporter;
  11
  12 my $build_exports = sub {
  13     my ($self, $meth, $args, $defaults) = @_;
  14
  15     my $request;
  16     my $class = $args->{class};
  17
  18     if ( $ENV{CATALYST_SERVER} ) {
  19         $request = sub { remote_request(@_) };
  20     } elsif (! $class) {
  21         $request = sub { Catalyst::Exception->throw("Must specify a test app: use Catalyst::Test 'TestApp'") };
  22     } else {
  23         unless (Class::MOP::is_class_loaded($class)) {
  24             Class::MOP::load_class($class);
  25         }
  26         $class->import;
  27
  28         $request = sub { local_request( $class, @_ ) };
  29     }
  30
  31     my $get = sub { $request->(@_)->content };
  32
  33     my $ctx_request = sub {
  34         my $me      = ref $self || $self;
  35
  36         ### throw an exception if ctx_request is being used against a remote
  37         ### server
  38         Catalyst::Exception->throw("$me only works with local requests, not remote")
  39             if $ENV{CATALYST_SERVER};
  40
  41         ### check explicitly for the class here, or the Cat->meta call will blow
  42         ### up in our face
  43         Catalyst::Exception->throw("Must specify a test app: use Catalyst::Test 'TestApp'") unless $class;
  44
  45         ### place holder for $c after the request finishes; reset every time
  46         ### requests are done.
  47         my $c;
  48
  49         ### hook into 'dispatch' -- the function gets called after all plugins
  50         ### have done their work, and it's an easy place to capture $c.
  51
  52         my $meta = Catalyst->meta;
  53         $meta->make_mutable;
  54         $meta->add_after_method_modifier( "dispatch", sub {
  55             $c = shift;
  56         });
  57         $meta->make_immutable;
  58
  59         ### do the request; C::T::request will know about the class name, and
  60         ### we've already stopped it from doing remote requests above.
  61         my $res = $request->( @_ );
  62
  63         ### return both values
  64         return ( $res, $c );
  65     };
  66
  67     return {
  68         request      => $request,
  69         get          => $get,
  70         ctx_request  => $ctx_request,
  71         content_like => sub {
  72             my $action = shift;
  73             return Test::More->builder->like($get->($action),@_);
  74         },
  75         action_ok => sub {
  76             my $action = shift;
  77             return Test::More->builder->ok($request->($action)->is_success, @_);
  78         },
  79         action_redirect => sub {
  80             my $action = shift;
  81             return Test::More->builder->ok($request->($action)->is_redirect,@_);
  82         },
  83         action_notfound => sub {
  84             my $action = shift;
  85             return Test::More->builder->is_eq($request->($action)->code,404,@_);
  86         },
  87         contenttype_is => sub {
  88             my $action = shift;
  89             my $res = $request->($action);
  90             return Test::More->builder->is_eq(scalar($res->content_type),@_);
  91         },
  92     };
  93 };
  94
  95 our $default_host;
  96
  97 {
  98     my $import = Sub::Exporter::build_exporter({
  99         groups => [ all => $build_exports ],
 100         into_level => 1,
 101     });
 102
 103
 104     sub import {
 105         my ($self, $class, $opts) = @_;
 106         $import->($self, '-all' => { class => $class });
 107         $opts = {} unless ref $opts eq 'HASH';
 108         $default_host = $opts->{default_host} if exists $opts->{default_host};
 109         return 1;
 110     }
 111 }
 112
 113 =head1 NAME
 114
 115 Catalyst::Test - Test Catalyst Applications
 116
 117 =head1 SYNOPSIS
 118
 119     # Helper
 120     script/test.pl
 121
 122     # Tests
 123     use Catalyst::Test 'TestApp';
 124     my $content  = get('index.html');           # Content as string
 125     my $response = request('index.html');       # HTTP::Response object
 126     my($res, $c) = ctx_request('index.html');      # HTTP::Response & context object
 127
 128     use HTTP::Request::Common;
 129     my $response = request POST '/foo', [
 130         bar => 'baz',
 131         something => 'else'
 132     ];
 133
 134     # Run tests against a remote server
 135     CATALYST_SERVER='http://localhost:3000/' prove -r -l lib/ t/
 136
 137     # Tests with inline apps need to use Catalyst::Engine::Test
 138     package TestApp;
 139
 140     use Catalyst;
 141
 142     sub foo : Global {
 143             my ( $self, $c ) = @_;
 144             $c->res->output('bar');
 145     }
 146
 147     __PACKAGE__->setup();
 148
 149     package main;
 150
 151     use Catalyst::Test 'TestApp';
 152     use Test::More tests => 1;
 153
 154     ok( get('/foo') =~ /bar/ );
 155
 156     # mock virtual hosts
 157     use Catalyst::Test 'MyApp', { default_host => 'myapp.com' };
 158     like( get('/whichhost'), qr/served by myapp.com/ );
 159     like( get( '/whichhost', { host => 'yourapp.com' } ), qr/served by yourapp.com/ );
 160     {
 161         local $Catalyst::Test::default_host = 'otherapp.com';
 162         like( get('/whichhost'), qr/served by otherapp.com/ );
 163     }
 164
 165 =head1 DESCRIPTION
 166
 167 This module allows you to make requests to a Catalyst application either without
 168 a server, by simulating the environment of an HTTP request using
 169 L<HTTP::Request::AsCGI> or remotely if you define the CATALYST_SERVER
 170 environment variable. This module also adds a few catalyst
 171 specific testing methods as displayed in the method section.
 172
 173 The L<get> and L<request> functions take either a URI or an L<HTTP::Request>
 174 object.
 175
 176 =head1 METHODS
 177
 178 =head2 $content = get( ... )
 179
 180 Returns the content.
 181
 182     my $content = get('foo/bar?test=1');
 183
 184 Note that this method doesn't follow redirects, so to test for a
 185 correctly redirecting page you'll need to use a combination of this
 186 method and the L<request> method below:
 187
 188     my $res = request('/'); # redirects to /y
 189     warn $res->header('location');
 190     use URI;
 191     my $uri = URI->new($res->header('location'));
 192     is ( $uri->path , '/y');
 193     my $content = get($uri->path);
 194
 195 =head2 $res = request( ... );
 196
 197 Returns a L<HTTP::Response> object. Accepts an optional hashref for request
 198 header configuration; currently only supports setting 'host' value.
 199
 200     my $res = request('foo/bar?test=1');
 201     my $virtual_res = request('foo/bar?test=1', {host => 'virtualhost.com'});
 202
 203 =head1 FUNCTIONS
 204
 205 =head2 ($res, $c) = ctx_request( ... );
 206
 207 Works exactly like L<request>, except it also returns the Catalyst context object,
 208 C<$c>. Note that this only works for local requests.
 209
 210 =head2 $res = Catalyst::Test::local_request( $AppClass, $url );
 211
 212 Simulate a request using L<HTTP::Request::AsCGI>.
 213
 214 =cut
 215
 216 sub local_request {
 217     my $class = shift;
 218
 219     require HTTP::Request::AsCGI;
 220
 221     my $request = Catalyst::Utils::request( shift(@_) );
 222     _customize_request($request, @_);
 223     my $cgi     = HTTP::Request::AsCGI->new( $request, %ENV )->setup;
 224
 225     $class->handle_request;
 226
 227     return $cgi->restore->response;
 228 }
 229
 230 my $agent;
 231
 232 =head2 $res = Catalyst::Test::remote_request( $url );
 233
 234 Do an actual remote request using LWP.
 235
 236 =cut
 237
 238 sub remote_request {
 239
 240     require LWP::UserAgent;
 241
 242     my $request = Catalyst::Utils::request( shift(@_) );
 243     my $server  = URI->new( $ENV{CATALYST_SERVER} );
 244
 245     _customize_request($request, @_);
 246
 247     if ( $server->path =~ m|^(.+)?/$| ) {
 248         my $path = $1;
 249         $server->path("$path") if $path;    # need to be quoted
 250     }
 251
 252     # the request path needs to be sanitised if $server is using a
 253     # non-root path due to potential overlap between request path and
 254     # response path.
 255     if ($server->path) {
 256         # If request path is '/', we have to add a trailing slash to the
 257         # final request URI
 258         my $add_trailing = $request->uri->path eq '/';
 259
 260         my @sp = split '/', $server->path;
 261         my @rp = split '/', $request->uri->path;
 262         shift @sp;shift @rp; # leading /
 263         if (@rp) {
 264             foreach my $sp (@sp) {
 265                 $sp eq $rp[0] ? shift @rp : last
 266             }
 267         }
 268         $request->uri->path(join '/', @rp);
 269
 270         if ( $add_trailing ) {
 271             $request->uri->path( $request->uri->path . '/' );
 272         }
 273     }
 274
 275     $request->uri->scheme( $server->scheme );
 276     $request->uri->host( $server->host );
 277     $request->uri->port( $server->port );
 278     $request->uri->path( $server->path . $request->uri->path );
 279
 280     unless ($agent) {
 281
 282         $agent = LWP::UserAgent->new(
 283             keep_alive   => 1,
 284             max_redirect => 0,
 285             timeout      => 60,
 286
 287             # work around newer LWP max_redirect 0 bug
 288             # http://rt.cpan.org/Ticket/Display.html?id=40260
 289             requests_redirectable => [],
 290         );
 291
 292         $agent->env_proxy;
 293     }
 294
 295     return $agent->request($request);
 296 }
 297
 298 sub _customize_request {
 299     my $request = shift;
 300     my $opts = pop(@_) || {};
 301     $opts = {} unless ref($opts) eq 'HASH';
 302     if ( my $host = exists $opts->{host} ? $opts->{host} : $default_host  ) {
 303         $request->header( 'Host' => $host );
 304     }
 305 }
 306
 307 =head2 action_ok
 308
 309 Fetches the given URL and check that the request was successful
 310
 311 =head2 action_redirect
 312
 313 Fetches the given URL and check that the request was a redirect
 314
 315 =head2 action_notfound
 316
 317 Fetches the given URL and check that the request was not found
 318
 319 =head2 content_like
 320
 321 Fetches the given URL and matches the content against it.
 322
 323 =head2 contenttype_is
 324
 325 Check for given MIME type
 326
 327 =head1 SEE ALSO
 328
 329 L<Catalyst>, L<Test::WWW::Mechanize::Catalyst>,
 330 L<Test::WWW::Selenium::Catalyst>, L<Test::More>, L<HTTP::Request::Common>
 331
 332 =head1 AUTHORS
 333
 334 Catalyst Contributors, see Catalyst.pm
 335
 336 =head1 COPYRIGHT
 337
 338 This program is free software, you can redistribute it and/or modify it under
 339 the same terms as Perl itself.
 340
 341 =cut
 342
 343 1;