lib/Catalyst/Script/Server.pm

   1 package Catalyst::Script::Server;
   2
   3 BEGIN {
   4     $ENV{CATALYST_ENGINE} ||= 'HTTP';
   5     require Catalyst::Engine::HTTP;
   6 }
   7
   8 use Moose;
   9 use MooseX::Types::Moose qw/ArrayRef Str Bool Int RegexpRef/;
  10 use namespace::autoclean;
  11
  12 with 'Catalyst::ScriptRole';
  13
  14 __PACKAGE__->meta->get_attribute('help')->cmd_aliases('?');
  15
  16 has debug => (
  17     traits => [qw(Getopt)],
  18     cmd_aliases => 'd',
  19     isa => Bool,
  20     is => 'ro',
  21     documentation => q{Force debug mode},
  22 );
  23
  24 has host => (
  25     traits => [qw(Getopt)],
  26     cmd_aliases => 'h',
  27     isa => Str,
  28     is => 'ro',
  29     default => 'localhost',
  30     documentation => 'Specify an IP on this host for the server to bind to',
  31 );
  32
  33 has fork => (
  34     traits => [qw(Getopt)],
  35     cmd_aliases => 'f',
  36     isa => Bool,
  37     is => 'ro',
  38     default => 0,
  39     documentation => 'Fork the server to be able to serve multiple requests at once',
  40 );
  41
  42 has port => (
  43     traits => [qw(Getopt)],
  44     cmd_aliases => 'p',
  45     isa => Int,
  46     is => 'ro',
  47     default => 3000,
  48     documentation => 'Specify a different listening port (to the default port 3000)',
  49 );
  50
  51 has pidfile => (
  52     traits => [qw(Getopt)],
  53     cmd_aliases => 'pid',
  54     isa => Str,
  55     is => 'ro',
  56     documentation => 'Specify a pidfile',
  57 );
  58
  59 has keepalive => (
  60     traits => [qw(Getopt)],
  61     cmd_aliases => 'k',
  62     isa => Bool,
  63     is => 'ro',
  64     default => 0,
  65     documentation => 'Support keepalive',
  66 );
  67
  68 has background => (
  69     traits => [qw(Getopt)],
  70     cmd_aliases => 'bg',
  71     isa => Bool,
  72     is => 'ro',
  73     default => 0,
  74     documentation => 'Run in the background',
  75 );
  76
  77 has restart => (
  78     traits => [qw(Getopt)],
  79     cmd_aliases => 'r',
  80     isa => Bool,
  81     is => 'ro',
  82     default => 0,
  83     documentation => 'use Catalyst::Restarter to detect code changes and restart the application',
  84 );
  85
  86 has restart_directory => (
  87     traits => [qw(Getopt)],
  88     cmd_aliases => 'rdir',
  89     isa => ArrayRef[Str],
  90     is  => 'ro',
  91     documentation => 'Restarter directory to watch',
  92     predicate => '_has_restart_directory',
  93 );
  94
  95 has restart_delay => (
  96     traits => [qw(Getopt)],
  97     cmd_aliases => 'rd',
  98     isa => Int,
  99     is => 'ro',
 100     documentation => 'Set a restart delay',
 101     predicate => '_has_restart_delay',
 102 );
 103
 104 {
 105     use Moose::Util::TypeConstraints;
 106
 107     my $tc = subtype as RegexpRef;
 108     coerce $tc, from Str, via { qr/$_/ };
 109
 110     MooseX::Getopt::OptionTypeMap->add_option_type_to_map($tc => '=s');
 111
 112     has restart_regex => (
 113         traits => [qw(Getopt)],
 114         cmd_aliases => 'rr',
 115         isa => $tc,
 116         coerce => 1,
 117         is => 'ro',
 118         documentation => 'Restart regex',
 119         predicate => '_has_restart_regex',
 120     );
 121 }
 122
 123 has follow_symlinks => (
 124     traits => [qw(Getopt)],
 125     cmd_aliases => 'sym',
 126     isa => Bool,
 127     is => 'ro',
 128     default => 0,
 129     documentation => 'Follow symbolic links',
 130     predicate => '_has_follow_symlinks',
 131 );
 132
 133 sub _restarter_args {
 134     my $self = shift;
 135
 136     my %args = (
 137         argv => $self->ARGV,
 138         start_sub => sub { $self->_run_application },
 139         ($self->_has_follow_symlinks   ? (follow_symlinks => $self->follow_symlinks)   : ()),
 140         ($self->_has_restart_delay     ? (sleep_interval  => $self->restart_delay)     : ()),
 141         ($self->_has_restart_directory ? (directories     => $self->restart_directory) : ()),
 142         ($self->_has_restart_regex     ? (filter          => $self->restart_regex)     : ()),
 143     );
 144
 145     return %args;
 146 }
 147
 148 sub run {
 149     my $self = shift;
 150
 151     local $ENV{CATALYST_DEBUG} = 1
 152         if $self->debug;
 153
 154     if ( $self->restart ) {
 155         die "Cannot run in the background and also watch for changed files.\n"
 156             if $self->background;
 157
 158         # If we load this here, then in the case of a restarter, it does not
 159         # need to be reloaded for each restart.
 160         require Catalyst;
 161
 162         # If this isn't done, then the Catalyst::Devel tests for the restarter
 163         # fail.
 164         $| = 1 if $ENV{HARNESS_ACTIVE};
 165
 166         require Catalyst::Restarter;
 167
 168         my $subclass = Catalyst::Restarter->pick_subclass;
 169
 170
 171         my $restarter = $subclass->new(
 172             $self->_restarter_args()
 173         );
 174
 175         $restarter->run_and_watch;
 176     }
 177     else {
 178         $self->_run_application;
 179     }
 180
 181
 182 }
 183
 184 sub _application_args {
 185     my ($self) = shift;
 186     return (
 187         $self->port,
 188         $self->host,
 189         {
 190            map { $_ => $self->$_ } qw/
 191                 fork
 192                 keepalive
 193                 background
 194                 pidfile
 195                 keepalive
 196                 follow_symlinks
 197             /,
 198         },
 199     );
 200 }
 201
 202 __PACKAGE__->meta->make_immutable;
 203
 204 1;
 205
 206 =head1 NAME
 207
 208 Catalyst::Script::Server - Catalyst test server
 209
 210 =head1 SYNOPSIS
 211
 212  myapp_server.pl [options]
 213
 214  Options:
 215    -d     --debug          force debug mode
 216    -f     --fork           handle each request in a new process
 217                       (defaults to false)
 218           --help           display this help and exits
 219    -h     --host           host (defaults to all)
 220    -p     --port           port (defaults to 3000)
 221    -k     --keepalive      enable keep-alive connections
 222    -r     --restart        restart when files get modified
 223                        (defaults to false)
 224    --rd   --restartdelay  delay between file checks
 225                       (ignored if you have Linux::Inotify2 installed)
 226    --rr   --restartregex  regex match files that trigger
 227                       a restart when modified
 228                       (defaults to '\.yml$|\.yaml$|\.conf|\.pm$')
 229    --rdir --restartdirectory  the directory to search for
 230                       modified files, can be set mulitple times
 231                       (defaults to '[SCRIPT_DIR]/..')
 232    --sym  --follow_symlinks   follow symlinks in search directories
 233                       (defaults to false. this is a no-op on Win32)
 234    --bg   --background        run the process in the background
 235    --pid  --pidfile           specify filename for pid file
 236
 237  See also:
 238    perldoc Catalyst::Manual
 239    perldoc Catalyst::Manual::Intro
 240
 241 =head1 DESCRIPTION
 242
 243 Run a Catalyst test server for this application.
 244
 245 =head1 AUTHORS
 246
 247 Catalyst Contributors, see Catalyst.pm
 248
 249 =head1 COPYRIGHT
 250
 251 This library is free software. You can redistribute it and/or modify
 252 it under the same terms as Perl itself.
 253
 254 =cut