lib/Catalyst/Script/Server.pm

   1 package Catalyst::Script::Server;
   2
   3 BEGIN {
   4     $ENV{CATALYST_ENGINE} ||= 'HTTP';
   5     require Catalyst::Engine::HTTP;
   6 }
   7
   8 use Moose;
   9 use MooseX::Types::Moose qw/ArrayRef Str Bool Int/;
  10 use namespace::autoclean;
  11
  12 with 'Catalyst::ScriptRole';
  13
  14 __PACKAGE__->meta->get_attribute('help')->cmd_aliases('?');
  15
  16 has debug => (
  17     traits => [qw(Getopt)],
  18     cmd_aliases => 'd',
  19     isa => Bool,
  20     is => 'ro',
  21     documentation => q{Force debug mode},
  22 );
  23
  24 has host => (
  25     traits => [qw(Getopt)],
  26     cmd_aliases => 'h',
  27     isa => Str,
  28     is => 'ro',
  29     default => 'localhost',
  30     documentation => 'Specify an IP on this host for the server to bind to',
  31 );
  32
  33 has fork => (
  34     traits => [qw(Getopt)],
  35     cmd_aliases => 'f',
  36     isa => Bool,
  37     is => 'ro',
  38     default => 0,
  39     documentation => 'Fork the server to be able to serve multiple requests at once',
  40 );
  41
  42 has port => (
  43     traits => [qw(Getopt)],
  44     cmd_aliases => 'p',
  45     isa => Int,
  46     is => 'ro',
  47     default => 3000,
  48     documentation => 'Specify a different listening port (to the default port 3000)',
  49 );
  50
  51 has pidfile => (
  52     traits => [qw(Getopt)],
  53     cmd_aliases => 'pid',
  54     isa => Str,
  55     is => 'ro',
  56     documentation => 'Specify a pidfile',
  57 );
  58
  59 has keepalive => (
  60     traits => [qw(Getopt)],
  61     cmd_aliases => 'k',
  62     isa => Bool,
  63     is => 'ro',
  64     default => 0,
  65     documentation => 'Support keepalive',
  66 );
  67
  68 has background => (
  69     traits => [qw(Getopt)],
  70     cmd_aliases => 'bg',
  71     isa => Bool,
  72     is => 'ro',
  73     default => 0,
  74     documentation => 'Run in the background',
  75 );
  76
  77 has restart => (
  78     traits => [qw(Getopt)],
  79     cmd_aliases => 'r',
  80     isa => Bool,
  81     is => 'ro',
  82     default => 0,
  83     documentation => 'use Catalyst::Restarter to detect code changes and restart the application',
  84 );
  85
  86 has restart_directory => (
  87     traits => [qw(Getopt)],
  88     cmd_aliases => 'rdir',
  89     isa => ArrayRef[Str],
  90     is  => 'ro',
  91     documentation => 'Restarter directory to watch',
  92     predicate => '_has_restart_directory',
  93 );
  94
  95 has restart_delay => (
  96     traits => [qw(Getopt)],
  97     cmd_aliases => 'rd',
  98     isa => Int,
  99     is => 'ro',
 100     documentation => 'Set a restart delay',
 101     predicate => '_has_restart_delay',
 102 );
 103
 104 has restart_regex => (
 105     traits => [qw(Getopt)],
 106     cmd_aliases => 'rr',
 107     isa => Str,
 108     is => 'ro',
 109     documentation => 'Restart regex',
 110     predicate => '_has_restart_regex',
 111 );
 112
 113 has follow_symlinks => (
 114     traits => [qw(Getopt)],
 115     cmd_aliases => 'sym',
 116     isa => Bool,
 117     is => 'ro',
 118     default => 0,
 119     documentation => 'Follow symbolic links',
 120     predicate => '_has_follow_symlinks',
 121 );
 122
 123 sub _restarter_args {
 124     my $self = shift;
 125
 126     my %args = (
 127         argv => $self->ARGV,
 128         start_sub => sub { $self->_run_application },
 129         ($self->_has_follow_symlinks   ? (follow_symlinks => $self->follow_symlinks)   : ()),
 130         ($self->_has_restart_delay     ? (sleep_interval  => $self->restart_delay)     : ()),
 131         ($self->_has_restart_directory ? (directories     => $self->restart_directory) : ()),
 132         ($self->_has_restart_regex     ? (filter          => qr/${\$self->restart_regex}/) : ()),
 133     );
 134
 135     return %args;
 136 }
 137
 138 sub run {
 139     my $self = shift;
 140
 141     local $ENV{CATALYST_DEBUG} = 1
 142         if $self->debug;
 143
 144     if ( $self->restart ) {
 145         die "Cannot run in the background and also watch for changed files.\n"
 146             if $self->background;
 147
 148         # If we load this here, then in the case of a restarter, it does not
 149         # need to be reloaded for each restart.
 150         require Catalyst;
 151
 152         # If this isn't done, then the Catalyst::Devel tests for the restarter
 153         # fail.
 154         $| = 1 if $ENV{HARNESS_ACTIVE};
 155
 156         require Catalyst::Restarter;
 157
 158         my $subclass = Catalyst::Restarter->pick_subclass;
 159
 160
 161         my $restarter = $subclass->new(
 162             $self->_restarter_args()
 163         );
 164
 165         $restarter->run_and_watch;
 166     }
 167     else {
 168         $self->_run_application;
 169     }
 170
 171
 172 }
 173
 174 sub _application_args {
 175     my ($self) = shift;
 176     return (
 177         $self->port,
 178         $self->host,
 179         {
 180            map { $_ => $self->$_ } qw/
 181                 fork
 182                 keepalive
 183                 background
 184                 pidfile
 185                 keepalive
 186                 follow_symlinks
 187             /,
 188         },
 189     );
 190 }
 191
 192 __PACKAGE__->meta->make_immutable;
 193
 194 1;
 195
 196 =head1 NAME
 197
 198 Catalyst::Script::Server - Catalyst test server
 199
 200 =head1 SYNOPSIS
 201
 202  myapp_server.pl [options]
 203
 204  Options:
 205    -d     --debug          force debug mode
 206    -f     --fork           handle each request in a new process
 207                       (defaults to false)
 208           --help           display this help and exits
 209    -h     --host           host (defaults to all)
 210    -p     --port           port (defaults to 3000)
 211    -k     --keepalive      enable keep-alive connections
 212    -r     --restart        restart when files get modified
 213                        (defaults to false)
 214    --rd   --restartdelay  delay between file checks
 215                       (ignored if you have Linux::Inotify2 installed)
 216    --rr   --restartregex  regex match files that trigger
 217                       a restart when modified
 218                       (defaults to '\.yml$|\.yaml$|\.conf|\.pm$')
 219    --rdir --restartdirectory  the directory to search for
 220                       modified files, can be set mulitple times
 221                       (defaults to '[SCRIPT_DIR]/..')
 222    --sym  --follow_symlinks   follow symlinks in search directories
 223                       (defaults to false. this is a no-op on Win32)
 224    --bg   --background        run the process in the background
 225    --pid  --pidfile           specify filename for pid file
 226
 227  See also:
 228    perldoc Catalyst::Manual
 229    perldoc Catalyst::Manual::Intro
 230
 231 =head1 DESCRIPTION
 232
 233 Run a Catalyst test server for this application.
 234
 235 =head1 AUTHORS
 236
 237 Catalyst Contributors, see Catalyst.pm
 238
 239 =head1 COPYRIGHT
 240
 241 This library is free software. You can redistribute it and/or modify
 242 it under the same terms as Perl itself.
 243
 244 =cut