lib/Catalyst/Request.pm

   1 package Catalyst::Request;
   2
   3 use IO::Socket qw[AF_INET inet_aton];
   4 use Carp;
   5 use utf8;
   6 use URI::http;
   7 use URI::https;
   8 use URI::QueryParam;
   9 use HTTP::Headers;
  10
  11 use Moose;
  12
  13 with 'MooseX::Emulate::Class::Accessor::Fast';
  14
  15 has action => (is => 'rw');
  16 has address => (is => 'rw');
  17 has arguments => (is => 'rw', default => sub { [] });
  18 has cookies => (is => 'rw', default => sub { {} });
  19 has query_keywords => (is => 'rw');
  20 has match => (is => 'rw');
  21 has method => (is => 'rw');
  22 has protocol => (is => 'rw');
  23 has query_parameters  => (is => 'rw', default => sub { {} });
  24 has secure => (is => 'rw', default => 0);
  25 has captures => (is => 'rw', default => sub { [] });
  26 has uri => (is => 'rw', predicate => 'has_uri');
  27 has user => (is => 'rw');
  28 has headers => (
  29   is      => 'rw',
  30   isa     => 'HTTP::Headers',
  31   handles => [qw(content_encoding content_length content_type header referer user_agent)],
  32   default => sub { HTTP::Headers->new() },
  33   required => 1,
  34   lazy => 1,
  35 );
  36
  37 # Moose TODO:
  38 # - Can we lose the before modifiers which just call prepare_body ?
  39 #   they are wasteful, slow us down and feel cluttery.
  40 # Can we call prepare_body at BUILD time?
  41 # Can we make _body an attribute, have the rest of
  42 # these lazy build from there and kill all the direct hash access
  43 # in Catalyst.pm and Engine.pm?
  44
  45 has _context => (
  46   is => 'rw',
  47   weak_ref => 1,
  48   handles => ['read'],
  49   clearer => '_clear_context',
  50 );
  51
  52 has body_parameters => (
  53   is => 'rw',
  54   required => 1,
  55   lazy => 1,
  56   default => sub { {} },
  57 );
  58
  59 before body_parameters => sub {
  60   my ($self) = @_;
  61   $self->_context->prepare_body();
  62 };
  63
  64 has uploads => (
  65   is => 'rw',
  66   required => 1,
  67   default => sub { {} },
  68 );
  69
  70 has parameters => (
  71   is => 'rw',
  72   required => 1,
  73   lazy => 1,
  74   default => sub { {} },
  75 );
  76
  77 before parameters => sub {
  78   my ($self, $params) = @_;
  79   if ( $params && !ref $params ) {
  80     $self->_context->log->warn(
  81         "Attempt to retrieve '$params' with req->params(), " .
  82         "you probably meant to call req->param('$params')" );
  83     $params = undef;
  84   }
  85
  86 };
  87
  88 has base => (
  89   is => 'rw',
  90   required => 1,
  91   lazy => 1,
  92   default => sub {
  93     my $self = shift;
  94     return $self->path if $self->has_uri;
  95   },
  96 );
  97
  98 has _body => (
  99   is => 'rw', clearer => '_clear_body', predicate => '_has_body',
 100 );
 101 # Eugh, ugly. Should just be able to rename accessor methods to 'body'
 102 #             and provide a custom reader..
 103 sub body {
 104   my $self = shift;
 105   $self->_context->prepare_body();
 106   $self->_body(@_) if scalar @_;
 107   return blessed $self->_body ? $self->_body->body : $self->_body;
 108 }
 109
 110 has hostname => (
 111   is        => 'rw',
 112   required  => 1,
 113   lazy      => 1,
 114   default   => sub {
 115     my ($self) = @_;
 116     gethostbyaddr( inet_aton( $self->address ), AF_INET ) || 'localhost'
 117   },
 118 );
 119
 120 has _path => ( is => 'rw', predicate => '_has_path', clearer => '_clear_path' );
 121
 122 no Moose;
 123
 124 sub args            { shift->arguments(@_) }
 125 sub body_params     { shift->body_parameters(@_) }
 126 sub input           { shift->body(@_) }
 127 sub params          { shift->parameters(@_) }
 128 sub query_params    { shift->query_parameters(@_) }
 129 sub path_info       { shift->path(@_) }
 130 sub snippets        { shift->captures(@_) }
 131
 132 =head1 NAME
 133
 134 Catalyst::Request - provides information about the current client request
 135
 136 =head1 SYNOPSIS
 137
 138     $req = $c->request;
 139     $req->action;
 140     $req->address;
 141     $req->arguments;
 142     $req->args;
 143     $req->base;
 144     $req->body;
 145     $req->body_parameters;
 146     $req->content_encoding;
 147     $req->content_length;
 148     $req->content_type;
 149     $req->cookie;
 150     $req->cookies;
 151     $req->header;
 152     $req->headers;
 153     $req->hostname;
 154     $req->input;
 155     $req->query_keywords;
 156     $req->match;
 157     $req->method;
 158     $req->param;
 159     $req->parameters;
 160     $req->params;
 161     $req->path;
 162     $req->protocol;
 163     $req->query_parameters;
 164     $req->read;
 165     $req->referer;
 166     $req->secure;
 167     $req->captures; # previously knows as snippets
 168     $req->upload;
 169     $req->uploads;
 170     $req->uri;
 171     $req->user;
 172     $req->user_agent;
 173
 174 See also L<Catalyst>, L<Catalyst::Request::Upload>.
 175
 176 =head1 DESCRIPTION
 177
 178 This is the Catalyst Request class, which provides an interface to data for the
 179 current client request. The request object is prepared by L<Catalyst::Engine>,
 180 thus hiding the details of the particular engine implementation.
 181
 182 =head1 METHODS
 183
 184 =head2 $req->action
 185
 186 [DEPRECATED] Returns the name of the requested action.
 187
 188
 189 Use C<< $c->action >> instead (which returns a
 190 L<Catalyst::Action|Catalyst::Action> object).
 191
 192 =head2 $req->address
 193
 194 Returns the IP address of the client.
 195
 196 =head2 $req->arguments
 197
 198 Returns a reference to an array containing the arguments.
 199
 200     print $c->request->arguments->[0];
 201
 202 For example, if your action was
 203
 204     package MyApp::C::Foo;
 205
 206     sub moose : Local {
 207         ...
 208     }
 209
 210 and the URI for the request was C<http://.../foo/moose/bah>, the string C<bah>
 211 would be the first and only argument.
 212
 213 =head2 $req->args
 214
 215 Shortcut for arguments.
 216
 217 =head2 $req->base
 218
 219 Contains the URI base. This will always have a trailing slash.
 220
 221 If your application was queried with the URI
 222 C<http://localhost:3000/some/path> then C<base> is C<http://localhost:3000/>.
 223
 224 =head2 $req->body
 225
 226 Returns the message body of the request, unless Content-Type is
 227 C<application/x-www-form-urlencoded> or C<multipart/form-data>.
 228
 229 =head2 $req->body_parameters
 230
 231 Returns a reference to a hash containing body (POST) parameters. Values can
 232 be either a scalar or an arrayref containing scalars.
 233
 234     print $c->request->body_parameters->{field};
 235     print $c->request->body_parameters->{field}->[0];
 236
 237 These are the parameters from the POST part of the request, if any.
 238
 239 =head2 $req->body_params
 240
 241 Shortcut for body_parameters.
 242
 243 =head2 $req->content_encoding
 244
 245 Shortcut for $req->headers->content_encoding.
 246
 247 =head2 $req->content_length
 248
 249 Shortcut for $req->headers->content_length.
 250
 251 =head2 $req->content_type
 252
 253 Shortcut for $req->headers->content_type.
 254
 255 =head2 $req->cookie
 256
 257 A convenient method to access $req->cookies.
 258
 259     $cookie  = $c->request->cookie('name');
 260     @cookies = $c->request->cookie;
 261
 262 =cut
 263
 264 sub cookie {
 265     my $self = shift;
 266
 267     if ( @_ == 0 ) {
 268         return keys %{ $self->cookies };
 269     }
 270
 271     if ( @_ == 1 ) {
 272
 273         my $name = shift;
 274
 275         unless ( exists $self->cookies->{$name} ) {
 276             return undef;
 277         }
 278
 279         return $self->cookies->{$name};
 280     }
 281 }
 282
 283 =head2 $req->cookies
 284
 285 Returns a reference to a hash containing the cookies.
 286
 287     print $c->request->cookies->{mycookie}->value;
 288
 289 The cookies in the hash are indexed by name, and the values are L<CGI::Cookie>
 290 objects.
 291
 292 =head2 $req->header
 293
 294 Shortcut for $req->headers->header.
 295
 296 =head2 $req->headers
 297
 298 Returns an L<HTTP::Headers> object containing the headers for the current request.
 299
 300     print $c->request->headers->header('X-Catalyst');
 301
 302 =head2 $req->hostname
 303
 304 Returns the hostname of the client.
 305
 306 =head2 $req->input
 307
 308 Alias for $req->body.
 309
 310 =head2 $req->query_keywords
 311
 312 Contains the keywords portion of a query string, when no '=' signs are
 313 present.
 314
 315     http://localhost/path?some+keywords
 316
 317     $c->request->query_keywords will contain 'some keywords'
 318
 319 =head2 $req->match
 320
 321 This contains the matching part of a Regex action. Otherwise
 322 it returns the same as 'action', except for default actions,
 323 which return an empty string.
 324
 325 =head2 $req->method
 326
 327 Contains the request method (C<GET>, C<POST>, C<HEAD>, etc).
 328
 329 =head2 $req->param
 330
 331 Returns GET and POST parameters with a CGI.pm-compatible param method. This
 332 is an alternative method for accessing parameters in $c->req->parameters.
 333
 334     $value  = $c->request->param( 'foo' );
 335     @values = $c->request->param( 'foo' );
 336     @params = $c->request->param;
 337
 338 Like L<CGI>, and B<unlike> earlier versions of Catalyst, passing multiple
 339 arguments to this method, like this:
 340
 341     $c->request->param( 'foo', 'bar', 'gorch', 'quxx' );
 342
 343 will set the parameter C<foo> to the multiple values C<bar>, C<gorch> and
 344 C<quxx>. Previously this would have added C<bar> as another value to C<foo>
 345 (creating it if it didn't exist before), and C<quxx> as another value for
 346 C<gorch>.
 347
 348 =cut
 349
 350 sub param {
 351     my $self = shift;
 352
 353     if ( @_ == 0 ) {
 354         return keys %{ $self->parameters };
 355     }
 356
 357     if ( @_ == 1 ) {
 358
 359         my $param = shift;
 360
 361         unless ( exists $self->parameters->{$param} ) {
 362             return wantarray ? () : undef;
 363         }
 364
 365         if ( ref $self->parameters->{$param} eq 'ARRAY' ) {
 366             return (wantarray)
 367               ? @{ $self->parameters->{$param} }
 368               : $self->parameters->{$param}->[0];
 369         }
 370         else {
 371             return (wantarray)
 372               ? ( $self->parameters->{$param} )
 373               : $self->parameters->{$param};
 374         }
 375     }
 376     elsif ( @_ > 1 ) {
 377         my $field = shift;
 378         $self->parameters->{$field} = [@_];
 379     }
 380 }
 381
 382 =head2 $req->parameters
 383
 384 Returns a reference to a hash containing GET and POST parameters. Values can
 385 be either a scalar or an arrayref containing scalars.
 386
 387     print $c->request->parameters->{field};
 388     print $c->request->parameters->{field}->[0];
 389
 390 This is the combination of C<query_parameters> and C<body_parameters>.
 391
 392 =head2 $req->params
 393
 394 Shortcut for $req->parameters.
 395
 396 =head2 $req->path
 397
 398 Returns the path, i.e. the part of the URI after $req->base, for the current request.
 399
 400 =head2 $req->path_info
 401
 402 Alias for path, added for compability with L<CGI>.
 403
 404 =cut
 405
 406 sub path {
 407     my ( $self, @params ) = @_;
 408
 409     if (@params) {
 410         $self->uri->path(@params);
 411         $self->_clear_path;
 412     }
 413     elsif ( $self->_has_path ) {
 414         return $self->_path;
 415     }
 416     else {
 417         my $path     = $self->uri->path;
 418         my $location = $self->base->path;
 419         $path =~ s/^(\Q$location\E)?//;
 420         $path =~ s/^\///;
 421         $self->_path($path);
 422
 423         return $path;
 424     }
 425 }
 426
 427 =head2 $req->protocol
 428
 429 Returns the protocol (HTTP/1.0 or HTTP/1.1) used for the current request.
 430
 431 =head2 $req->query_parameters
 432
 433 =head2 $req->query_params
 434
 435 Returns a reference to a hash containing query string (GET) parameters. Values can
 436 be either a scalar or an arrayref containing scalars.
 437
 438     print $c->request->query_parameters->{field};
 439     print $c->request->query_parameters->{field}->[0];
 440
 441 =head2 $req->read( [$maxlength] )
 442
 443 Reads a chunk of data from the request body. This method is intended to be
 444 used in a while loop, reading $maxlength bytes on every call. $maxlength
 445 defaults to the size of the request if not specified.
 446
 447 You have to set MyApp->config->{parse_on_demand} to use this directly.
 448
 449 =head2 $req->referer
 450
 451 Shortcut for $req->headers->referer. Returns the referring page.
 452
 453 =head2 $req->secure
 454
 455 Returns true or false, indicating whether the connection is secure (https).
 456
 457 =head2 $req->captures
 458
 459 Returns a reference to an array containing captured args from chained
 460 actions or regex captures.
 461
 462     my @captures = @{ $c->request->captures };
 463
 464 =head2 $req->snippets
 465
 466 C<captures> used to be called snippets. This is still available for backwoards
 467 compatibility, but is considered deprecated.
 468
 469 =head2 $req->upload
 470
 471 A convenient method to access $req->uploads.
 472
 473     $upload  = $c->request->upload('field');
 474     @uploads = $c->request->upload('field');
 475     @fields  = $c->request->upload;
 476
 477     for my $upload ( $c->request->upload('field') ) {
 478         print $upload->filename;
 479     }
 480
 481 =cut
 482
 483 sub upload {
 484     my $self = shift;
 485
 486     if ( @_ == 0 ) {
 487         return keys %{ $self->uploads };
 488     }
 489
 490     if ( @_ == 1 ) {
 491
 492         my $upload = shift;
 493
 494         unless ( exists $self->uploads->{$upload} ) {
 495             return wantarray ? () : undef;
 496         }
 497
 498         if ( ref $self->uploads->{$upload} eq 'ARRAY' ) {
 499             return (wantarray)
 500               ? @{ $self->uploads->{$upload} }
 501               : $self->uploads->{$upload}->[0];
 502         }
 503         else {
 504             return (wantarray)
 505               ? ( $self->uploads->{$upload} )
 506               : $self->uploads->{$upload};
 507         }
 508     }
 509
 510     if ( @_ > 1 ) {
 511
 512         while ( my ( $field, $upload ) = splice( @_, 0, 2 ) ) {
 513
 514             if ( exists $self->uploads->{$field} ) {
 515                 for ( $self->uploads->{$field} ) {
 516                     $_ = [$_] unless ref($_) eq "ARRAY";
 517                     push( @$_, $upload );
 518                 }
 519             }
 520             else {
 521                 $self->uploads->{$field} = $upload;
 522             }
 523         }
 524     }
 525 }
 526
 527 =head2 $req->uploads
 528
 529 Returns a reference to a hash containing uploads. Values can be either a
 530 L<Catalyst::Request::Upload> object, or an arrayref of
 531 L<Catalyst::Request::Upload> objects.
 532
 533     my $upload = $c->request->uploads->{field};
 534     my $upload = $c->request->uploads->{field}->[0];
 535
 536 =head2 $req->uri
 537
 538 Returns a URI object for the current request. Stringifies to the URI text.
 539
 540 =head2 $req->uri_with( { key => 'value' } );
 541
 542 Returns a rewritten URI object for the current request. Key/value pairs
 543 passed in will override existing parameters. You can remove an existing
 544 parameter by passing in an undef value. Unmodified pairs will be
 545 preserved.
 546
 547 =cut
 548
 549 sub uri_with {
 550     my( $self, $args ) = @_;
 551
 552     carp( 'No arguments passed to uri_with()' ) unless $args;
 553
 554     foreach my $value ( values %$args ) {
 555         next unless defined $value;
 556         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 557             $_ = "$_";
 558             utf8::encode( $_ ) if utf8::is_utf8($_);
 559         }
 560     };
 561
 562     my $uri   = $self->uri->clone;
 563     my %query = ( %{ $uri->query_form_hash }, %$args );
 564
 565     $uri->query_form( {
 566         # remove undef values
 567         map { defined $query{ $_ } ? ( $_ => $query{ $_ } ) : () } keys %query
 568     } );
 569     return $uri;
 570 }
 571
 572 =head2 $req->user
 573
 574 Returns the currently logged in user. Deprecated. The method recommended for
 575 newer plugins is $c->user.
 576
 577 =head2 $req->user_agent
 578
 579 Shortcut to $req->headers->user_agent. Returns the user agent (browser)
 580 version string.
 581
 582 =head2 meta
 583
 584 Provided by Moose
 585
 586 =head1 AUTHORS
 587
 588 Catalyst Contributors, see Catalyst.pm
 589
 590 =head1 COPYRIGHT
 591
 592 This program is free software, you can redistribute it and/or modify
 593 it under the same terms as Perl itself.
 594
 595 =cut
 596
 597 __PACKAGE__->meta->make_immutable;
 598
 599 1;