lib/Catalyst/Request.pm

   1 package Catalyst::Request;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5
   6 use IO::Socket qw[AF_INET inet_aton];
   7 use Carp;
   8 use utf8;
   9 use URI::QueryParam;
  10
  11 __PACKAGE__->mk_accessors(
  12     qw/action address arguments cookies headers match method
  13       protocol query_parameters secure captures uri user/
  14 );
  15
  16 *args         = \&arguments;
  17 *body_params  = \&body_parameters;
  18 *input        = \&body;
  19 *params       = \&parameters;
  20 *query_params = \&query_parameters;
  21 *path_info    = \&path;
  22 *snippets     = \&captures;
  23
  24 sub content_encoding { shift->headers->content_encoding(@_) }
  25 sub content_length   { shift->headers->content_length(@_) }
  26 sub content_type     { shift->headers->content_type(@_) }
  27 sub header           { shift->headers->header(@_) }
  28 sub referer          { shift->headers->referer(@_) }
  29 sub user_agent       { shift->headers->user_agent(@_) }
  30
  31 =head1 NAME
  32
  33 Catalyst::Request - provides information about the current client request
  34
  35 =head1 SYNOPSIS
  36
  37     $req = $c->request;
  38     $req->action;
  39     $req->address;
  40     $req->arguments;
  41     $req->args;
  42     $req->base;
  43     $req->body;
  44     $req->body_parameters;
  45     $req->content_encoding;
  46     $req->content_length;
  47     $req->content_type;
  48     $req->cookie;
  49     $req->cookies;
  50     $req->header;
  51     $req->headers;
  52     $req->hostname;
  53     $req->input;
  54     $req->match;
  55     $req->method;
  56     $req->param;
  57     $req->parameters;
  58     $req->params;
  59     $req->path;
  60     $req->protocol;
  61     $req->query_parameters;
  62     $req->read;
  63     $req->referer;
  64     $req->secure;
  65     $req->captures; # previously knows as snippets
  66     $req->upload;
  67     $req->uploads;
  68     $req->uri;
  69     $req->user;
  70     $req->user_agent;
  71
  72 See also L<Catalyst>, L<Catalyst::Request::Upload>.
  73
  74 =head1 DESCRIPTION
  75
  76 This is the Catalyst Request class, which provides an interface to data for the
  77 current client request. The request object is prepared by L<Catalyst::Engine>,
  78 thus hiding the details of the particular engine implementation.
  79
  80 =head1 METHODS
  81
  82 =head2 $req->action
  83
  84 [DEPRECATED] Returns the name of the requested action.
  85
  86
  87 Use C<< $c->action >> instead (which returns a
  88 L<Catalyst::Action|Catalyst::Action> object).
  89
  90 =head2 $req->address
  91
  92 Returns the IP address of the client.
  93
  94 =head2 $req->arguments
  95
  96 Returns a reference to an array containing the arguments.
  97
  98     print $c->request->arguments->[0];
  99
 100 For example, if your action was
 101
 102         package MyApp::C::Foo;
 103
 104         sub moose : Local {
 105                 ...
 106         }
 107
 108 and the URI for the request was C<http://.../foo/moose/bah>, the string C<bah>
 109 would be the first and only argument.
 110
 111 =head2 $req->args
 112
 113 Shortcut for arguments.
 114
 115 =head2 $req->base
 116
 117 Contains the URI base. This will always have a trailing slash.
 118
 119 If your application was queried with the URI
 120 C<http://localhost:3000/some/path> then C<base> is C<http://localhost:3000/>.
 121
 122 =cut
 123
 124 sub base {
 125     my ( $self, $base ) = @_;
 126
 127     return $self->{base} unless $base;
 128
 129     $self->{base} = $base;
 130
 131     # set the value in path for backwards-compat
 132     if ( $self->uri ) {
 133         $self->path;
 134     }
 135
 136     return $self->{base};
 137 }
 138
 139 =head2 $req->body
 140
 141 Returns the message body of the request, unless Content-Type is
 142 C<application/x-www-form-urlencoded> or C<multipart/form-data>.
 143
 144 =cut
 145
 146 sub body {
 147     my ( $self, $body ) = @_;
 148     $self->{_context}->prepare_body;
 149     $self->{_body}->body($body) if $body;
 150     return $self->{_body}->body;
 151 }
 152
 153 =head2 $req->body_parameters
 154
 155 Returns a reference to a hash containing body (POST) parameters. Values can
 156 be either a scalar or an arrayref containing scalars.
 157
 158     print $c->request->body_parameters->{field};
 159     print $c->request->body_parameters->{field}->[0];
 160
 161 These are the parameters from the POST part of the request, if any.
 162
 163 =head2 $req->body_params
 164
 165 Shortcut for body_parameters.
 166
 167 =cut
 168
 169 sub body_parameters {
 170     my ( $self, $params ) = @_;
 171     $self->{_context}->prepare_body;
 172     $self->{body_parameters} = $params if $params;
 173     return $self->{body_parameters};
 174 }
 175
 176 =head2 $req->content_encoding
 177
 178 Shortcut for $req->headers->content_encoding.
 179
 180 =head2 $req->content_length
 181
 182 Shortcut for $req->headers->content_length.
 183
 184 =head2 $req->content_type
 185
 186 Shortcut for $req->headers->content_type.
 187
 188 =head2 $req->cookie
 189
 190 A convenient method to access $req->cookies.
 191
 192     $cookie  = $c->request->cookie('name');
 193     @cookies = $c->request->cookie;
 194
 195 =cut
 196
 197 sub cookie {
 198     my $self = shift;
 199
 200     if ( @_ == 0 ) {
 201         return keys %{ $self->cookies };
 202     }
 203
 204     if ( @_ == 1 ) {
 205
 206         my $name = shift;
 207
 208         unless ( exists $self->cookies->{$name} ) {
 209             return undef;
 210         }
 211
 212         return $self->cookies->{$name};
 213     }
 214 }
 215
 216 =head2 $req->cookies
 217
 218 Returns a reference to a hash containing the cookies.
 219
 220     print $c->request->cookies->{mycookie}->value;
 221
 222 The cookies in the hash are indexed by name, and the values are L<CGI::Cookie>
 223 objects.
 224
 225 =head2 $req->header
 226
 227 Shortcut for $req->headers->header.
 228
 229 =head2 $req->headers
 230
 231 Returns an L<HTTP::Headers> object containing the headers for the current request.
 232
 233     print $c->request->headers->header('X-Catalyst');
 234
 235 =head2 $req->hostname
 236
 237 Returns the hostname of the client.
 238
 239 =cut
 240
 241 sub hostname {
 242     my $self = shift;
 243
 244     if ( @_ == 0 && not $self->{hostname} ) {
 245         $self->{hostname} =
 246           gethostbyaddr( inet_aton( $self->address ), AF_INET );
 247     }
 248
 249     if ( @_ == 1 ) {
 250         $self->{hostname} = shift;
 251     }
 252
 253     return $self->{hostname};
 254 }
 255
 256 =head2 $req->input
 257
 258 Alias for $req->body.
 259
 260 =head2 $req->match
 261
 262 This contains the matching part of a Regex action. Otherwise
 263 it returns the same as 'action', except for default actions,
 264 which return an empty string.
 265
 266 =head2 $req->method
 267
 268 Contains the request method (C<GET>, C<POST>, C<HEAD>, etc).
 269
 270 =head2 $req->param
 271
 272 Returns GET and POST parameters with a CGI.pm-compatible param method. This
 273 is an alternative method for accessing parameters in $c->req->parameters.
 274
 275     $value  = $c->request->param( 'foo' );
 276     @values = $c->request->param( 'foo' );
 277     @params = $c->request->param;
 278
 279 Like L<CGI>, and B<unlike> earlier versions of Catalyst, passing multiple
 280 arguments to this method, like this:
 281
 282         $c->request->param( 'foo', 'bar', 'gorch', 'quxx' );
 283
 284 will set the parameter C<foo> to the multiple values C<bar>, C<gorch> and
 285 C<quxx>. Previously this would have added C<bar> as another value to C<foo>
 286 (creating it if it didn't exist before), and C<quxx> as another value for
 287 C<gorch>.
 288
 289 =cut
 290
 291 sub param {
 292     my $self = shift;
 293
 294     if ( @_ == 0 ) {
 295         return keys %{ $self->parameters };
 296     }
 297
 298     if ( @_ == 1 ) {
 299
 300         my $param = shift;
 301
 302         unless ( exists $self->parameters->{$param} ) {
 303             return wantarray ? () : undef;
 304         }
 305
 306         if ( ref $self->parameters->{$param} eq 'ARRAY' ) {
 307             return (wantarray)
 308               ? @{ $self->parameters->{$param} }
 309               : $self->parameters->{$param}->[0];
 310         }
 311         else {
 312             return (wantarray)
 313               ? ( $self->parameters->{$param} )
 314               : $self->parameters->{$param};
 315         }
 316     }
 317     elsif ( @_ > 1 ) {
 318         my $field = shift;
 319         $self->parameters->{$field} = [@_];
 320     }
 321 }
 322
 323 =head2 $req->parameters
 324
 325 Returns a reference to a hash containing GET and POST parameters. Values can
 326 be either a scalar or an arrayref containing scalars.
 327
 328     print $c->request->parameters->{field};
 329     print $c->request->parameters->{field}->[0];
 330
 331 This is the combination of C<query_parameters> and C<body_parameters>.
 332
 333 =head2 $req->params
 334
 335 Shortcut for $req->parameters.
 336
 337 =cut
 338
 339 sub parameters {
 340     my ( $self, $params ) = @_;
 341     $self->{_context}->prepare_body;
 342     if ( $params ) {
 343         if ( ref $params ) {
 344             $self->{parameters} = $params;
 345         }
 346         else {
 347             $self->{_context}->log->warn(
 348                 "Attempt to retrieve '$params' with req->params(), " .
 349                 "you probably meant to call req->param('$params')" );
 350         }
 351     }
 352     return $self->{parameters};
 353 }
 354
 355 =head2 $req->path
 356
 357 Returns the path, i.e. the part of the URI after $req->base, for the current request.
 358
 359 =head2 $req->path_info
 360
 361 Alias for path, added for compability with L<CGI>.
 362
 363 =cut
 364
 365 sub path {
 366     my ( $self, $params ) = @_;
 367
 368     if ($params) {
 369         $self->uri->path($params);
 370     }
 371     else {
 372         return $self->{path} if $self->{path};
 373     }
 374
 375     my $path     = $self->uri->path;
 376     my $location = $self->base->path;
 377     $path =~ s/^(\Q$location\E)?//;
 378     $path =~ s/^\///;
 379     $self->{path} = $path;
 380
 381     return $path;
 382 }
 383
 384 =head2 $req->protocol
 385
 386 Returns the protocol (HTTP/1.0 or HTTP/1.1) used for the current request.
 387
 388 =head2 $req->query_parameters
 389
 390 Returns a reference to a hash containing query string (GET) parameters. Values can
 391 be either a scalar or an arrayref containing scalars.
 392
 393     print $c->request->query_parameters->{field};
 394     print $c->request->query_parameters->{field}->[0];
 395
 396 =head2 $req->read( [$maxlength] )
 397
 398 Reads a chunk of data from the request body. This method is intended to be
 399 used in a while loop, reading $maxlength bytes on every call. $maxlength
 400 defaults to the size of the request if not specified.
 401
 402 You have to set MyApp->config->{parse_on_demand} to use this directly.
 403
 404 =cut
 405
 406 sub read { shift->{_context}->read(@_); }
 407
 408 =head2 $req->referer
 409
 410 Shortcut for $req->headers->referer. Returns the referring page.
 411
 412 =head2 $req->secure
 413
 414 Returns true or false, indicating whether the connection is secure (https).
 415
 416 =head2 $req->captures
 417
 418 Returns a reference to an array containing regex captures.
 419
 420     my @captures = @{ $c->request->captures };
 421
 422 =head2 $req->snippets
 423
 424 C<captures> used to be called snippets. This is still available for backwoards
 425 compatibility, but is considered deprecated.
 426
 427 =head2 $req->upload
 428
 429 A convenient method to access $req->uploads.
 430
 431     $upload  = $c->request->upload('field');
 432     @uploads = $c->request->upload('field');
 433     @fields  = $c->request->upload;
 434
 435     for my $upload ( $c->request->upload('field') ) {
 436         print $upload->filename;
 437     }
 438
 439 =cut
 440
 441 sub upload {
 442     my $self = shift;
 443
 444     if ( @_ == 0 ) {
 445         return keys %{ $self->uploads };
 446     }
 447
 448     if ( @_ == 1 ) {
 449
 450         my $upload = shift;
 451
 452         unless ( exists $self->uploads->{$upload} ) {
 453             return wantarray ? () : undef;
 454         }
 455
 456         if ( ref $self->uploads->{$upload} eq 'ARRAY' ) {
 457             return (wantarray)
 458               ? @{ $self->uploads->{$upload} }
 459               : $self->uploads->{$upload}->[0];
 460         }
 461         else {
 462             return (wantarray)
 463               ? ( $self->uploads->{$upload} )
 464               : $self->uploads->{$upload};
 465         }
 466     }
 467
 468     if ( @_ > 1 ) {
 469
 470         while ( my ( $field, $upload ) = splice( @_, 0, 2 ) ) {
 471
 472             if ( exists $self->uploads->{$field} ) {
 473                 for ( $self->uploads->{$field} ) {
 474                     $_ = [$_] unless ref($_) eq "ARRAY";
 475                     push( @$_, $upload );
 476                 }
 477             }
 478             else {
 479                 $self->uploads->{$field} = $upload;
 480             }
 481         }
 482     }
 483 }
 484
 485 =head2 $req->uploads
 486
 487 Returns a reference to a hash containing uploads. Values can be either a
 488 L<Catalyst::Request::Upload> object, or an arrayref of
 489 L<Catalyst::Request::Upload> objects.
 490
 491     my $upload = $c->request->uploads->{field};
 492     my $upload = $c->request->uploads->{field}->[0];
 493
 494 =cut
 495
 496 sub uploads {
 497     my ( $self, $uploads ) = @_;
 498     $self->{_context}->prepare_body;
 499     $self->{uploads} = $uploads if $uploads;
 500     return $self->{uploads};
 501 }
 502
 503 =head2 $req->uri
 504
 505 Returns a URI object for the current request. Stringifies to the URI text.
 506
 507 =head2 $req->uri_with( { key => 'value' } );
 508
 509 Returns a rewritten URI object for the current request. Key/value pairs
 510 passed in will override existing parameters. Unmodified pairs will be
 511 preserved.
 512
 513 =cut
 514
 515 sub uri_with {
 516     my( $self, $args ) = @_;
 517
 518     carp( 'No arguments passed to uri_with()' ) unless $args;
 519
 520     for my $value ( values %$args ) {
 521         next unless defined $value;
 522         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 523             $_ = "$_";
 524             utf8::encode( $_ );
 525         }
 526     };
 527
 528     my $uri = $self->uri->clone;
 529
 530     $uri->query_form( {
 531         %{ $uri->query_form_hash },
 532         %$args
 533     } );
 534     return $uri;
 535 }
 536
 537 =head2 $req->user
 538
 539 Returns the currently logged in user. Deprecated. The method recommended for
 540 newer plugins is $c->user.
 541
 542 =head2 $req->user_agent
 543
 544 Shortcut to $req->headers->user_agent. Returns the user agent (browser)
 545 version string.
 546
 547 =head1 AUTHORS
 548
 549 Sebastian Riedel, C<sri@cpan.org>
 550
 551 Marcus Ramberg, C<mramberg@cpan.org>
 552
 553 =head1 COPYRIGHT
 554
 555 This program is free software, you can redistribute it and/or modify
 556 it under the same terms as Perl itself.
 557
 558 =cut
 559
 560 1;