lib/Catalyst/Response.pm

   1 package Catalyst::Response;
   2
   3 use Moose;
   4 use HTTP::Headers;
   5 use Moose::Util::TypeConstraints;
   6 use namespace::autoclean;
   7
   8 with 'MooseX::Emulate::Class::Accessor::Fast';
   9
  10 has _response_cb => (
  11     is      => 'ro',
  12     isa     => 'CodeRef',
  13     writer  => '_set_response_cb',
  14     clearer => '_clear_response_cb',
  15     predicate => '_has_response_cb',
  16 );
  17
  18 subtype 'Catalyst::Engine::Types::Writer',
  19     as duck_type([qw(write close)]);
  20
  21 has _writer => (
  22     is      => 'ro',
  23     isa     => 'Catalyst::Engine::Types::Writer',
  24     writer  => '_set_writer',
  25     clearer => '_clear_writer',
  26     predicate => '_has_writer',
  27 );
  28
  29 has write_fh => (
  30   is=>'ro',
  31   predicate=>'has_write_fh',
  32   lazy_build=>1);
  33
  34   sub _build_write_fh {
  35     my $self = shift;
  36     $self->_context->finalize_headers unless
  37       $self->finalized_headers;
  38     $self->_writer;
  39   };
  40
  41 sub DEMOLISH {
  42   my $self = shift;
  43   return if $self->has_write_fh;
  44   if($self->_has_writer) {
  45     $self->_writer->close
  46   }
  47 }
  48
  49 has cookies   => (is => 'rw', default => sub { {} });
  50 has body      => (is => 'rw', default => undef);
  51 sub has_body { defined($_[0]->body) }
  52
  53 has location  => (is => 'rw');
  54 has status    => (is => 'rw', default => 200);
  55 has finalized_headers => (is => 'rw', default => 0);
  56 has headers   => (
  57   is      => 'rw',
  58   isa => 'HTTP::Headers',
  59   handles => [qw(content_encoding content_length content_type header)],
  60   default => sub { HTTP::Headers->new() },
  61   required => 1,
  62   lazy => 1,
  63 );
  64 has _context => (
  65   is => 'rw',
  66   weak_ref => 1,
  67   clearer => '_clear_context',
  68 );
  69
  70 sub output { shift->body(@_) }
  71
  72 sub code   { shift->status(@_) }
  73
  74 sub write {
  75     my ( $self, $buffer ) = @_;
  76
  77     # Finalize headers if someone manually writes output
  78     $self->_context->finalize_headers unless $self->finalized_headers;
  79
  80     $buffer = q[] unless defined $buffer;
  81
  82     my $len = length($buffer);
  83     $self->_writer->write($buffer);
  84
  85     return $len;
  86 }
  87
  88 sub finalize_headers {
  89     my ($self) = @_;
  90
  91     # This is a less-than-pretty hack to avoid breaking the old
  92     # Catalyst::Engine::PSGI. 5.9 Catalyst::Engine sets a response_cb and
  93     # expects us to pass headers to it here, whereas Catalyst::Enngine::PSGI
  94     # just pulls the headers out of $ctx->response in its run method and never
  95     # sets response_cb. So take the lack of a response_cb as a sign that we
  96     # don't need to set the headers.
  97
  98     return unless $self->_has_response_cb;
  99
 100     # If we already have a writer, we already did this, so don't do it again
 101     return if $self->_has_writer;
 102
 103     my @headers;
 104     $self->headers->scan(sub { push @headers, @_ });
 105
 106     my $writer = $self->_response_cb->([ $self->status, \@headers ]);
 107     $self->_set_writer($writer);
 108     $self->_clear_response_cb;
 109
 110     return;
 111 }
 112
 113 =head1 NAME
 114
 115 Catalyst::Response - stores output responding to the current client request
 116
 117 =head1 SYNOPSIS
 118
 119     $res = $c->response;
 120     $res->body;
 121     $res->code;
 122     $res->content_encoding;
 123     $res->content_length;
 124     $res->content_type;
 125     $res->cookies;
 126     $res->header;
 127     $res->headers;
 128     $res->output;
 129     $res->redirect;
 130     $res->status;
 131     $res->write;
 132
 133 =head1 DESCRIPTION
 134
 135 This is the Catalyst Response class, which provides methods for responding to
 136 the current client request. The appropriate L<Catalyst::Engine> for your environment
 137 will turn the Catalyst::Response into a HTTP Response and return it to the client.
 138
 139 =head1 METHODS
 140
 141 =head2 $res->body( $text | $fh | $iohandle_object )
 142
 143     $c->response->body('Catalyst rocks!');
 144
 145 Sets or returns the output (text or binary data). If you are returning a large body,
 146 you might want to use a L<IO::Handle> type of object (Something that implements the read method
 147 in the same fashion), or a filehandle GLOB. Catalyst
 148 will write it piece by piece into the response.
 149
 150 =head2 $res->has_body
 151
 152 Predicate which returns true when a body has been set.
 153
 154 =head2 $res->code
 155
 156 Alias for $res->status.
 157
 158 =head2 $res->content_encoding
 159
 160 Shortcut for $res->headers->content_encoding.
 161
 162 =head2 $res->content_length
 163
 164 Shortcut for $res->headers->content_length.
 165
 166 =head2 $res->content_type
 167
 168 Shortcut for $res->headers->content_type.
 169
 170 This value is typically set by your view or plugin. For example,
 171 L<Catalyst::Plugin::Static::Simple> will guess the mime type based on the file
 172 it found, while L<Catalyst::View::TT> defaults to C<text/html>.
 173
 174 =head2 $res->cookies
 175
 176 Returns a reference to a hash containing cookies to be set. The keys of the
 177 hash are the cookies' names, and their corresponding values are hash
 178 references used to construct a L<CGI::Simple::Cookie> object.
 179
 180     $c->response->cookies->{foo} = { value => '123' };
 181
 182 The keys of the hash reference on the right correspond to the L<CGI::Simple::Cookie>
 183 parameters of the same name, except they are used without a leading dash.
 184 Possible parameters are:
 185
 186 =over
 187
 188 =item value
 189
 190 =item expires
 191
 192 =item domain
 193
 194 =item path
 195
 196 =item secure
 197
 198 =item httponly
 199
 200 =back
 201
 202 =head2 $res->header
 203
 204 Shortcut for $res->headers->header.
 205
 206 =head2 $res->headers
 207
 208 Returns an L<HTTP::Headers> object, which can be used to set headers.
 209
 210     $c->response->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
 211
 212 =head2 $res->output
 213
 214 Alias for $res->body.
 215
 216 =head2 $res->redirect( $url, $status )
 217
 218 Causes the response to redirect to the specified URL. The default status is
 219 C<302>.
 220
 221     $c->response->redirect( 'http://slashdot.org' );
 222     $c->response->redirect( 'http://slashdot.org', 307 );
 223
 224 This is a convenience method that sets the Location header to the
 225 redirect destination, and then sets the response status.  You will
 226 want to C< return > or C<< $c->detach() >> to interrupt the normal
 227 processing flow if you want the redirect to occur straight away.
 228
 229 B<Note:> do not give a relative URL as $url, i.e: one that is not fully
 230 qualified (= C<http://...>, etc.) or that starts with a slash
 231 (= C</path/here>). While it may work, it is not guaranteed to do the right
 232 thing and is not a standard behaviour. You may opt to use uri_for() or
 233 uri_for_action() instead.
 234
 235 =cut
 236
 237 sub redirect {
 238     my $self = shift;
 239
 240     if (@_) {
 241         my $location = shift;
 242         my $status   = shift || 302;
 243
 244         $self->location($location);
 245         $self->status($status);
 246     }
 247
 248     return $self->location;
 249 }
 250
 251 =head2 $res->location
 252
 253 Sets or returns the HTTP 'Location'.
 254
 255 =head2 $res->status
 256
 257 Sets or returns the HTTP status.
 258
 259     $c->response->status(404);
 260
 261 $res->code is an alias for this, to match HTTP::Response->code.
 262
 263 =head2 $res->write( $data )
 264
 265 Writes $data to the output stream.
 266
 267 =head2 $res->write_fh
 268
 269 Returns a PSGI $writer object that has two methods, write and close.  You can
 270 close over this object for asynchronous and nonblocking applications.  For
 271 example (assuming you are using a supporting server, like L<Twiggy>
 272
 273     package AsyncExample::Controller::Root;
 274
 275     use Moose;
 276
 277     BEGIN { extends 'Catalyst::Controller' }
 278
 279     sub prepare_cb {
 280       my $write_fh = pop;
 281       return sub {
 282         my $message = shift;
 283         $write_fh->write("Finishing: $message\n");
 284         $write_fh->close;
 285       };
 286     }
 287
 288     sub anyevent :Local :Args(0) {
 289       my ($self, $c) = @_;
 290       my $cb = $self->prepare_cb($c->res->write_fh);
 291
 292       my $watcher;
 293       $watcher = AnyEvent->timer(
 294         after => 5,
 295         cb => sub {
 296           $cb->(scalar localtime);
 297           undef $watcher; # cancel circular-ref
 298         });
 299     }
 300
 301 =head2 $res->print( @data )
 302
 303 Prints @data to the output stream, separated by $,.  This lets you pass
 304 the response object to functions that want to write to an L<IO::Handle>.
 305
 306 =head2 $self->finalize_headers($c)
 307
 308 Writes headers to response if not already written
 309
 310 =head2 DEMOLISH
 311
 312 Ensures that the response is flushed and closed at the end of the
 313 request.
 314
 315 =head2 meta
 316
 317 Provided by Moose
 318
 319 =cut
 320
 321 sub print {
 322     my $self = shift;
 323     my $data = shift;
 324
 325     defined $self->write($data) or return;
 326
 327     for (@_) {
 328         defined $self->write($,) or return;
 329         defined $self->write($_) or return;
 330     }
 331     defined $self->write($\) or return;
 332
 333     return 1;
 334 }
 335
 336 =head1 AUTHORS
 337
 338 Catalyst Contributors, see Catalyst.pm
 339
 340 =head1 COPYRIGHT
 341
 342 This library is free software. You can redistribute it and/or modify
 343 it under the same terms as Perl itself.
 344
 345 =cut
 346
 347 __PACKAGE__->meta->make_immutable;
 348
 349 1;