lib/Catalyst/Script/FastCGI.pm

   1 package Catalyst::Script::FastCGI;
   2 use Moose;
   3 use MooseX::Types::Moose qw/Str Bool Int/;
   4 use Data::OptList;
   5 use namespace::autoclean;
   6
   7 sub _plack_engine_name { 'FCGI' }
   8
   9 with 'Catalyst::ScriptRole';
  10
  11 has listen => (
  12     traits        => [qw(Getopt)],
  13     cmd_aliases   => 'l',
  14     isa           => Str,
  15     is            => 'ro',
  16     documentation => 'Specify a listening port/socket',
  17 );
  18
  19 has pidfile => (
  20     traits        => [qw(Getopt)],
  21     cmd_aliases   => [qw/pid p/],
  22     isa           => Str,
  23     is            => 'ro',
  24     documentation => 'Specify a pidfile',
  25 );
  26
  27 has daemon => (
  28     traits        => [qw(Getopt)],
  29     isa           => Bool,
  30     is            => 'ro',
  31     cmd_aliases   => [qw/d detach/], # Eww, detach is here as we fucked it up.. Deliberately not documented
  32     documentation => 'Daemonize (go into the background)',
  33 );
  34
  35 has manager => (
  36     traits        => [qw(Getopt)],
  37     isa           => Str,
  38     is            => 'ro',
  39     cmd_aliases   => 'M',
  40     documentation => 'Use a different FastCGI process manager class',
  41 );
  42
  43 has keeperr => (
  44     traits        => [qw(Getopt)],
  45     cmd_aliases   => 'e',
  46     isa           => Bool,
  47     is            => 'ro',
  48     documentation => 'Log STDERR',
  49 );
  50
  51 has nproc => (
  52     traits        => [qw(Getopt)],
  53     cmd_aliases   => 'n',
  54     isa           => Int,
  55     is            => 'ro',
  56     documentation => 'Specify a number of child processes',
  57 );
  58
  59 has proc_title => (
  60     traits        => [qw(Getopt)],
  61     isa           => Str,
  62     is            => 'ro',
  63     lazy          => 1,
  64     builder       => '_build_proc_title',
  65     documentation => 'Set the process title',
  66 );
  67
  68 sub _build_proc_title {
  69     my ($self) = @_;
  70     return sprintf 'perl-fcgi-pm [%s]', $self->application_name;
  71 }
  72
  73 sub BUILD {
  74     my ($self) = @_;
  75     $self->proc_title;
  76 }
  77
  78 # Munge the 'listen' arg so that Plack::Handler::FCGI will accept it.
  79 sub _listen {
  80     my ($self) = @_;
  81
  82     if (defined (my $listen = $self->listen)) {
  83         return [ $listen ];
  84     } else {
  85         return undef;
  86     }
  87 }
  88
  89 sub _plack_loader_args {
  90     my ($self) = shift;
  91
  92     my $opts = Data::OptList::mkopt([
  93       qw/pidfile manager nproc proc_title/,
  94             detach          => [ 'daemon' ],
  95             keep_stderr     => [ 'keeperr' ],
  96             listen          => [ '_listen' ],
  97         ]);
  98
  99     my %args = map { $_->[0] => $self->${ \($_->[1] ? $_->[1]->[0] : $_->[0]) } } @$opts;
 100
 101     # Plack::Handler::FCGI thinks manager => undef means "use no manager".
 102     delete $args{'manager'} unless defined $args{'manager'};
 103
 104     return %args;
 105 }
 106
 107 sub _application_args {
 108     my ($self) = shift;
 109     return (
 110         $self->listen,
 111         {
 112             nproc       => $self->nproc,
 113             pidfile     => $self->pidfile,
 114             manager     => $self->manager,
 115             detach      => $self->daemon,
 116             keep_stderr => $self->keeperr,
 117             proc_title  => $self->proc_title,
 118         }
 119     );
 120 }
 121
 122 __PACKAGE__->meta->make_immutable;
 123
 124 =head1 NAME
 125
 126 Catalyst::Script::FastCGI - The FastCGI Catalyst Script
 127
 128 =head1 SYNOPSIS
 129
 130   myapp_fastcgi.pl [options]
 131
 132  Options:
 133    -? --help       display this help and exits
 134    -l --listen     Socket path to listen on
 135                    (defaults to standard input)
 136                    can be HOST:PORT, :PORT or a
 137                    filesystem path
 138    -n --nproc      specify number of processes to keep
 139                    to serve requests (defaults to 1,
 140                    requires -listen)
 141    -p --pidfile    specify filename for pid file
 142                    (requires -listen)
 143    -d --daemon     daemonize (requires -listen)
 144    -M --manager    specify alternate process manager
 145                    (FCGI::ProcManager sub-class)
 146                    or empty string to disable
 147    -e --keeperr    send error messages to STDOUT, not
 148                    to the webserver
 149       --proc_title set the process title
 150
 151 =head1 DESCRIPTION
 152
 153 Run a Catalyst application as fastcgi.
 154
 155 =head1 AUTHORS
 156
 157 Catalyst Contributors, see Catalyst.pm
 158
 159 =head1 COPYRIGHT
 160
 161 This library is free software. You can redistribute it and/or modify it under
 162 the same terms as Perl itself.
 163
 164 =cut