lib/Catalyst/Response.pm

   1 package Catalyst::Response;
   2
   3 use Moose;
   4 use HTTP::Headers;
   5
   6 with 'MooseX::Emulate::Class::Accessor::Fast';
   7
   8 has cookies   => (is => 'rw', default => sub { {} });
   9 has body      => (is => 'rw', default => '');
  10 has location  => (is => 'rw');
  11 has status    => (is => 'rw', default => 200);
  12 has finalized_headers => (is => 'rw', default => 0);
  13 has headers   => (
  14   is      => 'rw',
  15   handles => [qw(content_encoding content_length content_type header)],
  16   default => sub { HTTP::Headers->new() },
  17   required => 1,
  18   lazy => 1,
  19 );
  20 has _context => (
  21   is => 'rw',
  22   weak_ref => 1,
  23   handles => ['write'],
  24 );
  25
  26 sub output { shift->body(@_) }
  27
  28 no Moose;
  29
  30 =head1 NAME
  31
  32 Catalyst::Response - stores output responding to the current client request
  33
  34 =head1 SYNOPSIS
  35
  36     $res = $c->response;
  37     $res->body;
  38     $res->content_encoding;
  39     $res->content_length;
  40     $res->content_type;
  41     $res->cookies;
  42     $res->header;
  43     $res->headers;
  44     $res->output;
  45     $res->redirect;
  46     $res->status;
  47     $res->write;
  48
  49 =head1 DESCRIPTION
  50
  51 This is the Catalyst Response class, which provides methods for responding to
  52 the current client request. The appropriate L<Catalyst::Engine> for your environment
  53 will turn the Catalyst::Response into a HTTP Response and return it to the client.
  54
  55 =head1 METHODS
  56
  57 =head2 $res->body(<$text|$fh|$iohandle_object)
  58
  59     $c->response->body('Catalyst rocks!');
  60
  61 Sets or returns the output (text or binary data). If you are returning a large body,
  62 you might want to use a L<IO::Handle> type of object (Something that implements the read method
  63 in the same fashion), or a filehandle GLOB. Catalyst
  64 will write it piece by piece into the response.
  65
  66 =head2 $res->content_encoding
  67
  68 Shortcut for $res->headers->content_encoding.
  69
  70 =head2 $res->content_length
  71
  72 Shortcut for $res->headers->content_length.
  73
  74 =head2 $res->content_type
  75
  76 Shortcut for $res->headers->content_type.
  77
  78 This value is typically set by your view or plugin. For example,
  79 L<Catalyst::Plugin::Static::Simple> will guess the mime type based on the file
  80 it found, while L<Catalyst::View::TT> defaults to C<text/html>.
  81
  82 =head2 $res->cookies
  83
  84 Returns a reference to a hash containing cookies to be set. The keys of the
  85 hash are the cookies' names, and their corresponding values are hash
  86 references used to construct a L<CGI::Cookie> object.
  87
  88     $c->response->cookies->{foo} = { value => '123' };
  89
  90 The keys of the hash reference on the right correspond to the L<CGI::Cookie>
  91 parameters of the same name, except they are used without a leading dash.
  92 Possible parameters are:
  93
  94 =over
  95
  96 =item value
  97
  98 =item expires
  99
 100 =item domain
 101
 102 =item path
 103
 104 =item secure
 105
 106 =back
 107
 108 =head2 $res->header
 109
 110 Shortcut for $res->headers->header.
 111
 112 =head2 $res->headers
 113
 114 Returns an L<HTTP::Headers> object, which can be used to set headers.
 115
 116     $c->response->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
 117
 118 =head2 $res->output
 119
 120 Alias for $res->body.
 121
 122 =head2 $res->redirect( $url, $status )
 123
 124 Causes the response to redirect to the specified URL. The default status is
 125 C<302>.
 126
 127     $c->response->redirect( 'http://slashdot.org' );
 128     $c->response->redirect( 'http://slashdot.org', 307 );
 129
 130 This is a convenience method that sets the Location header to the
 131 redirect destination, and then sets the response status.  You will
 132 want to C< return; > or C< $c->detach() > to interrupt the normal
 133 processing flow if you want the redirect to occur straight away.
 134
 135 =cut
 136
 137 sub redirect {
 138     my $self = shift;
 139
 140     if (@_) {
 141         my $location = shift;
 142         my $status   = shift || 302;
 143
 144         $self->location($location);
 145         $self->status($status);
 146     }
 147
 148     return $self->location;
 149 }
 150
 151 =head2 $res->location
 152
 153 Sets or returns the HTTP 'Location'.
 154
 155 =head2 $res->status
 156
 157 Sets or returns the HTTP status.
 158
 159     $c->response->status(404);
 160
 161 =head2 $res->write( $data )
 162
 163 Writes $data to the output stream.
 164
 165 =head2 meta
 166
 167 Provided by Moose
 168
 169 =head2 $res->print( @data )
 170
 171 Prints @data to the output stream, separated by $,.  This lets you pass
 172 the response object to functions that want to write to an L<IO::Handle>.
 173
 174 =cut
 175
 176 sub print {
 177     my $self = shift;
 178     my $data = shift;
 179
 180     defined $self->write($data) or return;
 181
 182     for (@_) {
 183         defined $self->write($,) or return;
 184         defined $self->write($_) or return;
 185     }
 186
 187     return 1;
 188 }
 189
 190 =head1 AUTHORS
 191
 192 Catalyst Contributors, see Catalyst.pm
 193
 194 =head1 COPYRIGHT
 195
 196 This program is free software, you can redistribute it and/or modify
 197 it under the same terms as Perl itself.
 198
 199 =cut
 200
 201 __PACKAGE__->meta->make_immutable;
 202
 203 1;