lib/Catalyst/Response.pm

   1 package Catalyst::Response;
   2
   3 use Moose;
   4 use HTTP::Headers;
   5 use Moose::Util::TypeConstraints;
   6 use namespace::autoclean;
   7
   8 with 'MooseX::Emulate::Class::Accessor::Fast';
   9
  10 has _response_cb => (
  11     is      => 'ro',
  12     isa     => 'CodeRef',
  13     writer  => '_set_response_cb',
  14     clearer => '_clear_response_cb',
  15     predicate => '_has_response_cb',
  16 );
  17
  18 subtype 'Catalyst::Engine::Types::Writer',
  19     as duck_type([qw(write close)]);
  20
  21 has _writer => (
  22     is      => 'ro',
  23     isa     => 'Catalyst::Engine::Types::Writer',
  24     writer  => '_set_writer',
  25     clearer => '_clear_writer',
  26     predicate => '_has_writer',
  27 );
  28
  29 sub DEMOLISH { $_[0]->_writer->close if $_[0]->_has_writer }
  30
  31 has cookies   => (is => 'rw', default => sub { {} });
  32 has body      => (is => 'rw', default => undef);
  33 sub has_body { defined($_[0]->body) }
  34
  35 has location  => (is => 'rw');
  36 has status    => (is => 'rw', default => 200);
  37 has finalized_headers => (is => 'rw', default => 0);
  38 has headers   => (
  39   is      => 'rw',
  40   isa => 'HTTP::Headers',
  41   handles => [qw(content_encoding content_length content_type header)],
  42   default => sub { HTTP::Headers->new() },
  43   required => 1,
  44   lazy => 1,
  45 );
  46
  47 sub output { shift->body(@_) }
  48
  49 sub code   { shift->status(@_) }
  50
  51 =head2 $self->write($buffer)
  52
  53 Writes the buffer to the client.
  54
  55 =cut
  56
  57 sub write {
  58     my ( $self, $buffer ) = @_;
  59
  60     # Finalize headers if someone manually writes output
  61     $self->finalize_headers;
  62
  63     $buffer = q[] unless defined $buffer;
  64
  65     my $len = length($buffer);
  66     $self->_writer->write($buffer);
  67
  68     return $len;
  69 }
  70
  71 =head2 $self->finalize_headers($c)
  72
  73 Abstract method, allows engines to write headers to response
  74
  75 =cut
  76
  77 sub finalize_headers {
  78     my ($self) = @_;
  79
  80     # This is a less-than-pretty hack to avoid breaking the old
  81     # Catalyst::Engine::PSGI. 5.9 Catalyst::Engine sets a response_cb and
  82     # expects us to pass headers to it here, whereas Catalyst::Enngine::PSGI
  83     # just pulls the headers out of $ctx->response in its run method and never
  84     # sets response_cb. So take the lack of a response_cb as a sign that we
  85     # don't need to set the headers.
  86
  87     return unless $self->_has_response_cb;
  88
  89     # If we already have a writer, we already did this, so don't do it again
  90     return if $self->_has_writer;
  91
  92     my @headers;
  93     $self->headers->scan(sub { push @headers, @_ });
  94
  95     my $writer = $self->_response_cb->([ $self->status, \@headers ]);
  96     $self->_set_writer($writer);
  97     $self->_clear_response_cb;
  98
  99     return;
 100 }
 101
 102 =head1 NAME
 103
 104 Catalyst::Response - stores output responding to the current client request
 105
 106 =head1 SYNOPSIS
 107
 108     $res = $c->response;
 109     $res->body;
 110     $res->code;
 111     $res->content_encoding;
 112     $res->content_length;
 113     $res->content_type;
 114     $res->cookies;
 115     $res->header;
 116     $res->headers;
 117     $res->output;
 118     $res->redirect;
 119     $res->status;
 120     $res->write;
 121
 122 =head1 DESCRIPTION
 123
 124 This is the Catalyst Response class, which provides methods for responding to
 125 the current client request. The appropriate L<Catalyst::Engine> for your environment
 126 will turn the Catalyst::Response into a HTTP Response and return it to the client.
 127
 128 =head1 METHODS
 129
 130 =head2 $res->body( $text | $fh | $iohandle_object )
 131
 132     $c->response->body('Catalyst rocks!');
 133
 134 Sets or returns the output (text or binary data). If you are returning a large body,
 135 you might want to use a L<IO::Handle> type of object (Something that implements the read method
 136 in the same fashion), or a filehandle GLOB. Catalyst
 137 will write it piece by piece into the response.
 138
 139 =head2 $res->has_body
 140
 141 Predicate which returns true when a body has been set.
 142
 143 =head2 $res->code
 144
 145 Alias for $res->status.
 146
 147 =head2 $res->content_encoding
 148
 149 Shortcut for $res->headers->content_encoding.
 150
 151 =head2 $res->content_length
 152
 153 Shortcut for $res->headers->content_length.
 154
 155 =head2 $res->content_type
 156
 157 Shortcut for $res->headers->content_type.
 158
 159 This value is typically set by your view or plugin. For example,
 160 L<Catalyst::Plugin::Static::Simple> will guess the mime type based on the file
 161 it found, while L<Catalyst::View::TT> defaults to C<text/html>.
 162
 163 =head2 $res->cookies
 164
 165 Returns a reference to a hash containing cookies to be set. The keys of the
 166 hash are the cookies' names, and their corresponding values are hash
 167 references used to construct a L<CGI::Simple::Cookie> object.
 168
 169     $c->response->cookies->{foo} = { value => '123' };
 170
 171 The keys of the hash reference on the right correspond to the L<CGI::Simple::Cookie>
 172 parameters of the same name, except they are used without a leading dash.
 173 Possible parameters are:
 174
 175 =over
 176
 177 =item value
 178
 179 =item expires
 180
 181 =item domain
 182
 183 =item path
 184
 185 =item secure
 186
 187 =item httponly
 188
 189 =back
 190
 191 =head2 $res->header
 192
 193 Shortcut for $res->headers->header.
 194
 195 =head2 $res->headers
 196
 197 Returns an L<HTTP::Headers> object, which can be used to set headers.
 198
 199     $c->response->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
 200
 201 =head2 $res->output
 202
 203 Alias for $res->body.
 204
 205 =head2 $res->redirect( $url, $status )
 206
 207 Causes the response to redirect to the specified URL. The default status is
 208 C<302>.
 209
 210     $c->response->redirect( 'http://slashdot.org' );
 211     $c->response->redirect( 'http://slashdot.org', 307 );
 212
 213 This is a convenience method that sets the Location header to the
 214 redirect destination, and then sets the response status.  You will
 215 want to C< return > or C<< $c->detach() >> to interrupt the normal
 216 processing flow if you want the redirect to occur straight away.
 217
 218 B<Note:> do not give a relative URL as $url, i.e: one that is not fully
 219 qualified (= C<http://...>, etc.) or that starts with a slash
 220 (= C</path/here>). While it may work, it is not guaranteed to do the right
 221 thing and is not a standard behaviour. You may opt to use uri_for() or
 222 uri_for_action() instead.
 223
 224 =cut
 225
 226 sub redirect {
 227     my $self = shift;
 228
 229     if (@_) {
 230         my $location = shift;
 231         my $status   = shift || 302;
 232
 233         $self->location($location);
 234         $self->status($status);
 235     }
 236
 237     return $self->location;
 238 }
 239
 240 =head2 $res->location
 241
 242 Sets or returns the HTTP 'Location'.
 243
 244 =head2 $res->status
 245
 246 Sets or returns the HTTP status.
 247
 248     $c->response->status(404);
 249
 250 $res->code is an alias for this, to match HTTP::Response->code.
 251
 252 =head2 $res->write( $data )
 253
 254 Writes $data to the output stream.
 255
 256 =head2 $res->print( @data )
 257
 258 Prints @data to the output stream, separated by $,.  This lets you pass
 259 the response object to functions that want to write to an L<IO::Handle>.
 260
 261 =head2 DEMOLISH
 262
 263 Ensures that the response is flushed and closed at the end of the
 264 request.
 265
 266 =head2 meta
 267
 268 Provided by Moose
 269
 270 =cut
 271
 272 sub print {
 273     my $self = shift;
 274     my $data = shift;
 275
 276     defined $self->write($data) or return;
 277
 278     for (@_) {
 279         defined $self->write($,) or return;
 280         defined $self->write($_) or return;
 281     }
 282     defined $self->write($\) or return;
 283
 284     return 1;
 285 }
 286
 287 =head1 AUTHORS
 288
 289 Catalyst Contributors, see Catalyst.pm
 290
 291 =head1 COPYRIGHT
 292
 293 This library is free software. You can redistribute it and/or modify
 294 it under the same terms as Perl itself.
 295
 296 =cut
 297
 298 __PACKAGE__->meta->make_immutable;
 299
 300 1;