lib/Catalyst/Request.pm

   1 package Catalyst::Request;
   2
   3 use IO::Socket qw[AF_INET inet_aton];
   4 use Carp;
   5 use utf8;
   6 use URI::http;
   7 use URI::https;
   8 use URI::QueryParam;
   9 use HTTP::Headers;
  10 use Stream::Buffered;
  11 use Hash::MultiValue;
  12 use Scalar::Util;
  13 use HTTP::Body;
  14 use Moose;
  15
  16 use namespace::clean -except => 'meta';
  17
  18 with 'MooseX::Emulate::Class::Accessor::Fast';
  19
  20 has env => (is => 'ro', writer => '_set_env', predicate => '_has_env');
  21 # XXX Deprecated crap here - warn?
  22 has action => (is => 'rw');
  23 # XXX: Deprecated in docs ages ago (2006), deprecated with warning in 5.8000 due
  24 # to confusion between Engines and Plugin::Authentication. Remove in 5.8100?
  25 has user => (is => 'rw');
  26 sub snippets        { shift->captures(@_) }
  27
  28 has _read_position => (
  29     # FIXME: work around Moose bug RT#75367
  30     # init_arg => undef,
  31     is => 'ro',
  32     writer => '_set_read_position',
  33     default => 0,
  34 );
  35 has _read_length => (
  36     # FIXME: work around Moose bug RT#75367
  37     # init_arg => undef,
  38     is => 'ro',
  39     default => sub {
  40         my $self = shift;
  41         $self->header('Content-Length') || 0;
  42     },
  43     lazy => 1,
  44 );
  45
  46 has address => (is => 'rw');
  47 has arguments => (is => 'rw', default => sub { [] });
  48 has cookies => (is => 'ro', builder => 'prepare_cookies', lazy => 1);
  49
  50 sub prepare_cookies {
  51     my ( $self ) = @_;
  52
  53     if ( my $header = $self->header('Cookie') ) {
  54         return { CGI::Simple::Cookie->parse($header) };
  55     }
  56     {};
  57 }
  58
  59 has query_keywords => (is => 'rw');
  60 has match => (is => 'rw');
  61 has method => (is => 'rw');
  62 has protocol => (is => 'rw');
  63 has query_parameters  => (is => 'rw', lazy=>1, default => sub { shift->_use_hash_multivalue ? Hash::MultiValue->new : +{} });
  64 has secure => (is => 'rw', default => 0);
  65 has captures => (is => 'rw', default => sub { [] });
  66 has uri => (is => 'rw', predicate => 'has_uri');
  67 has remote_user => (is => 'rw');
  68 has headers => (
  69   is      => 'rw',
  70   isa     => 'HTTP::Headers',
  71   handles => [qw(content_encoding content_length content_type header referer user_agent)],
  72   builder => 'prepare_headers',
  73   lazy => 1,
  74 );
  75
  76 sub prepare_headers {
  77     my ($self) = @_;
  78
  79     my $env = $self->env;
  80     my $headers = HTTP::Headers->new();
  81
  82     for my $header (keys %{ $env }) {
  83         next unless $header =~ /^(HTTP|CONTENT|COOKIE)/i;
  84         (my $field = $header) =~ s/^HTTPS?_//;
  85         $field =~ tr/_/-/;
  86         $headers->header($field => $env->{$header});
  87     }
  88     return $headers;
  89 }
  90
  91 has _log => (
  92     is => 'ro',
  93     weak_ref => 1,
  94     required => 1,
  95 );
  96
  97 has io_fh => (
  98     is=>'ro',
  99     predicate=>'_has_io_fh',
 100     lazy=>1,
 101     builder=>'_build_io_fh');
 102
 103 sub _build_io_fh {
 104     my $self = shift;
 105     return $self->env->{'psgix.io'}
 106       || (
 107         $self->env->{'net.async.http.server.req'} &&
 108         $self->env->{'net.async.http.server.req'}->stream)   ## Until I can make ioasync cabal see the value of supportin psgix.io (jnap)
 109       || die "Your Server does not support psgix.io";
 110 };
 111
 112 has data_handlers => ( is=>'ro', isa=>'HashRef', default=>sub { +{} } );
 113
 114 has body_data => (
 115     is=>'ro',
 116     lazy=>1,
 117     builder=>'_build_body_data');
 118
 119 sub _build_body_data {
 120     my ($self) = @_;
 121     my $content_type = $self->content_type;
 122     my ($match) = grep { $content_type =~/$_/i }
 123       keys(%{$self->data_handlers});
 124
 125     if($match) {
 126       my $fh = $self->body;
 127       local $_ = $fh;
 128       return $self->data_handlers->{$match}->($fh, $self);
 129     } else {
 130       return undef;
 131     }
 132 }
 133
 134 has _use_hash_multivalue => (
 135     is=>'ro',
 136     required=>1,
 137     default=> sub {0});
 138
 139 # Amount of data to read from input on each pass
 140 our $CHUNKSIZE = 64 * 1024;
 141
 142 sub read {
 143     my ($self, $maxlength) = @_;
 144     my $remaining = $self->_read_length - $self->_read_position;
 145     $maxlength ||= $CHUNKSIZE;
 146
 147     # Are we done reading?
 148     if ( $remaining <= 0 ) {
 149         return;
 150     }
 151
 152     my $readlen = ( $remaining > $maxlength ) ? $maxlength : $remaining;
 153     my $rc = $self->read_chunk( my $buffer, $readlen );
 154     if ( defined $rc ) {
 155         if (0 == $rc) { # Nothing more to read even though Content-Length
 156                         # said there should be.
 157             return;
 158         }
 159         $self->_set_read_position( $self->_read_position + $rc );
 160         return $buffer;
 161     }
 162     else {
 163         Catalyst::Exception->throw(
 164             message => "Unknown error reading input: $!" );
 165     }
 166 }
 167
 168 sub read_chunk {
 169     my $self = shift;
 170     return $self->env->{'psgi.input'}->read(@_);
 171 }
 172
 173 has body_parameters => (
 174   is => 'rw',
 175   required => 1,
 176   lazy => 1,
 177   builder => 'prepare_body_parameters',
 178 );
 179
 180 has uploads => (
 181   is => 'rw',
 182   required => 1,
 183   default => sub { {} },
 184 );
 185
 186 has parameters => (
 187     is => 'rw',
 188     lazy => 1,
 189     builder => '_build_parameters',
 190     clearer => '_clear_parameters',
 191 );
 192
 193 # TODO:
 194 # - Can we lose the before modifiers which just call prepare_body ?
 195 #   they are wasteful, slow us down and feel cluttery.
 196
 197 #  Can we make _body an attribute, have the rest of
 198 #  these lazy build from there and kill all the direct hash access
 199 #  in Catalyst.pm and Engine.pm?
 200
 201 sub prepare_parameters {
 202     my ( $self ) = @_;
 203     $self->_clear_parameters;
 204     return $self->parameters;
 205 }
 206
 207 sub _build_parameters {
 208     my ( $self ) = @_;
 209     my $parameters = {};
 210     my $body_parameters = $self->body_parameters;
 211     my $query_parameters = $self->query_parameters;
 212
 213     if($self->_use_hash_multivalue) {
 214         return Hash::MultiValue->new($query_parameters->flatten, $body_parameters->flatten);
 215     }
 216
 217     # We copy, no references
 218     foreach my $name (keys %$query_parameters) {
 219         my $param = $query_parameters->{$name};
 220         $parameters->{$name} = ref $param eq 'ARRAY' ? [ @$param ] : $param;
 221     }
 222
 223     # Merge query and body parameters
 224     foreach my $name (keys %$body_parameters) {
 225         my $param = $body_parameters->{$name};
 226         my @values = ref $param eq 'ARRAY' ? @$param : ($param);
 227         if ( my $existing = $parameters->{$name} ) {
 228           unshift(@values, (ref $existing eq 'ARRAY' ? @$existing : $existing));
 229         }
 230         $parameters->{$name} = @values > 1 ? \@values : $values[0];
 231     }
 232     $parameters;
 233 }
 234
 235 has _uploadtmp => (
 236     is => 'ro',
 237     predicate => '_has_uploadtmp',
 238 );
 239
 240 sub prepare_body {
 241     my ( $self ) = @_;
 242
 243     # If previously applied middleware created the HTTP::Body object, then we
 244     # just use that one.
 245
 246     if(my $plack_body = $self->_has_env ? $self->env->{'plack.request.http.body'} : undef) {
 247         $self->_body($plack_body);
 248         $self->_body->cleanup(1);
 249         return;
 250     }
 251
 252     # If there is nothing to read, set body to naught and return.  This
 253     # will cause all body code to be skipped
 254
 255     return $self->_body(0) unless my $length = $self->_read_length;
 256
 257     # Unless the body has already been set, create it.  Not sure about this
 258     # code, how else might it be set, but this was existing logic.
 259
 260     unless ($self->_body) {
 261         my $type = $self->header('Content-Type');
 262         $self->_body(HTTP::Body->new( $type, $length ));
 263         $self->_body->cleanup(1);
 264
 265         # JNAP: I'm not sure this is doing what we expect, but it also doesn't
 266         # seem to be hurting (seems ->_has_uploadtmp is true more than I would
 267         # expect.
 268
 269         $self->_body->tmpdir( $self->_uploadtmp )
 270           if $self->_has_uploadtmp;
 271     }
 272
 273     # Ok if we get this far, we have to read psgi.input into the new body
 274     # object.  Lets play nice with any plack app or other downstream, so
 275     # we create a buffer unless one exists.
 276
 277     my $stream_buffer;
 278     if ($self->env->{'psgix.input.buffered'}) {
 279         # Be paranoid about previous psgi middleware or apps that read the
 280         # input but didn't return the buffer to the start.
 281         $self->env->{'psgi.input'}->seek(0, 0);
 282     } else {
 283         $stream_buffer = Stream::Buffered->new($length);
 284     }
 285
 286     # Check for definedness as you could read '0'
 287     while ( defined ( my $chunk = $self->read() ) ) {
 288         $self->prepare_body_chunk($chunk);
 289         $stream_buffer->print($chunk) if $stream_buffer;
 290     }
 291
 292     # Ok, we read the body.  Lets play nice for any PSGI app down the pipe
 293
 294     if ($stream_buffer) {
 295         $self->env->{'psgix.input.buffered'} = 1;
 296         $self->env->{'psgi.input'} = $stream_buffer->rewind;
 297     } else {
 298         $self->env->{'psgi.input'}->seek(0, 0); # Reset the buffer for downstream middleware or apps
 299     }
 300
 301     # paranoia against wrong Content-Length header
 302     my $remaining = $length - $self->_read_position;
 303     if ( $remaining > 0 ) {
 304         Catalyst::Exception->throw("Wrong Content-Length value: $length" );
 305     }
 306 }
 307
 308 sub prepare_body_chunk {
 309     my ( $self, $chunk ) = @_;
 310
 311     $self->_body->add($chunk);
 312 }
 313
 314 sub prepare_body_parameters {
 315     my ( $self, $c ) = @_;
 316
 317     $self->prepare_body if ! $self->_has_body;
 318
 319     unless($self->_body) {
 320       return $self->_use_hash_multivalue ? Hash::MultiValue->new : {};
 321     }
 322
 323     my $params = $self->_body->param;
 324
 325     # If we have an encoding configured (like UTF-8) in general we expect a client
 326     # to POST with the encoding we fufilled the request in. Otherwise don't do any
 327     # encoding (good change wide chars could be in HTML entity style llike the old
 328     # days -JNAP
 329
 330     # so, now that HTTP::Body prepared the body params, we gotta 'walk' the structure
 331     # and do any needed decoding.
 332
 333     # This only does something if the encoding is set via the encoding param.  Remember
 334     # this is assuming the client is not bad and responds with what you provided.  In
 335     # general you can just use utf8 and get away with it.
 336     #
 337     # I need to see if $c is here since this also doubles as a builder for the object :(
 338
 339     if($c and $c->encoding) {
 340         $params = $c->_handle_unicode_decoding($params);
 341     }
 342
 343     return $self->_use_hash_multivalue ?
 344         Hash::MultiValue->from_mixed($params) :
 345         $params;
 346 }
 347
 348 sub prepare_connection {
 349     my ($self) = @_;
 350
 351     my $env = $self->env;
 352
 353     $self->address( $env->{REMOTE_ADDR} );
 354     $self->hostname( $env->{REMOTE_HOST} )
 355         if exists $env->{REMOTE_HOST};
 356     $self->protocol( $env->{SERVER_PROTOCOL} );
 357     $self->remote_user( $env->{REMOTE_USER} );
 358     $self->method( $env->{REQUEST_METHOD} );
 359     $self->secure( $env->{'psgi.url_scheme'} eq 'https' ? 1 : 0 );
 360 }
 361
 362 # XXX - FIXME - method is here now, move this crap...
 363 around parameters => sub {
 364     my ($orig, $self, $params) = @_;
 365     if ($params) {
 366         if ( !ref $params ) {
 367             $self->_log->warn(
 368                 "Attempt to retrieve '$params' with req->params(), " .
 369                 "you probably meant to call req->param('$params')"
 370             );
 371             $params = undef;
 372         }
 373         return $self->$orig($params);
 374     }
 375     $self->$orig();
 376 };
 377
 378 has base => (
 379   is => 'rw',
 380   required => 1,
 381   lazy => 1,
 382   default => sub {
 383     my $self = shift;
 384     return $self->path if $self->has_uri;
 385   },
 386 );
 387
 388 has _body => (
 389   is => 'rw', clearer => '_clear_body', predicate => '_has_body',
 390 );
 391 # Eugh, ugly. Should just be able to rename accessor methods to 'body'
 392 #             and provide a custom reader..
 393 sub body {
 394   my $self = shift;
 395   $self->prepare_body unless $self->_has_body;
 396   croak 'body is a reader' if scalar @_;
 397   return blessed $self->_body ? $self->_body->body : $self->_body;
 398 }
 399
 400 has hostname => (
 401   is        => 'rw',
 402   required  => 1,
 403   lazy      => 1,
 404   default   => sub {
 405     my ($self) = @_;
 406     gethostbyaddr( inet_aton( $self->address ), AF_INET ) || $self->address
 407   },
 408 );
 409
 410 has _path => ( is => 'rw', predicate => '_has_path', clearer => '_clear_path' );
 411
 412 sub args            { shift->arguments(@_) }
 413 sub body_params     { shift->body_parameters(@_) }
 414 sub input           { shift->body(@_) }
 415 sub params          { shift->parameters(@_) }
 416 sub query_params    { shift->query_parameters(@_) }
 417 sub path_info       { shift->path(@_) }
 418
 419 =for stopwords param params
 420
 421 =head1 NAME
 422
 423 Catalyst::Request - provides information about the current client request
 424
 425 =head1 SYNOPSIS
 426
 427     $req = $c->request;
 428     $req->address eq "127.0.0.1";
 429     $req->arguments;
 430     $req->args;
 431     $req->base;
 432     $req->body;
 433     $req->body_data;
 434     $req->body_parameters;
 435     $req->content_encoding;
 436     $req->content_length;
 437     $req->content_type;
 438     $req->cookie;
 439     $req->cookies;
 440     $req->header;
 441     $req->headers;
 442     $req->hostname;
 443     $req->input;
 444     $req->query_keywords;
 445     $req->match;
 446     $req->method;
 447     $req->param;
 448     $req->parameters;
 449     $req->params;
 450     $req->path;
 451     $req->protocol;
 452     $req->query_parameters;
 453     $req->read;
 454     $req->referer;
 455     $req->secure;
 456     $req->captures;
 457     $req->upload;
 458     $req->uploads;
 459     $req->uri;
 460     $req->user;
 461     $req->user_agent;
 462     $req->env;
 463
 464 See also L<Catalyst>, L<Catalyst::Request::Upload>.
 465
 466 =head1 DESCRIPTION
 467
 468 This is the Catalyst Request class, which provides an interface to data for the
 469 current client request. The request object is prepared by L<Catalyst::Engine>,
 470 thus hiding the details of the particular engine implementation.
 471
 472 =head1 METHODS
 473
 474 =head2 $req->address
 475
 476 Returns the IP address of the client.
 477
 478 =head2 $req->arguments
 479
 480 Returns a reference to an array containing the arguments.
 481
 482     print $c->request->arguments->[0];
 483
 484 For example, if your action was
 485
 486     package MyApp::Controller::Foo;
 487
 488     sub moose : Local {
 489         ...
 490     }
 491
 492 and the URI for the request was C<http://.../foo/moose/bah>, the string C<bah>
 493 would be the first and only argument.
 494
 495 Arguments get automatically URI-unescaped for you.
 496
 497 =head2 $req->args
 498
 499 Shortcut for L</arguments>.
 500
 501 =head2 $req->base
 502
 503 Contains the URI base. This will always have a trailing slash. Note that the
 504 URI scheme (e.g., http vs. https) must be determined through heuristics;
 505 depending on your server configuration, it may be incorrect. See $req->secure
 506 for more info.
 507
 508 If your application was queried with the URI
 509 C<http://localhost:3000/some/path> then C<base> is C<http://localhost:3000/>.
 510
 511 =head2 $req->body
 512
 513 Returns the message body of the request, as returned by L<HTTP::Body>: a string,
 514 unless Content-Type is C<application/x-www-form-urlencoded>, C<text/xml>, or
 515 C<multipart/form-data>, in which case a L<File::Temp> object is returned.
 516
 517 =head2 $req->body_data
 518
 519 Returns a Perl representation of POST/PUT body data that is not classic HTML
 520 form data, such as JSON, XML, etc.  By default, Catalyst will parse incoming
 521 data of the type 'application/json' and return access to that data via this
 522 method.  You may define addition data_handlers via a global configuration
 523 setting.  See L<Catalyst\DATA HANDLERS> for more information.
 524
 525 =head2 $req->body_parameters
 526
 527 Returns a reference to a hash containing body (POST) parameters. Values can
 528 be either a scalar or an arrayref containing scalars.
 529
 530     print $c->request->body_parameters->{field};
 531     print $c->request->body_parameters->{field}->[0];
 532
 533 These are the parameters from the POST part of the request, if any.
 534
 535 =head2 $req->body_params
 536
 537 Shortcut for body_parameters.
 538
 539 =head2 $req->content_encoding
 540
 541 Shortcut for $req->headers->content_encoding.
 542
 543 =head2 $req->content_length
 544
 545 Shortcut for $req->headers->content_length.
 546
 547 =head2 $req->content_type
 548
 549 Shortcut for $req->headers->content_type.
 550
 551 =head2 $req->cookie
 552
 553 A convenient method to access $req->cookies.
 554
 555     $cookie  = $c->request->cookie('name');
 556     @cookies = $c->request->cookie;
 557
 558 =cut
 559
 560 sub cookie {
 561     my $self = shift;
 562
 563     if ( @_ == 0 ) {
 564         return keys %{ $self->cookies };
 565     }
 566
 567     if ( @_ == 1 ) {
 568
 569         my $name = shift;
 570
 571         unless ( exists $self->cookies->{$name} ) {
 572             return undef;
 573         }
 574
 575         return $self->cookies->{$name};
 576     }
 577 }
 578
 579 =head2 $req->cookies
 580
 581 Returns a reference to a hash containing the cookies.
 582
 583     print $c->request->cookies->{mycookie}->value;
 584
 585 The cookies in the hash are indexed by name, and the values are L<CGI::Simple::Cookie>
 586 objects.
 587
 588 =head2 $req->header
 589
 590 Shortcut for $req->headers->header.
 591
 592 =head2 $req->headers
 593
 594 Returns an L<HTTP::Headers> object containing the headers for the current request.
 595
 596     print $c->request->headers->header('X-Catalyst');
 597
 598 =head2 $req->hostname
 599
 600 Returns the hostname of the client. Use C<< $req->uri->host >> to get the hostname of the server.
 601
 602 =head2 $req->input
 603
 604 Alias for $req->body.
 605
 606 =head2 $req->query_keywords
 607
 608 Contains the keywords portion of a query string, when no '=' signs are
 609 present.
 610
 611     http://localhost/path?some+keywords
 612
 613     $c->request->query_keywords will contain 'some keywords'
 614
 615 =head2 $req->match
 616
 617 This contains the matching part of a Regex action. Otherwise
 618 it returns the same as 'action', except for default actions,
 619 which return an empty string.
 620
 621 =head2 $req->method
 622
 623 Contains the request method (C<GET>, C<POST>, C<HEAD>, etc).
 624
 625 =head2 $req->param
 626
 627 Returns GET and POST parameters with a CGI.pm-compatible param method. This
 628 is an alternative method for accessing parameters in $c->req->parameters.
 629
 630     $value  = $c->request->param( 'foo' );
 631     @values = $c->request->param( 'foo' );
 632     @params = $c->request->param;
 633
 634 Like L<CGI>, and B<unlike> earlier versions of Catalyst, passing multiple
 635 arguments to this method, like this:
 636
 637     $c->request->param( 'foo', 'bar', 'gorch', 'quxx' );
 638
 639 will set the parameter C<foo> to the multiple values C<bar>, C<gorch> and
 640 C<quxx>. Previously this would have added C<bar> as another value to C<foo>
 641 (creating it if it didn't exist before), and C<quxx> as another value for
 642 C<gorch>.
 643
 644 B<NOTE> this is considered a legacy interface and care should be taken when
 645 using it. C<< scalar $c->req->param( 'foo' ) >> will return only the first
 646 C<foo> param even if multiple are present; C<< $c->req->param( 'foo' ) >> will
 647 return a list of as many are present, which can have unexpected consequences
 648 when writing code of the form:
 649
 650     $foo->bar(
 651         a => 'b',
 652         baz => $c->req->param( 'baz' ),
 653     );
 654
 655 If multiple C<baz> parameters are provided this code might corrupt data or
 656 cause a hash initialization error. For a more straightforward interface see
 657 C<< $c->req->parameters >>.
 658
 659 =cut
 660
 661 sub param {
 662     my $self = shift;
 663
 664     if ( @_ == 0 ) {
 665         return keys %{ $self->parameters };
 666     }
 667
 668     # If anything in @_ is undef, carp about that, and remove it from
 669     # the list;
 670
 671     my @params = grep { defined($_) ? 1 : do {carp "You called ->params with an undefined value"; 0} } @_;
 672
 673     if ( @params == 1 ) {
 674
 675         defined(my $param = shift @params) ||
 676           carp "You called ->params with an undefined value 2";
 677
 678         unless ( exists $self->parameters->{$param} ) {
 679             return wantarray ? () : undef;
 680         }
 681
 682         if ( ref $self->parameters->{$param} eq 'ARRAY' ) {
 683             return (wantarray)
 684               ? @{ $self->parameters->{$param} }
 685               : $self->parameters->{$param}->[0];
 686         }
 687         else {
 688             return (wantarray)
 689               ? ( $self->parameters->{$param} )
 690               : $self->parameters->{$param};
 691         }
 692     }
 693     elsif ( @params > 1 ) {
 694         my $field = shift @params;
 695         $self->parameters->{$field} = [@params];
 696     }
 697 }
 698
 699 =head2 $req->parameters
 700
 701 Returns a reference to a hash containing GET and POST parameters. Values can
 702 be either a scalar or an arrayref containing scalars.
 703
 704     print $c->request->parameters->{field};
 705     print $c->request->parameters->{field}->[0];
 706
 707 This is the combination of C<query_parameters> and C<body_parameters>.
 708
 709 =head2 $req->params
 710
 711 Shortcut for $req->parameters.
 712
 713 =head2 $req->path
 714
 715 Returns the path, i.e. the part of the URI after $req->base, for the current request.
 716
 717     http://localhost/path/foo
 718
 719     $c->request->path will contain 'path/foo'
 720
 721 =head2 $req->path_info
 722
 723 Alias for path, added for compatibility with L<CGI>.
 724
 725 =cut
 726
 727 sub path {
 728     my ( $self, @params ) = @_;
 729
 730     if (@params) {
 731         $self->uri->path(@params);
 732         $self->_clear_path;
 733     }
 734     elsif ( $self->_has_path ) {
 735         return $self->_path;
 736     }
 737     else {
 738         my $path     = $self->uri->path;
 739         my $location = $self->base->path;
 740         $path =~ s/^(\Q$location\E)?//;
 741         $path =~ s/^\///;
 742         $self->_path($path);
 743
 744         return $path;
 745     }
 746 }
 747
 748 =head2 $req->protocol
 749
 750 Returns the protocol (HTTP/1.0 or HTTP/1.1) used for the current request.
 751
 752 =head2 $req->query_parameters
 753
 754 =head2 $req->query_params
 755
 756 Returns a reference to a hash containing query string (GET) parameters. Values can
 757 be either a scalar or an arrayref containing scalars.
 758
 759     print $c->request->query_parameters->{field};
 760     print $c->request->query_parameters->{field}->[0];
 761
 762 =head2 $req->read( [$maxlength] )
 763
 764 Reads a chunk of data from the request body. This method is intended to be
 765 used in a while loop, reading $maxlength bytes on every call. $maxlength
 766 defaults to the size of the request if not specified.
 767
 768 =head2 $req->read_chunk(\$buff, $max)
 769
 770 Reads a chunk.
 771
 772 You have to set MyApp->config(parse_on_demand => 1) to use this directly.
 773
 774 =head2 $req->referer
 775
 776 Shortcut for $req->headers->referer. Returns the referring page.
 777
 778 =head2 $req->secure
 779
 780 Returns true or false, indicating whether the connection is secure
 781 (https). The reliability of $req->secure may depend on your server
 782 configuration; Catalyst relies on PSGI to determine whether or not a
 783 request is secure (Catalyst looks at psgi.url_scheme), and different
 784 PSGI servers may make this determination in different ways (as by
 785 directly passing along information from the server, interpreting any of
 786 several HTTP headers, or using heuristics of their own).
 787
 788 =head2 $req->captures
 789
 790 Returns a reference to an array containing captured args from chained
 791 actions or regex captures.
 792
 793     my @captures = @{ $c->request->captures };
 794
 795 =head2 $req->upload
 796
 797 A convenient method to access $req->uploads.
 798
 799     $upload  = $c->request->upload('field');
 800     @uploads = $c->request->upload('field');
 801     @fields  = $c->request->upload;
 802
 803     for my $upload ( $c->request->upload('field') ) {
 804         print $upload->filename;
 805     }
 806
 807 =cut
 808
 809 sub upload {
 810     my $self = shift;
 811
 812     if ( @_ == 0 ) {
 813         return keys %{ $self->uploads };
 814     }
 815
 816     if ( @_ == 1 ) {
 817
 818         my $upload = shift;
 819
 820         unless ( exists $self->uploads->{$upload} ) {
 821             return wantarray ? () : undef;
 822         }
 823
 824         if ( ref $self->uploads->{$upload} eq 'ARRAY' ) {
 825             return (wantarray)
 826               ? @{ $self->uploads->{$upload} }
 827               : $self->uploads->{$upload}->[0];
 828         }
 829         else {
 830             return (wantarray)
 831               ? ( $self->uploads->{$upload} )
 832               : $self->uploads->{$upload};
 833         }
 834     }
 835
 836     if ( @_ > 1 ) {
 837
 838         while ( my ( $field, $upload ) = splice( @_, 0, 2 ) ) {
 839
 840             if ( exists $self->uploads->{$field} ) {
 841                 for ( $self->uploads->{$field} ) {
 842                     $_ = [$_] unless ref($_) eq "ARRAY";
 843                     push( @$_, $upload );
 844                 }
 845             }
 846             else {
 847                 $self->uploads->{$field} = $upload;
 848             }
 849         }
 850     }
 851 }
 852
 853 =head2 $req->uploads
 854
 855 Returns a reference to a hash containing uploads. Values can be either a
 856 L<Catalyst::Request::Upload> object, or an arrayref of
 857 L<Catalyst::Request::Upload> objects.
 858
 859     my $upload = $c->request->uploads->{field};
 860     my $upload = $c->request->uploads->{field}->[0];
 861
 862 =head2 $req->uri
 863
 864 Returns a L<URI> object for the current request. Stringifies to the URI text.
 865
 866 =head2 $req->mangle_params( { key => 'value' }, $appendmode);
 867
 868 Returns a hashref of parameters stemming from the current request's params,
 869 plus the ones supplied.  Keys for which no current param exists will be
 870 added, keys with undefined values will be removed and keys with existing
 871 params will be replaced.  Note that you can supply a true value as the final
 872 argument to change behavior with regards to existing parameters, appending
 873 values rather than replacing them.
 874
 875 A quick example:
 876
 877   # URI query params foo=1
 878   my $hashref = $req->mangle_params({ foo => 2 });
 879   # Result is query params of foo=2
 880
 881 versus append mode:
 882
 883   # URI query params foo=1
 884   my $hashref = $req->mangle_params({ foo => 2 }, 1);
 885   # Result is query params of foo=1&foo=2
 886
 887 This is the code behind C<uri_with>.
 888
 889 =cut
 890
 891 sub mangle_params {
 892     my ($self, $args, $append) = @_;
 893
 894     carp('No arguments passed to mangle_params()') unless $args;
 895
 896     foreach my $value ( values %$args ) {
 897         next unless defined $value;
 898         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 899             $_ = "$_";
 900             #      utf8::encode($_);
 901         }
 902     };
 903
 904     my %params = %{ $self->uri->query_form_hash };
 905     foreach my $key (keys %{ $args }) {
 906         my $val = $args->{$key};
 907         if(defined($val)) {
 908
 909             if($append && exists($params{$key})) {
 910
 911                 # This little bit of heaven handles appending a new value onto
 912                 # an existing one regardless if the existing value is an array
 913                 # or not, and regardless if the new value is an array or not
 914                 $params{$key} = [
 915                     ref($params{$key}) eq 'ARRAY' ? @{ $params{$key} } : $params{$key},
 916                     ref($val) eq 'ARRAY' ? @{ $val } : $val
 917                 ];
 918
 919             } else {
 920                 $params{$key} = $val;
 921             }
 922         } else {
 923
 924             # If the param wasn't defined then we delete it.
 925             delete($params{$key});
 926         }
 927     }
 928
 929
 930     return \%params;
 931 }
 932
 933 =head2 $req->uri_with( { key => 'value' } );
 934
 935 Returns a rewritten URI object for the current request. Key/value pairs
 936 passed in will override existing parameters. You can remove an existing
 937 parameter by passing in an undef value. Unmodified pairs will be
 938 preserved.
 939
 940 You may also pass an optional second parameter that puts C<uri_with> into
 941 append mode:
 942
 943   $req->uri_with( { key => 'value' }, { mode => 'append' } );
 944
 945 See C<mangle_params> for an explanation of this behavior.
 946
 947 =cut
 948
 949 sub uri_with {
 950     my( $self, $args, $behavior) = @_;
 951
 952     carp( 'No arguments passed to uri_with()' ) unless $args;
 953
 954     my $append = 0;
 955     if((ref($behavior) eq 'HASH') && defined($behavior->{mode}) && ($behavior->{mode} eq 'append')) {
 956         $append = 1;
 957     }
 958
 959     my $params = $self->mangle_params($args, $append);
 960
 961     my $uri = $self->uri->clone;
 962     $uri->query_form($params);
 963
 964     return $uri;
 965 }
 966
 967 =head2 $req->remote_user
 968
 969 Returns the value of the C<REMOTE_USER> environment variable.
 970
 971 =head2 $req->user_agent
 972
 973 Shortcut to $req->headers->user_agent. Returns the user agent (browser)
 974 version string.
 975
 976 =head2 $req->io_fh
 977
 978 Returns a psgix.io bidirectional socket, if your server supports one.  Used for
 979 when you want to jailbreak out of PSGI and handle bidirectional client server
 980 communication manually, such as when you are using cometd or websockets.
 981
 982 =head1 SETUP METHODS
 983
 984 You should never need to call these yourself in application code,
 985 however they are useful if extending Catalyst by applying a request role.
 986
 987 =head2 $self->prepare_headers()
 988
 989 Sets up the C<< $res->headers >> accessor.
 990
 991 =head2 $self->prepare_body()
 992
 993 Sets up the body using L<HTTP::Body>
 994
 995 =head2 $self->prepare_body_chunk()
 996
 997 Add a chunk to the request body.
 998
 999 =head2 $self->prepare_body_parameters()
1000
1001 Sets up parameters from body.
1002
1003 =head2 $self->prepare_cookies()
1004
1005 Parse cookies from header. Sets up a L<CGI::Simple::Cookie> object.
1006
1007 =head2 $self->prepare_connection()
1008
1009 Sets up various fields in the request like the local and remote addresses,
1010 request method, hostname requested etc.
1011
1012 =head2 $self->prepare_parameters()
1013
1014 Ensures that the body has been parsed, then builds the parameters, which are
1015 combined from those in the request and those in the body.
1016
1017 If parameters have already been set will clear the parameters and build them again.
1018
1019 =head2 $self->env
1020
1021 Access to the raw PSGI env.
1022
1023 =head2 meta
1024
1025 Provided by Moose
1026
1027 =head1 AUTHORS
1028
1029 Catalyst Contributors, see Catalyst.pm
1030
1031 =head1 COPYRIGHT
1032
1033 This library is free software. You can redistribute it and/or modify
1034 it under the same terms as Perl itself.
1035
1036 =cut
1037
1038 __PACKAGE__->meta->make_immutable;
1039
1040 1;