lib/Catalyst/Response.pm

   1 package Catalyst::Response;
   2
   3 use Moose;
   4 use HTTP::Headers;
   5
   6 with 'MooseX::Emulate::Class::Accessor::Fast';
   7
   8 has cookies   => (is => 'rw', default => sub { {} });
   9 has body      => (is => 'rw', default => '', lazy => 1, predicate => 'has_body');
  10 has location  => (is => 'rw');
  11 has status    => (is => 'rw', default => 200);
  12 has finalized_headers => (is => 'rw', default => 0);
  13 has headers   => (
  14   is      => 'rw',
  15   handles => [qw(content_encoding content_length content_type header)],
  16   default => sub { HTTP::Headers->new() },
  17   required => 1,
  18   lazy => 1,
  19 );
  20 has _context => (
  21   is => 'rw',
  22   weak_ref => 1,
  23   handles => ['write'],
  24   clearer => '_clear_context',
  25 );
  26
  27 sub output { shift->body(@_) }
  28
  29 no Moose;
  30
  31 =head1 NAME
  32
  33 Catalyst::Response - stores output responding to the current client request
  34
  35 =head1 SYNOPSIS
  36
  37     $res = $c->response;
  38     $res->body;
  39     $res->content_encoding;
  40     $res->content_length;
  41     $res->content_type;
  42     $res->cookies;
  43     $res->header;
  44     $res->headers;
  45     $res->output;
  46     $res->redirect;
  47     $res->status;
  48     $res->write;
  49
  50 =head1 DESCRIPTION
  51
  52 This is the Catalyst Response class, which provides methods for responding to
  53 the current client request. The appropriate L<Catalyst::Engine> for your environment
  54 will turn the Catalyst::Response into a HTTP Response and return it to the client.
  55
  56 =head1 METHODS
  57
  58 =head2 $res->body(<$text|$fh|$iohandle_object)
  59
  60     $c->response->body('Catalyst rocks!');
  61
  62 Sets or returns the output (text or binary data). If you are returning a large body,
  63 you might want to use a L<IO::Handle> type of object (Something that implements the read method
  64 in the same fashion), or a filehandle GLOB. Catalyst
  65 will write it piece by piece into the response.
  66
  67 =head2 $res->has_body
  68
  69 Predicate which returns true when a body has been set.
  70
  71 =head2 $res->content_encoding
  72
  73 Shortcut for $res->headers->content_encoding.
  74
  75 =head2 $res->content_length
  76
  77 Shortcut for $res->headers->content_length.
  78
  79 =head2 $res->content_type
  80
  81 Shortcut for $res->headers->content_type.
  82
  83 This value is typically set by your view or plugin. For example,
  84 L<Catalyst::Plugin::Static::Simple> will guess the mime type based on the file
  85 it found, while L<Catalyst::View::TT> defaults to C<text/html>.
  86
  87 =head2 $res->cookies
  88
  89 Returns a reference to a hash containing cookies to be set. The keys of the
  90 hash are the cookies' names, and their corresponding values are hash
  91 references used to construct a L<CGI::Cookie> object.
  92
  93     $c->response->cookies->{foo} = { value => '123' };
  94
  95 The keys of the hash reference on the right correspond to the L<CGI::Cookie>
  96 parameters of the same name, except they are used without a leading dash.
  97 Possible parameters are:
  98
  99 =over
 100
 101 =item value
 102
 103 =item expires
 104
 105 =item domain
 106
 107 =item path
 108
 109 =item secure
 110
 111 =back
 112
 113 =head2 $res->header
 114
 115 Shortcut for $res->headers->header.
 116
 117 =head2 $res->headers
 118
 119 Returns an L<HTTP::Headers> object, which can be used to set headers.
 120
 121     $c->response->headers->header( 'X-Catalyst' => $Catalyst::VERSION );
 122
 123 =head2 $res->output
 124
 125 Alias for $res->body.
 126
 127 =head2 $res->redirect( $url, $status )
 128
 129 Causes the response to redirect to the specified URL. The default status is
 130 C<302>.
 131
 132     $c->response->redirect( 'http://slashdot.org' );
 133     $c->response->redirect( 'http://slashdot.org', 307 );
 134
 135 This is a convenience method that sets the Location header to the
 136 redirect destination, and then sets the response status.  You will
 137 want to C< return; > or C< $c->detach() > to interrupt the normal
 138 processing flow if you want the redirect to occur straight away.
 139
 140 =cut
 141
 142 sub redirect {
 143     my $self = shift;
 144
 145     if (@_) {
 146         my $location = shift;
 147         my $status   = shift || 302;
 148
 149         $self->location($location);
 150         $self->status($status);
 151     }
 152
 153     return $self->location;
 154 }
 155
 156 =head2 $res->location
 157
 158 Sets or returns the HTTP 'Location'.
 159
 160 =head2 $res->status
 161
 162 Sets or returns the HTTP status.
 163
 164     $c->response->status(404);
 165
 166 =head2 $res->write( $data )
 167
 168 Writes $data to the output stream.
 169
 170 =head2 meta
 171
 172 Provided by Moose
 173
 174 =head2 $res->print( @data )
 175
 176 Prints @data to the output stream, separated by $,.  This lets you pass
 177 the response object to functions that want to write to an L<IO::Handle>.
 178
 179 =cut
 180
 181 sub print {
 182     my $self = shift;
 183     my $data = shift;
 184
 185     defined $self->write($data) or return;
 186
 187     for (@_) {
 188         defined $self->write($,) or return;
 189         defined $self->write($_) or return;
 190     }
 191
 192     return 1;
 193 }
 194
 195 =head1 AUTHORS
 196
 197 Catalyst Contributors, see Catalyst.pm
 198
 199 =head1 COPYRIGHT
 200
 201 This program is free software, you can redistribute it and/or modify
 202 it under the same terms as Perl itself.
 203
 204 =cut
 205
 206 __PACKAGE__->meta->make_immutable;
 207
 208 1;