lib/Catalyst/Request.pm

   1 package Catalyst::Request;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5
   6 use IO::Socket qw[AF_INET inet_aton];
   7 use Carp;
   8 use utf8;
   9 use URI::QueryParam;
  10
  11 __PACKAGE__->mk_accessors(
  12     qw/action address arguments cookies headers match method
  13       protocol query_parameters secure captures uri user/
  14 );
  15
  16 *args         = \&arguments;
  17 *body_params  = \&body_parameters;
  18 *input        = \&body;
  19 *params       = \&parameters;
  20 *query_params = \&query_parameters;
  21 *path_info    = \&path;
  22 *snippets     = \&captures;
  23
  24 sub content_encoding { shift->headers->content_encoding(@_) }
  25 sub content_length   { shift->headers->content_length(@_) }
  26 sub content_type     { shift->headers->content_type(@_) }
  27 sub header           { shift->headers->header(@_) }
  28 sub referer          { shift->headers->referer(@_) }
  29 sub user_agent       { shift->headers->user_agent(@_) }
  30
  31 =head1 NAME
  32
  33 Catalyst::Request - provides information about the current client request
  34
  35 =head1 SYNOPSIS
  36
  37     $req = $c->request;
  38     $req->action;
  39     $req->address;
  40     $req->arguments;
  41     $req->args;
  42     $req->base;
  43     $req->body;
  44     $req->body_parameters;
  45     $req->content_encoding;
  46     $req->content_length;
  47     $req->content_type;
  48     $req->cookie;
  49     $req->cookies;
  50     $req->header;
  51     $req->headers;
  52     $req->hostname;
  53     $req->input;
  54     $req->match;
  55     $req->method;
  56     $req->param;
  57     $req->parameters;
  58     $req->params;
  59     $req->path;
  60     $req->protocol;
  61     $req->query_parameters;
  62     $req->read;
  63     $req->referer;
  64     $req->secure;
  65     $req->captures; # previously knows as snippets
  66     $req->upload;
  67     $req->uploads;
  68     $req->uri;
  69     $req->user;
  70     $req->user_agent;
  71
  72 See also L<Catalyst>, L<Catalyst::Request::Upload>.
  73
  74 =head1 DESCRIPTION
  75
  76 This is the Catalyst Request class, which provides an interface to data for the
  77 current client request. The request object is prepared by L<Catalyst::Engine>,
  78 thus hiding the details of the particular engine implementation.
  79
  80 =head1 METHODS
  81
  82 =head2 $req->action
  83
  84 [DEPRECATED] Returns the name of the requested action.
  85
  86
  87 Use C<< $c->action >> instead (which returns a
  88 L<Catalyst::Action|Catalyst::Action> object).
  89
  90 =head2 $req->address
  91
  92 Returns the IP address of the client.
  93
  94 =head2 $req->arguments
  95
  96 Returns a reference to an array containing the arguments.
  97
  98     print $c->request->arguments->[0];
  99
 100 For example, if your action was
 101
 102         package MyApp::C::Foo;
 103
 104         sub moose : Local {
 105                 ...
 106         }
 107
 108 and the URI for the request was C<http://.../foo/moose/bah>, the string C<bah>
 109 would be the first and only argument.
 110
 111 =head2 $req->args
 112
 113 Shortcut for arguments.
 114
 115 =head2 $req->base
 116
 117 Contains the URI base. This will always have a trailing slash.
 118
 119 If your application was queried with the URI
 120 C<http://localhost:3000/some/path> then C<base> is C<http://localhost:3000/>.
 121
 122 =cut
 123
 124 sub base {
 125     my ( $self, $base ) = @_;
 126
 127     return $self->{base} unless $base;
 128
 129     $self->{base} = $base;
 130
 131     # set the value in path for backwards-compat
 132     if ( $self->uri ) {
 133         $self->path;
 134     }
 135
 136     return $self->{base};
 137 }
 138
 139 =head2 $req->body
 140
 141 Returns the message body of the request, unless Content-Type is
 142 C<application/x-www-form-urlencoded> or C<multipart/form-data>.
 143
 144 =cut
 145
 146 sub body {
 147     my ( $self, $body ) = @_;
 148     $self->{_context}->prepare_body;
 149     return $self->{_body}->body;
 150 }
 151
 152 =head2 $req->body_parameters
 153
 154 Returns a reference to a hash containing body (POST) parameters. Values can
 155 be either a scalar or an arrayref containing scalars.
 156
 157     print $c->request->body_parameters->{field};
 158     print $c->request->body_parameters->{field}->[0];
 159
 160 These are the parameters from the POST part of the request, if any.
 161
 162 =head2 $req->body_params
 163
 164 Shortcut for body_parameters.
 165
 166 =cut
 167
 168 sub body_parameters {
 169     my ( $self, $params ) = @_;
 170     $self->{_context}->prepare_body;
 171     $self->{body_parameters} = $params if $params;
 172     return $self->{body_parameters};
 173 }
 174
 175 =head2 $req->content_encoding
 176
 177 Shortcut for $req->headers->content_encoding.
 178
 179 =head2 $req->content_length
 180
 181 Shortcut for $req->headers->content_length.
 182
 183 =head2 $req->content_type
 184
 185 Shortcut for $req->headers->content_type.
 186
 187 =head2 $req->cookie
 188
 189 A convenient method to access $req->cookies.
 190
 191     $cookie  = $c->request->cookie('name');
 192     @cookies = $c->request->cookie;
 193
 194 =cut
 195
 196 sub cookie {
 197     my $self = shift;
 198
 199     if ( @_ == 0 ) {
 200         return keys %{ $self->cookies };
 201     }
 202
 203     if ( @_ == 1 ) {
 204
 205         my $name = shift;
 206
 207         unless ( exists $self->cookies->{$name} ) {
 208             return undef;
 209         }
 210
 211         return $self->cookies->{$name};
 212     }
 213 }
 214
 215 =head2 $req->cookies
 216
 217 Returns a reference to a hash containing the cookies.
 218
 219     print $c->request->cookies->{mycookie}->value;
 220
 221 The cookies in the hash are indexed by name, and the values are L<CGI::Cookie>
 222 objects.
 223
 224 =head2 $req->header
 225
 226 Shortcut for $req->headers->header.
 227
 228 =head2 $req->headers
 229
 230 Returns an L<HTTP::Headers> object containing the headers for the current request.
 231
 232     print $c->request->headers->header('X-Catalyst');
 233
 234 =head2 $req->hostname
 235
 236 Returns the hostname of the client.
 237
 238 =cut
 239
 240 sub hostname {
 241     my $self = shift;
 242
 243     if ( @_ == 0 && not $self->{hostname} ) {
 244         $self->{hostname} =
 245           gethostbyaddr( inet_aton( $self->address ), AF_INET );
 246     }
 247
 248     if ( @_ == 1 ) {
 249         $self->{hostname} = shift;
 250     }
 251
 252     return $self->{hostname};
 253 }
 254
 255 =head2 $req->input
 256
 257 Alias for $req->body.
 258
 259 =head2 $req->match
 260
 261 This contains the matching part of a Regex action. Otherwise
 262 it returns the same as 'action', except for default actions,
 263 which return an empty string.
 264
 265 =head2 $req->method
 266
 267 Contains the request method (C<GET>, C<POST>, C<HEAD>, etc).
 268
 269 =head2 $req->param
 270
 271 Returns GET and POST parameters with a CGI.pm-compatible param method. This
 272 is an alternative method for accessing parameters in $c->req->parameters.
 273
 274     $value  = $c->request->param( 'foo' );
 275     @values = $c->request->param( 'foo' );
 276     @params = $c->request->param;
 277
 278 Like L<CGI>, and B<unlike> earlier versions of Catalyst, passing multiple
 279 arguments to this method, like this:
 280
 281         $c->request->param( 'foo', 'bar', 'gorch', 'quxx' );
 282
 283 will set the parameter C<foo> to the multiple values C<bar>, C<gorch> and
 284 C<quxx>. Previously this would have added C<bar> as another value to C<foo>
 285 (creating it if it didn't exist before), and C<quxx> as another value for
 286 C<gorch>.
 287
 288 =cut
 289
 290 sub param {
 291     my $self = shift;
 292
 293     if ( @_ == 0 ) {
 294         return keys %{ $self->parameters };
 295     }
 296
 297     if ( @_ == 1 ) {
 298
 299         my $param = shift;
 300
 301         unless ( exists $self->parameters->{$param} ) {
 302             return wantarray ? () : undef;
 303         }
 304
 305         if ( ref $self->parameters->{$param} eq 'ARRAY' ) {
 306             return (wantarray)
 307               ? @{ $self->parameters->{$param} }
 308               : $self->parameters->{$param}->[0];
 309         }
 310         else {
 311             return (wantarray)
 312               ? ( $self->parameters->{$param} )
 313               : $self->parameters->{$param};
 314         }
 315     }
 316     elsif ( @_ > 1 ) {
 317         my $field = shift;
 318         $self->parameters->{$field} = [@_];
 319     }
 320 }
 321
 322 =head2 $req->parameters
 323
 324 Returns a reference to a hash containing GET and POST parameters. Values can
 325 be either a scalar or an arrayref containing scalars.
 326
 327     print $c->request->parameters->{field};
 328     print $c->request->parameters->{field}->[0];
 329
 330 This is the combination of C<query_parameters> and C<body_parameters>.
 331
 332 =head2 $req->params
 333
 334 Shortcut for $req->parameters.
 335
 336 =cut
 337
 338 sub parameters {
 339     my ( $self, $params ) = @_;
 340     $self->{_context}->prepare_body;
 341     if ( $params ) {
 342         if ( ref $params ) {
 343             $self->{parameters} = $params;
 344         }
 345         else {
 346             $self->{_context}->log->warn(
 347                 "Attempt to retrieve '$params' with req->params(), " .
 348                 "you probably meant to call req->param('$params')" );
 349         }
 350     }
 351     return $self->{parameters};
 352 }
 353
 354 =head2 $req->path
 355
 356 Returns the path, i.e. the part of the URI after $req->base, for the current request.
 357
 358 =head2 $req->path_info
 359
 360 Alias for path, added for compability with L<CGI>.
 361
 362 =cut
 363
 364 sub path {
 365     my ( $self, $params ) = @_;
 366
 367     if ($params) {
 368         $self->uri->path($params);
 369     }
 370     else {
 371         return $self->{path} if $self->{path};
 372     }
 373
 374     my $path     = $self->uri->path;
 375     my $location = $self->base->path;
 376     $path =~ s/^(\Q$location\E)?//;
 377     $path =~ s/^\///;
 378     $self->{path} = $path;
 379
 380     return $path;
 381 }
 382
 383 =head2 $req->protocol
 384
 385 Returns the protocol (HTTP/1.0 or HTTP/1.1) used for the current request.
 386
 387 =head2 $req->query_parameters
 388
 389 Returns a reference to a hash containing query string (GET) parameters. Values can
 390 be either a scalar or an arrayref containing scalars.
 391
 392     print $c->request->query_parameters->{field};
 393     print $c->request->query_parameters->{field}->[0];
 394
 395 =head2 $req->read( [$maxlength] )
 396
 397 Reads a chunk of data from the request body. This method is intended to be
 398 used in a while loop, reading $maxlength bytes on every call. $maxlength
 399 defaults to the size of the request if not specified.
 400
 401 You have to set MyApp->config->{parse_on_demand} to use this directly.
 402
 403 =cut
 404
 405 sub read { shift->{_context}->read(@_); }
 406
 407 =head2 $req->referer
 408
 409 Shortcut for $req->headers->referer. Returns the referring page.
 410
 411 =head2 $req->secure
 412
 413 Returns true or false, indicating whether the connection is secure (https).
 414
 415 =head2 $req->captures
 416
 417 Returns a reference to an array containing regex captures.
 418
 419     my @captures = @{ $c->request->captures };
 420
 421 =head2 $req->snippets
 422
 423 C<captures> used to be called snippets. This is still available for backwoards
 424 compatibility, but is considered deprecated.
 425
 426 =head2 $req->upload
 427
 428 A convenient method to access $req->uploads.
 429
 430     $upload  = $c->request->upload('field');
 431     @uploads = $c->request->upload('field');
 432     @fields  = $c->request->upload;
 433
 434     for my $upload ( $c->request->upload('field') ) {
 435         print $upload->filename;
 436     }
 437
 438 =cut
 439
 440 sub upload {
 441     my $self = shift;
 442
 443     if ( @_ == 0 ) {
 444         return keys %{ $self->uploads };
 445     }
 446
 447     if ( @_ == 1 ) {
 448
 449         my $upload = shift;
 450
 451         unless ( exists $self->uploads->{$upload} ) {
 452             return wantarray ? () : undef;
 453         }
 454
 455         if ( ref $self->uploads->{$upload} eq 'ARRAY' ) {
 456             return (wantarray)
 457               ? @{ $self->uploads->{$upload} }
 458               : $self->uploads->{$upload}->[0];
 459         }
 460         else {
 461             return (wantarray)
 462               ? ( $self->uploads->{$upload} )
 463               : $self->uploads->{$upload};
 464         }
 465     }
 466
 467     if ( @_ > 1 ) {
 468
 469         while ( my ( $field, $upload ) = splice( @_, 0, 2 ) ) {
 470
 471             if ( exists $self->uploads->{$field} ) {
 472                 for ( $self->uploads->{$field} ) {
 473                     $_ = [$_] unless ref($_) eq "ARRAY";
 474                     push( @$_, $upload );
 475                 }
 476             }
 477             else {
 478                 $self->uploads->{$field} = $upload;
 479             }
 480         }
 481     }
 482 }
 483
 484 =head2 $req->uploads
 485
 486 Returns a reference to a hash containing uploads. Values can be either a
 487 hashref or a arrayref containing L<Catalyst::Request::Upload> objects.
 488
 489     my $upload = $c->request->uploads->{field};
 490     my $upload = $c->request->uploads->{field}->[0];
 491
 492 =cut
 493
 494 sub uploads {
 495     my ( $self, $uploads ) = @_;
 496     $self->{_context}->prepare_body;
 497     $self->{uploads} = $uploads if $uploads;
 498     return $self->{uploads};
 499 }
 500
 501 =head2 $req->uri
 502
 503 Returns a URI object for the current request. Stringifies to the URI text.
 504
 505 =head2 $req->uri_with( { key => 'value' } );
 506
 507 Returns a rewritten URI object for the current request. Key/value pairs
 508 passed in will override existing parameters. Unmodified pairs will be
 509 preserved.
 510
 511 =cut
 512
 513 sub uri_with {
 514     my( $self, $args ) = @_;
 515
 516     carp( 'No arguments passed to uri_with()' ) unless $args;
 517
 518     for my $value ( values %$args ) {
 519         next unless defined $value;
 520         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 521             $_ = "$_";
 522             utf8::encode( $_ );
 523         }
 524     };
 525
 526     my $uri = $self->uri->clone;
 527
 528     $uri->query_form( {
 529         %{ $uri->query_form_hash },
 530         %$args
 531     } );
 532     return $uri;
 533 }
 534
 535 =head2 $req->user
 536
 537 Returns the currently logged in user. Deprecated. The method recommended for
 538 newer plugins is $c->user.
 539
 540 =head2 $req->user_agent
 541
 542 Shortcut to $req->headers->user_agent. Returns the user agent (browser)
 543 version string.
 544
 545 =head1 AUTHORS
 546
 547 Sebastian Riedel, C<sri@cpan.org>
 548
 549 Marcus Ramberg, C<mramberg@cpan.org>
 550
 551 =head1 COPYRIGHT
 552
 553 This program is free software, you can redistribute it and/or modify
 554 it under the same terms as Perl itself.
 555
 556 =cut
 557
 558 1;