lib/Catalyst/Request.pm

   1 package Catalyst::Request;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5
   6 use IO::Socket qw[AF_INET inet_aton];
   7 use Carp;
   8 use utf8;
   9 use URI::QueryParam;
  10
  11 __PACKAGE__->mk_accessors(
  12     qw/action address arguments cookies headers match method
  13       protocol query_parameters secure captures uri user/
  14 );
  15
  16 *args         = \&arguments;
  17 *body_params  = \&body_parameters;
  18 *input        = \&body;
  19 *params       = \&parameters;
  20 *query_params = \&query_parameters;
  21 *path_info    = \&path;
  22 *snippets     = \&captures;
  23
  24 sub content_encoding { shift->headers->content_encoding(@_) }
  25 sub content_length   { shift->headers->content_length(@_) }
  26 sub content_type     { shift->headers->content_type(@_) }
  27 sub header           { shift->headers->header(@_) }
  28 sub referer          { shift->headers->referer(@_) }
  29 sub user_agent       { shift->headers->user_agent(@_) }
  30
  31 =head1 NAME
  32
  33 Catalyst::Request - provides information about the current client request
  34
  35 =head1 SYNOPSIS
  36
  37     $req = $c->request;
  38     $req->action;
  39     $req->address;
  40     $req->arguments;
  41     $req->args;
  42     $req->base;
  43     $req->body;
  44     $req->body_parameters;
  45     $req->content_encoding;
  46     $req->content_length;
  47     $req->content_type;
  48     $req->cookie;
  49     $req->cookies;
  50     $req->header;
  51     $req->headers;
  52     $req->hostname;
  53     $req->input;
  54     $req->match;
  55     $req->method;
  56     $req->param;
  57     $req->parameters;
  58     $req->params;
  59     $req->path;
  60     $req->protocol;
  61     $req->query_parameters;
  62     $req->read;
  63     $req->referer;
  64     $req->secure;
  65     $req->captures; # previously knows as snippets
  66     $req->upload;
  67     $req->uploads;
  68     $req->uri;
  69     $req->user;
  70     $req->user_agent;
  71
  72 See also L<Catalyst>, L<Catalyst::Request::Upload>.
  73
  74 =head1 DESCRIPTION
  75
  76 This is the Catalyst Request class, which provides an interface to data for the
  77 current client request. The request object is prepared by L<Catalyst::Engine>,
  78 thus hiding the details of the particular engine implementation.
  79
  80 =head1 METHODS
  81
  82 =head2 $req->action
  83
  84 [DEPRECATED] Returns the name of the requested action.
  85
  86
  87 Use C<< $c->action >> instead (which returns a
  88 L<Catalyst::Action|Catalyst::Action> object).
  89
  90 =head2 $req->address
  91
  92 Returns the IP address of the client.
  93
  94 =head2 $req->arguments
  95
  96 Returns a reference to an array containing the arguments.
  97
  98     print $c->request->arguments->[0];
  99
 100 For example, if your action was
 101
 102     package MyApp::C::Foo;
 103
 104     sub moose : Local {
 105         ...
 106     }
 107
 108 and the URI for the request was C<http://.../foo/moose/bah>, the string C<bah>
 109 would be the first and only argument.
 110
 111 =head2 $req->args
 112
 113 Shortcut for arguments.
 114
 115 =head2 $req->base
 116
 117 Contains the URI base. This will always have a trailing slash.
 118
 119 If your application was queried with the URI
 120 C<http://localhost:3000/some/path> then C<base> is C<http://localhost:3000/>.
 121
 122 =cut
 123
 124 sub base {
 125     my ( $self, $base ) = @_;
 126
 127     return $self->{base} unless $base;
 128
 129     $self->{base} = $base;
 130
 131     # set the value in path for backwards-compat
 132     if ( $self->uri ) {
 133         $self->path;
 134     }
 135
 136     return $self->{base};
 137 }
 138
 139 =head2 $req->body
 140
 141 Returns the message body of the request, unless Content-Type is
 142 C<application/x-www-form-urlencoded> or C<multipart/form-data>.
 143
 144 =cut
 145
 146 sub body {
 147     my $self = shift;
 148     $self->{_context}->prepare_body;
 149
 150     return unless $self->{_body};
 151
 152     return $self->{_body}->body;
 153 }
 154
 155 =head2 $req->body_parameters
 156
 157 Returns a reference to a hash containing body (POST) parameters. Values can
 158 be either a scalar or an arrayref containing scalars.
 159
 160     print $c->request->body_parameters->{field};
 161     print $c->request->body_parameters->{field}->[0];
 162
 163 These are the parameters from the POST part of the request, if any.
 164
 165 =head2 $req->body_params
 166
 167 Shortcut for body_parameters.
 168
 169 =cut
 170
 171 sub body_parameters {
 172     my ( $self, $params ) = @_;
 173     $self->{_context}->prepare_body;
 174     $self->{body_parameters} = $params if $params;
 175     return $self->{body_parameters};
 176 }
 177
 178 =head2 $req->content_encoding
 179
 180 Shortcut for $req->headers->content_encoding.
 181
 182 =head2 $req->content_length
 183
 184 Shortcut for $req->headers->content_length.
 185
 186 =head2 $req->content_type
 187
 188 Shortcut for $req->headers->content_type.
 189
 190 =head2 $req->cookie
 191
 192 A convenient method to access $req->cookies.
 193
 194     $cookie  = $c->request->cookie('name');
 195     @cookies = $c->request->cookie;
 196
 197 =cut
 198
 199 sub cookie {
 200     my $self = shift;
 201
 202     if ( @_ == 0 ) {
 203         return keys %{ $self->cookies };
 204     }
 205
 206     if ( @_ == 1 ) {
 207
 208         my $name = shift;
 209
 210         unless ( exists $self->cookies->{$name} ) {
 211             return undef;
 212         }
 213
 214         return $self->cookies->{$name};
 215     }
 216 }
 217
 218 =head2 $req->cookies
 219
 220 Returns a reference to a hash containing the cookies.
 221
 222     print $c->request->cookies->{mycookie}->value;
 223
 224 The cookies in the hash are indexed by name, and the values are L<CGI::Cookie>
 225 objects.
 226
 227 =head2 $req->header
 228
 229 Shortcut for $req->headers->header.
 230
 231 =head2 $req->headers
 232
 233 Returns an L<HTTP::Headers> object containing the headers for the current request.
 234
 235     print $c->request->headers->header('X-Catalyst');
 236
 237 =head2 $req->hostname
 238
 239 Returns the hostname of the client.
 240
 241 =cut
 242
 243 sub hostname {
 244     my $self = shift;
 245
 246     if ( @_ == 0 && not $self->{hostname} ) {
 247         $self->{hostname} =
 248           gethostbyaddr( inet_aton( $self->address ), AF_INET );
 249     }
 250
 251     if ( @_ == 1 ) {
 252         $self->{hostname} = shift;
 253     }
 254
 255     return $self->{hostname};
 256 }
 257
 258 =head2 $req->input
 259
 260 Alias for $req->body.
 261
 262 =head2 $req->match
 263
 264 This contains the matching part of a Regex action. Otherwise
 265 it returns the same as 'action', except for default actions,
 266 which return an empty string.
 267
 268 =head2 $req->method
 269
 270 Contains the request method (C<GET>, C<POST>, C<HEAD>, etc).
 271
 272 =head2 $req->param
 273
 274 Returns GET and POST parameters with a CGI.pm-compatible param method. This
 275 is an alternative method for accessing parameters in $c->req->parameters.
 276
 277     $value  = $c->request->param( 'foo' );
 278     @values = $c->request->param( 'foo' );
 279     @params = $c->request->param;
 280
 281 Like L<CGI>, and B<unlike> earlier versions of Catalyst, passing multiple
 282 arguments to this method, like this:
 283
 284     $c->request->param( 'foo', 'bar', 'gorch', 'quxx' );
 285
 286 will set the parameter C<foo> to the multiple values C<bar>, C<gorch> and
 287 C<quxx>. Previously this would have added C<bar> as another value to C<foo>
 288 (creating it if it didn't exist before), and C<quxx> as another value for
 289 C<gorch>.
 290
 291 =cut
 292
 293 sub param {
 294     my $self = shift;
 295
 296     if ( @_ == 0 ) {
 297         return keys %{ $self->parameters };
 298     }
 299
 300     if ( @_ == 1 ) {
 301
 302         my $param = shift;
 303
 304         unless ( exists $self->parameters->{$param} ) {
 305             return wantarray ? () : undef;
 306         }
 307
 308         if ( ref $self->parameters->{$param} eq 'ARRAY' ) {
 309             return (wantarray)
 310               ? @{ $self->parameters->{$param} }
 311               : $self->parameters->{$param}->[0];
 312         }
 313         else {
 314             return (wantarray)
 315               ? ( $self->parameters->{$param} )
 316               : $self->parameters->{$param};
 317         }
 318     }
 319     elsif ( @_ > 1 ) {
 320         my $field = shift;
 321         $self->parameters->{$field} = [@_];
 322     }
 323 }
 324
 325 =head2 $req->parameters
 326
 327 Returns a reference to a hash containing GET and POST parameters. Values can
 328 be either a scalar or an arrayref containing scalars.
 329
 330     print $c->request->parameters->{field};
 331     print $c->request->parameters->{field}->[0];
 332
 333 This is the combination of C<query_parameters> and C<body_parameters>.
 334
 335 =head2 $req->params
 336
 337 Shortcut for $req->parameters.
 338
 339 =cut
 340
 341 sub parameters {
 342     my ( $self, $params ) = @_;
 343     $self->{_context}->prepare_body;
 344     if ( $params ) {
 345         if ( ref $params ) {
 346             $self->{parameters} = $params;
 347         }
 348         else {
 349             $self->{_context}->log->warn(
 350                 "Attempt to retrieve '$params' with req->params(), " .
 351                 "you probably meant to call req->param('$params')" );
 352         }
 353     }
 354     return $self->{parameters};
 355 }
 356
 357 =head2 $req->path
 358
 359 Returns the path, i.e. the part of the URI after $req->base, for the current request.
 360
 361 =head2 $req->path_info
 362
 363 Alias for path, added for compability with L<CGI>.
 364
 365 =cut
 366
 367 sub path {
 368     my ( $self, @params ) = @_;
 369
 370     if (@params) {
 371         $self->uri->path(@params);
 372         undef $self->{path};
 373     }
 374     elsif ( defined( my $path = $self->{path} ) ) {
 375         return $path;
 376     }
 377     else {
 378         my $path     = $self->uri->path;
 379         my $location = $self->base->path;
 380         $path =~ s/^(\Q$location\E)?//;
 381         $path =~ s/^\///;
 382         $self->{path} = $path;
 383
 384         return $path;
 385     }
 386 }
 387
 388 =head2 $req->protocol
 389
 390 Returns the protocol (HTTP/1.0 or HTTP/1.1) used for the current request.
 391
 392 =head2 $req->query_parameters
 393
 394 Returns a reference to a hash containing query string (GET) parameters. Values can
 395 be either a scalar or an arrayref containing scalars.
 396
 397     print $c->request->query_parameters->{field};
 398     print $c->request->query_parameters->{field}->[0];
 399
 400 =head2 $req->read( [$maxlength] )
 401
 402 Reads a chunk of data from the request body. This method is intended to be
 403 used in a while loop, reading $maxlength bytes on every call. $maxlength
 404 defaults to the size of the request if not specified.
 405
 406 You have to set MyApp->config->{parse_on_demand} to use this directly.
 407
 408 =cut
 409
 410 sub read { shift->{_context}->read(@_); }
 411
 412 =head2 $req->referer
 413
 414 Shortcut for $req->headers->referer. Returns the referring page.
 415
 416 =head2 $req->secure
 417
 418 Returns true or false, indicating whether the connection is secure (https).
 419
 420 =head2 $req->captures
 421
 422 Returns a reference to an array containing regex captures.
 423
 424     my @captures = @{ $c->request->captures };
 425
 426 =head2 $req->snippets
 427
 428 C<captures> used to be called snippets. This is still available for backwoards
 429 compatibility, but is considered deprecated.
 430
 431 =head2 $req->upload
 432
 433 A convenient method to access $req->uploads.
 434
 435     $upload  = $c->request->upload('field');
 436     @uploads = $c->request->upload('field');
 437     @fields  = $c->request->upload;
 438
 439     for my $upload ( $c->request->upload('field') ) {
 440         print $upload->filename;
 441     }
 442
 443 =cut
 444
 445 sub upload {
 446     my $self = shift;
 447
 448     if ( @_ == 0 ) {
 449         return keys %{ $self->uploads };
 450     }
 451
 452     if ( @_ == 1 ) {
 453
 454         my $upload = shift;
 455
 456         unless ( exists $self->uploads->{$upload} ) {
 457             return wantarray ? () : undef;
 458         }
 459
 460         if ( ref $self->uploads->{$upload} eq 'ARRAY' ) {
 461             return (wantarray)
 462               ? @{ $self->uploads->{$upload} }
 463               : $self->uploads->{$upload}->[0];
 464         }
 465         else {
 466             return (wantarray)
 467               ? ( $self->uploads->{$upload} )
 468               : $self->uploads->{$upload};
 469         }
 470     }
 471
 472     if ( @_ > 1 ) {
 473
 474         while ( my ( $field, $upload ) = splice( @_, 0, 2 ) ) {
 475
 476             if ( exists $self->uploads->{$field} ) {
 477                 for ( $self->uploads->{$field} ) {
 478                     $_ = [$_] unless ref($_) eq "ARRAY";
 479                     push( @$_, $upload );
 480                 }
 481             }
 482             else {
 483                 $self->uploads->{$field} = $upload;
 484             }
 485         }
 486     }
 487 }
 488
 489 =head2 $req->uploads
 490
 491 Returns a reference to a hash containing uploads. Values can be either a
 492 L<Catalyst::Request::Upload> object, or an arrayref of
 493 L<Catalyst::Request::Upload> objects.
 494
 495     my $upload = $c->request->uploads->{field};
 496     my $upload = $c->request->uploads->{field}->[0];
 497
 498 =cut
 499
 500 sub uploads {
 501     my ( $self, $uploads ) = @_;
 502     $self->{_context}->prepare_body;
 503     $self->{uploads} = $uploads if $uploads;
 504     return $self->{uploads};
 505 }
 506
 507 =head2 $req->uri
 508
 509 Returns a URI object for the current request. Stringifies to the URI text.
 510
 511 =head2 $req->uri_with( { key => 'value' } );
 512
 513 Returns a rewritten URI object for the current request. Key/value pairs
 514 passed in will override existing parameters. Unmodified pairs will be
 515 preserved.
 516
 517 =cut
 518
 519 sub uri_with {
 520     my( $self, $args ) = @_;
 521
 522     carp( 'No arguments passed to uri_with()' ) unless $args;
 523
 524     for my $value ( values %$args ) {
 525         next unless defined $value;
 526         for ( ref $value eq 'ARRAY' ? @$value : $value ) {
 527             $_ = "$_";
 528             utf8::encode( $_ );
 529         }
 530     };
 531
 532     my $uri = $self->uri->clone;
 533
 534     $uri->query_form( {
 535         %{ $uri->query_form_hash },
 536         %$args
 537     } );
 538     return $uri;
 539 }
 540
 541 =head2 $req->user
 542
 543 Returns the currently logged in user. Deprecated. The method recommended for
 544 newer plugins is $c->user.
 545
 546 =head2 $req->user_agent
 547
 548 Shortcut to $req->headers->user_agent. Returns the user agent (browser)
 549 version string.
 550
 551 =head1 AUTHORS
 552
 553 Sebastian Riedel, C<sri@cpan.org>
 554
 555 Marcus Ramberg, C<mramberg@cpan.org>
 556
 557 =head1 COPYRIGHT
 558
 559 This program is free software, you can redistribute it and/or modify
 560 it under the same terms as Perl itself.
 561
 562 =cut
 563
 564 1;