added recipe for content disposition from dwc
[catagits/Catalyst-Runtime.git] / lib / Catalyst / Manual / Cookbook.pod
1 =head1 NAME
2
3 Catalyst::Manual::Cookbook - Cooking with Catalyst
4
5 =head1 DESCRIPTION
6
7 Yummy code like your mum used to bake!
8
9 =head1 RECIPES
10
11 =head1 Basics
12
13 These recipes cover some basic stuff that is worth knowing for catalyst developers.
14
15 =head2 Delivering a Custom Error Page
16
17 By default, Catalyst will display its own error page whenever it
18 encounters an error in your application. When running under C<-Debug>
19 mode, the error page is a useful screen including the error message and
20 L<Data::Dump> output of the relevant parts of the C<$c> context object. 
21 When not in C<-Debug>, users see a simple "Please come back later" screen.
22
23 To use a custom error page, use a special C<end> method to short-circuit
24 the error processing. The following is an example; you might want to
25 adjust it further depending on the needs of your application (for
26 example, any calls to C<fillform> will probably need to go into this
27 C<end> method; see L<Catalyst::Plugin::FillInForm>).
28
29     sub end : Private {
30         my ( $self, $c ) = @_;
31
32         if ( scalar @{ $c->error } ) {
33             $c->stash->{errors}   = $c->error;
34             $c->stash->{template} = 'errors.tt';
35             $c->forward('MyApp::View::TT');
36             $c->error(0);
37         }
38
39         return 1 if $c->response->status =~ /^3\d\d$/;
40         return 1 if $c->response->body;
41
42         unless ( $c->response->content_type ) {
43             $c->response->content_type('text/html; charset=utf-8');
44         }
45
46         $c->forward('MyApp::View::TT');
47     }
48
49 You can manually set errors in your code to trigger this page by calling
50
51     $c->error( 'You broke me!' );
52
53 =head2 Disable statistics
54
55 Just add this line to your application class if you don't want those nifty
56 statistics in your debug messages.
57
58     sub Catalyst::Log::info { }
59
60 =head2 Enable debug status in the environment
61
62 Normally you enable the debugging info by adding the C<-Debug> flag to
63 your C<use Catalyst> statement. However, you can also enable it using
64 environment variable, so you can (for example) get debug info without
65 modifying your application scripts. Just set C<CATALYST_DEBUG> or
66 C<E<lt>MYAPPE<gt>_DEBUG> to a true value.
67
68 =head2 Sessions
69
70 When you have your users identified, you will want to somehow remember that
71 fact, to save them from having to identify themselves for every single
72 page. One way to do this is to send the username and password parameters in
73 every single page, but that's ugly, and won't work for static pages. 
74
75 Sessions are a method of saving data related to some transaction, and giving
76 the whole collection a single ID. This ID is then given to the user to return
77 to us on every page they visit while logged in. The usual way to do this is
78 using a browser cookie.
79
80 Catalyst uses two types of plugins to represent sessions:
81
82 =head3 State
83
84 A State module is used to keep track of the state of the session between the
85 users browser, and your application.  
86
87 A common example is the Cookie state module, which sends the browser a cookie
88 containing the session ID. It will use default value for the cookie name and
89 domain, so will "just work" when used. 
90
91 =head3 Store
92
93 A Store module is used to hold all the data relating to your session, for
94 example the users ID, or the items for their shopping cart. You can store data
95 in memory (FastMmap), in a file (File) or in a database (DBI).
96
97 =head3 Authentication magic
98
99 If you have included the session modules in your application, the
100 Authentication modules will automagically use your session to save and
101 retrieve the user data for you.
102
103 =head3 Using a session
104
105 Once the session modules are loaded, the session is available as C<<
106 $c->session >>, and can be writen to and read from as a simple hash reference.
107
108 =head3 EXAMPLE
109
110   use Catalyst qw/
111                  Session
112                  Session::Store::FastMmap
113                  Session::State::Cookie
114                  /;
115
116
117   ## Write data into the session
118
119   sub add_item : Local {
120      my ( $self, $c ) = @_;
121
122      my $item_id = $c->req->param("item");
123
124      push @{ $c->session->{items} }, $item_id;
125
126   }
127
128   ## A page later we retrieve the data from the session:
129
130   sub get_items : Local {
131      my ( $self, $c ) = @_;
132
133      $c->stash->{items_to_display} = $c->session->{items};
134
135   }
136
137
138 =head3 More information
139
140 L<http://search.cpan.org/dist/Catalyst-Plugin-Session>
141
142 L<http://search.cpan.org/dist/Catalyst-Plugin-Session-State-Cookie>
143
144 L<http://search.cpan.org/dist/Catalyst-Plugin-Session-State-URI>
145
146 L<http://search.cpan.org/dist/Catalyst-Plugin-Session-Store-FastMmap>
147
148 L<http://search.cpan.org/dist/Catalyst-Plugin-Session-Store-File>
149
150 L<http://search.cpan.org/dist/Catalyst-Plugin-Session-Store-DBI>
151
152 =head2 Configure your application
153
154 You configure your application with the C<config> method in your
155 application class. This can be hard-coded, or brought in from a
156 separate configuration file.
157
158 =head3 Using YAML
159
160 YAML is a method for creating flexible and readable configuration
161 files. It's a great way to keep your Catalyst application configuration
162 in one easy-to-understand location.
163
164 In your application class (e.g. C<lib/MyApp.pm>):
165
166   use YAML;
167   # application setup
168   __PACKAGE__->config( YAML::LoadFile(__PACKAGE__->config->{'home'} . '/myapp.yml') );
169   __PACKAGE__->setup;
170
171 Now create C<myapp.yml> in your application home:
172
173   --- #YAML:1.0
174   # DO NOT USE TABS FOR INDENTATION OR label/value SEPARATION!!!
175   name:     MyApp
176
177   # session; perldoc Catalyst::Plugin::Session::FastMmap
178   session:
179     expires:        '3600'
180     rewrite:        '0'
181     storage:        '/tmp/myapp.session'
182
183   # emails; perldoc Catalyst::Plugin::Email
184   # this passes options as an array :(
185   email:
186     - SMTP
187     - localhost
188
189 This is equivalent to:
190
191   # configure base package
192   __PACKAGE__->config( name => MyApp );
193   # configure authentication
194   __PACKAGE__->config->{authentication} = {
195     user_class => 'MyApp::Model::MyDB::Customer',
196     ...
197   };
198   # configure sessions
199   __PACKAGE__->config->{session} = {
200     expires => 3600,
201     ...
202   };
203   # configure email sending
204   __PACKAGE__->config->{email} = [qw/SMTP localhost/];
205
206 See also L<YAML>.
207
208 =head1 Users and Access Control
209
210 Most multiuser, and some single user web applications require that
211 users identify themselves, and the application is often required to
212 define those roles.  The recipes below describe some ways of doing
213 this.
214
215 =head2 Authentication (logging in)
216
217 This is extensively covered in other documentation; see in particular
218 L<Catalyst::Plugin::Authentication> and the Authentication chapter
219 of the Tutorial at L<Catalyst::Manual::Tutorial::Authorization>.
220
221 =head2 Pass-through login (and other actions)
222
223 An easy way of having assorted actions that occur during the processing
224 of a request that are orthogonal to its actual purpose - logins, silent
225 commands etc. Provide actions for these, but when they're required for
226 something else fill e.g. a form variable __login and have a sub begin
227 like so:
228
229     sub begin : Private {
230       my ($self, $c) = @_;
231       foreach my $action (qw/login docommand foo bar whatever/) {
232         if ($c->req->params->{"__${action}"}) {
233           $c->forward($action);
234         }
235       }
236     }
237
238
239 =head2 Role-based Authorization
240
241 For more advanced access control, you may want to consider using role-based
242 authorization. This means you can assign different roles to each user, e.g.
243 "user", "admin", etc.
244
245 The C<login> and C<logout> methods and view template are exactly the same as
246 in the previous example.
247
248 The L<Catalyst::Plugin::Authorization::Roles> plugin is required when
249 implementing roles:
250
251  use Catalyst qw/
252     Authentication
253     Authentication::Credential::Password
254     Authentication::Store::Htpasswd
255     Authorization::Roles
256   /;
257
258 Roles are implemented automatically when using
259 L<Catalyst::Authentication::Store::Htpasswd>:
260
261   # no additional role configuration required
262   __PACKAGE__->config->{authentication}{htpasswd} = "passwdfile";
263
264 Or can be set up manually when using L<Catalyst::Authentication::Store::DBIC>:
265
266   # Authorization using a many-to-many role relationship
267   __PACKAGE__->config->{authorization}{dbic} = {
268     'role_class'           => 'My::Model::DBIC::Role',
269     'role_field'           => 'name',
270     'user_role_user_field' => 'user',
271
272     # DBIx::Class only (omit if using Class::DBI)
273     'role_rel'             => 'user_role',
274
275     # Class::DBI only, (omit if using DBIx::Class)
276     'user_role_class'      => 'My::Model::CDBI::UserRole'
277     'user_role_role_field' => 'role',
278   };
279
280 To restrict access to any action, you can use the C<check_user_roles> method:
281
282   sub restricted : Local {
283      my ( $self, $c ) = @_;
284
285      $c->detach("unauthorized")
286        unless $c->check_user_roles( "admin" );
287
288      # do something restricted here
289   }
290
291 You can also use the C<assert_user_roles> method. This just gives an error if
292 the current user does not have one of the required roles:
293
294   sub also_restricted : Global {
295     my ( $self, $c ) = @_;
296     $c->assert_user_roles( qw/ user admin / );
297   }
298   
299 =head2 Authentication/Authorization
300
301 This is done in several steps:
302
303 =over 4
304
305 =item Verification
306
307 Getting the user to identify themselves, by giving you some piece of
308 information known only to you and the user. Then you can assume that the user
309 is who they say they are. This is called B<credential verification>.
310
311 =item Authorization
312
313 Making sure the user only accesses functions you want them to access. This is
314 done by checking the verified users data against your internal list of groups,
315 or allowed persons for the current page.
316
317 =back
318
319 =head3 Modules
320
321 The Catalyst Authentication system is made up of many interacting modules, to
322 give you the most flexibility possible.
323
324 =head4 Credential verifiers
325
326 A Credential module tables the user input, and passes it to a Store, or some
327 other system, for verification. Typically, a user object is created by either
328 this module or the Store and made accessible by a C<< $c->user >> call.
329
330 Examples:
331
332  Password - Simple username/password checking.
333  HTTPD    - Checks using basic HTTP auth.
334  TypeKey  - Check using the typekey system.
335
336 =head3 Storage backends
337
338 A Storage backend contains the actual data representing the users. It is
339 queried by the credential verifiers. Updating the store is not done within
340 this system, you will need to do it yourself.
341
342 Examples:
343
344  DBIC     - Storage using a database.
345  Minimal  - Storage using a simple hash (for testing).
346
347 =head3 User objects
348
349 A User object is created by either the storage backend or the credential
350 verifier, and filled with the retrieved user information.
351
352 Examples:
353
354  Hash     - A simple hash of keys and values.
355
356 =head3 ACL authorization
357
358 ACL stands for Access Control List. The ACL plugin allows you to regulate
359 access on a path by path basis, by listing which users, or roles, have access
360 to which paths.
361
362 =head3 Roles authorization
363
364 Authorization by roles is for assigning users to groups, which can then be
365 assigned to ACLs, or just checked when needed.
366
367 =head3 Logging in
368
369 When you have chosen your modules, all you need to do is call the C<<
370 $c->login >> method. If called with no parameters, it will try to find
371 suitable parameters, such as B<username> and B<password>, or you can pass it
372 these values.
373
374 =head3 Checking roles
375
376 Role checking is done by using the C<< $c->check_user_roles >> method, this will
377 check using the currently logged in user (via C<< $c->user >>). You pass it
378 the name of a role to check, and it returns true if the user is a member.
379
380 =head3 EXAMPLE
381
382  use Catalyst qw/Authentication
383                  Authentication::Credential::Password
384                  Authentication::Store::Htpasswd
385                  Authorization::Roles/;
386
387  __PACKAGE__->config->{authentication}{htpasswd} = "passwdfile";
388
389   sub login : Local {
390      my ($self, $c) = @_;
391
392      if (    my $user = $c->req->param("user")
393          and my $password = $c->req->param("password") )
394      {
395          if ( $c->login( $user, $password ) ) {
396               $c->res->body( "hello " . $c->user->name );
397          } else {
398             # login incorrect
399          }
400      }
401      else {
402          # invalid form input
403      }
404   }
405
406   sub restricted : Local {
407      my ( $self, $c ) = @_;
408
409      $c->detach("unauthorized")
410        unless $c->check_user_roles( "admin" );
411
412      # do something restricted here
413   }
414
415 =head3 Using authentication in a testing environment
416
417 Ideally, to write tests for authentication/authorization code one would first
418 set up a test database with known data, then use
419 L<Test::WWW::Mechanize::Catalyst> to simulate a user logging in. Unfortunately
420 the former can be rather awkward, which is why it's a good thing that the
421 authentication framework is so flexible.
422
423 Instead of using a test database, one can simply change the authentication
424 store to something a bit easier to deal with in a testing
425 environment. Additionally, this has the advantage of not modifying one's
426 database, which can be problematic if one forgets to use the testing instead of
427 production database.
428
429 e.g.,
430
431   use Catalyst::Plugin::Authentication::Store::Minimal::Backend;
432
433   # Sets up the user `test_user' with password `test_pass'
434   MyApp->default_auth_store(
435     Catalyst::Plugin::Authentication::Store::Minimal::Backend->new({
436       test_user => { password => 'test_pass' },
437     })
438   );
439
440 Now, your test code can call C<$c->login('test_user', 'test_pass')> and
441 successfully login, without messing with the database at all.
442
443 =head3 More information
444
445 L<http://search.cpan.org/perldoc?Catalyst::Plugin::Authentication> has a longer explanation.
446
447 =head2 Authorization
448
449 =head3 Introduction
450
451 Authorization is the step that comes after authentication. Authentication
452 establishes that the user agent is really representing the user we think it's
453 representing, and then authorization determines what this user is allowed to
454 do.
455
456 =head3 Role Based Access Control
457
458 Under role based access control each user is allowed to perform any number of
459 roles. For example, at a zoo no one but specially trained personnel can enter
460 the moose cage (Mynd you, møøse bites kan be pretty nasti!). For example: 
461
462     package Zoo::Controller::MooseCage;
463
464     sub feed_moose : Local {
465         my ( $self, $c ) = @_;
466
467         $c->model( "Moose" )->eat( $c->req->param("food") );
468     }
469
470 With this action, anyone can just come into the moose cage and feed the moose,
471 which is a very dangerous thing. We need to restrict this action, so that only
472 a qualified moose feeder can perform that action.
473
474 The Authorization::Roles plugin let's us perform role based access control
475 checks. Let's load it:
476
477     use Catalyst qw/
478         Authentication # yadda yadda
479         Authorization::Roles
480     /;
481
482 And now our action should look like this:
483
484     sub feed_moose : Local {
485         my ( $self, $c ) = @_;
486
487         if ( $c->check_roles( "moose_feeder" ) ) {
488             $c->model( "Moose" )->eat( $c->req->param("food") );
489         } else {
490             $c->stash->{error} = "unauthorized";
491         }
492     }
493
494 This checks C<< $c->user >>, and only if the user has B<all> the roles in the
495 list, a true value is returned.
496
497 C<check_roles> has a sister method, C<assert_roles>, which throws an exception
498 if any roles are missing.
499
500 Some roles that might actually make sense in, say, a forum application:
501
502 =over 4
503
504 =item *
505
506 administrator
507
508 =item *
509
510 moderator
511
512 =back
513
514 each with a distinct task (system administration versus content administration).
515
516 =head3 Access Control Lists
517
518 Checking for roles all the time can be tedious and error prone.
519
520 The Authorization::ACL plugin let's us declare where we'd like checks to be
521 done automatically for us.
522
523 For example, we may want to completely block out anyone who isn't a
524 C<moose_feeder> from the entire C<MooseCage> controller:
525
526     Zoo->deny_access_unless( "/moose_cage", [qw/moose_feeder/] );
527
528 The role list behaves in the same way as C<check_roles>. However, the ACL
529 plugin isn't limited to just interacting with the Roles plugin. We can use a
530 code reference instead. For example, to allow either moose trainers or moose
531 feeders into the moose cage, we can create a more complex check:
532
533     Zoo->deny_access_unless( "/moose_cage", sub {
534         my $c = shift;
535         $c->check_roles( "moose_trainer" ) || $c->check_roles( "moose_feeder" );
536     });
537
538 The more specific a role, the earlier it will be checked. Let's say moose
539 feeders are now restricted to only the C<feed_moose> action, while moose
540 trainers get access everywhere:
541
542     Zoo->deny_access_unless( "/moose_cage", [qw/moose_trainer/] );
543     Zoo->allow_access_if( "/moose_cage/feed_moose", [qw/moose_feeder/]);
544
545 When the C<feed_moose> action is accessed the second check will be made. If the
546 user is a C<moose_feeder>, then access will be immediately granted. Otherwise,
547 the next rule in line will be tested - the one checking for a C<moose_trainer>.
548 If this rule is not satisfied, access will be immediately denied.
549
550 Rules applied to the same path will be checked in the order they were added.
551
552 Lastly, handling access denial events is done by creating an C<access_denied>
553 private action:
554
555     sub access_denied : Private {
556         my ( $self, $c, $action ) = @_;
557
558         
559     }
560
561 This action works much like auto, in that it is inherited across namespaces
562 (not like object oriented code). This means that the C<access_denied> action
563 which is B<nearest> to the action which was blocked will be triggered.
564
565 If this action does not exist, an error will be thrown, which you can clean up
566 in your C<end> private action instead.
567
568 Also, it's important to note that if you restrict access to "/" then C<end>,
569 C<default>, etc will also be restricted.
570
571    MyApp->acl_allow_root_internals;
572
573 will create rules that permit access to C<end>, C<begin>, and C<auto> in the
574 root of your app (but not in any other controller).
575
576 =head1 Models
577
578 Models are where application data belongs.  Catalyst is exteremely
579 flexible with the kind of models that it can use.  The recipes here
580 are just the start.
581
582 =head2 Using existing DBIC (etc.) classes with Catalyst
583
584 Many people have existing Model classes that they would like to use with
585 Catalyst (or, conversely, they want to write Catalyst models that can be
586 used outside of Catalyst, e.g.  in a cron job). It's trivial to write a
587 simple component in Catalyst that slurps in an outside Model:
588
589     package MyApp::Model::DB;
590     use base qw/Catalyst::Model::DBIC::Schema/;
591     __PACKAGE__->config(
592         schema_class => 'Some::DBIC::Schema',
593         connect_info => ['dbi:SQLite:foo.db', '', '', {AutoCommit=>1}];
594     );
595     1;
596
597 and that's it! Now C<Some::DBIC::Schema> is part of your
598 Cat app as C<MyApp::Model::DB>.
599
600 =head2 DBIx::Class as a Catalyst Model
601
602 See L<Catalyst::Model::DBIC::Schema>.
603
604 =head2 XMLRPC
605
606 Unlike SOAP, XMLRPC is a very simple (and imo elegant) web-services
607 protocol, exchanging small XML messages like these:
608
609 Request:
610
611     POST /api HTTP/1.1
612     TE: deflate,gzip;q=0.3
613     Connection: TE, close
614     Accept: text/xml
615     Accept: multipart/*
616     Host: 127.0.0.1:3000
617     User-Agent: SOAP::Lite/Perl/0.60
618     Content-Length: 192
619     Content-Type: text/xml
620
621     <?xml version="1.0" encoding="UTF-8"?>
622     <methodCall>
623         <methodName>add</methodName>
624         <params>
625             <param><value><int>1</int></value></param>
626             <param><value><int>2</int></value></param>
627         </params>
628     </methodCall>
629
630 Response:
631
632     Connection: close
633     Date: Tue, 20 Dec 2005 07:45:55 GMT
634     Content-Length: 133
635     Content-Type: text/xml
636     Status: 200
637     X-Catalyst: 5.70
638
639     <?xml version="1.0" encoding="us-ascii"?>
640     <methodResponse>
641         <params>
642             <param><value><int>3</int></value></param>
643         </params>
644     </methodResponse>
645
646 Now follow these few steps to implement the application:
647
648 1. Install Catalyst (5.61 or later), Catalyst::Plugin::XMLRPC (0.06 or
649 later) and SOAP::Lite (for XMLRPCsh.pl).
650
651 2. Create an application framework:
652
653     % catalyst.pl MyApp
654     ...
655     % cd MyApp
656
657 3. Add the XMLRPC plugin to MyApp.pm
658
659     use Catalyst qw/-Debug Static::Simple XMLRPC/;
660
661 4. Add an API controller
662
663     % ./script/myapp_create.pl controller API
664
665 5. Add a XMLRPC redispatch method and an add method with Remote
666 attribute to lib/MyApp/Controller/API.pm
667
668     sub default : Private {
669         my ( $self, $c ) = @_;
670         $c->xmlrpc;
671     }
672
673     sub add : Remote {
674         my ( $self, $c, $a, $b ) = @_;
675         return $a + $b;
676     }
677
678 The default action is the entry point for each XMLRPC request. It will
679 redispatch every request to methods with Remote attribute in the same
680 class.
681
682 The C<add> method is not a traditional action; it has no private or
683 public path. Only the XMLRPC dispatcher knows it exists.
684
685 6. That's it! You have built your first web service. Let's test it with
686 XMLRPCsh.pl (part of SOAP::Lite):
687
688     % ./script/myapp_server.pl
689     ...
690     % XMLRPCsh.pl http://127.0.0.1:3000/api
691     Usage: method[(parameters)]
692     > add( 1, 2 )
693     --- XMLRPC RESULT ---
694     '3'
695
696 =head3 Tip
697
698 Your return data type is usually auto-detected, but you can easily
699 enforce a specific one.
700
701     sub add : Remote {
702         my ( $self, $c, $a, $b ) = @_;
703         return RPC::XML::int->new( $a + $b );
704     }
705     
706
707
708 =head1 Views
709
710 Views pertain to the display of your application.  As with models,
711 catalyst is uncommonly flexible.  The recipes below are just a start.
712
713 =head2 Catalyst::View::TT
714
715 One of the first things you probably want to do when starting a new
716 Catalyst application is set up your View. Catalyst doesn't care how you
717 display your data; you can choose to generate HTML, PDF files, or plain
718 text if you wanted.
719
720 Most Catalyst applications use a template system to generate their HTML,
721 and though there are several template systems available, Template
722 Toolkit is probably the most popular.
723
724 Once again, the Catalyst developers have done all the hard work, and
725 made things easy for the rest of us. Catalyst::View::TT provides the
726 interface to Template Toolkit, and provides Helpers which let us set it
727 up that much more easily.
728
729 =head3 Creating your View
730
731 Catalyst::View::TT provides two different helpers for us to use: TT and
732 TTSite.
733
734 =head4 TT
735
736 Create a basic Template Toolkit View using the provided helper script:
737
738     script/myapp_create.pl view TT TT
739
740 This will create lib/MyApp/View/MyView.pm, which is going to be pretty
741 empty to start. However, it sets everything up that you need to get
742 started. You can now define which template you want and forward to your
743 view. For instance:
744
745     sub hello : Local {
746         my ( $self, $c ) = @_;
747
748         $c->stash->{template} = 'hello.tt';
749
750         $c->forward( $c->view('TT') );
751     }
752
753 In practice you wouldn't do the forwarding manually, but would
754 use L<Catalyst::Action::RenderView>.
755
756 =head4 TTSite
757
758 Although the TT helper does create a functional, working view, you may
759 find yourself having to create the same template files and changing the
760 same options every time you create a new application. The TTSite helper
761 saves us even more time by creating the basic templates and setting some
762 common options for us.
763
764 Once again, you can use the helper script:
765
766     script/myapp_create.pl view TT TTSite
767
768 This time, the helper sets several options for us in the generated View.
769
770     __PACKAGE__->config({
771         CATALYST_VAR => 'Catalyst',
772         INCLUDE_PATH => [
773             MyApp->path_to( 'root', 'src' ),
774             MyApp->path_to( 'root', 'lib' )
775         ],
776         PRE_PROCESS  => 'config/main',
777         WRAPPER      => 'site/wrapper',
778         ERROR        => 'error.tt2',
779         TIMER        => 0
780     });
781
782 =over
783
784 =item 
785
786 INCLUDE_PATH defines the directories that Template Toolkit should search
787 for the template files.
788
789 =item
790
791 PRE_PROCESS is used to process configuration options which are common to
792 every template file.
793
794 =item
795
796 WRAPPER is a file which is processed with each template, usually used to
797 easily provide a common header and footer for every page.
798
799 =back
800
801 In addition to setting these options, the TTSite helper also created the
802 template and config files for us! In the 'root' directory, you'll notice
803 two new directories: src and lib.
804
805 Several configuration files in root/lib/config are called by PRE_PROCESS.
806
807 The files in root/lib/site are the site-wide templates, called by
808 WRAPPER, and display the html framework, control the layout, and provide
809 the templates for the header and footer of your page. Using the template
810 organization provided makes it much easier to standardize pages and make
811 changes when they are (inevitably) needed.
812
813 The template files that you will create for your application will go
814 into root/src, and you don't need to worry about putting the the <html>
815 or <head> sections; just put in the content. The WRAPPER will the rest
816 of the page around your template for you.
817
818
819 =head3 $c->stash
820
821 Of course, having the template system include the header and footer for
822 you isn't all that we want our templates to do. We need to be able to
823 put data into our templates, and have it appear where and how we want
824 it, right? That's where the stash comes in.
825
826 In our controllers, we can add data to the stash, and then access it
827 from the template. For instance:
828
829     sub hello : Local {
830         my ( $self, $c ) = @_;
831
832         $c->stash->{name} = 'Adam';
833
834         $c->stash->{template} = 'hello.tt';
835
836         $c->forward( $c->view('TT') );
837     }
838
839 Then, in hello.tt:
840
841     <strong>Hello, [% name %]!</strong>
842
843 When you view this page, it will display "Hello, Adam!"
844
845 All of the information in your stash is available, by its name/key, in
846 your templates. And your data don't have to be plain, old, boring
847 scalars. You can pass array references and hash references, too.
848
849 In your controller:
850
851     sub hello : Local {
852         my ( $self, $c ) = @_;
853
854         $c->stash->{names} = [ 'Adam', 'Dave', 'John' ];
855
856         $c->stash->{template} = 'hello.tt';
857
858         $c->forward( $c->view('TT') );
859     }
860
861 In hello.tt:
862
863     [% FOREACH name IN names %]
864         <strong>Hello, [% name %]!</strong><br />
865     [% END %]
866
867 This allowed us to loop through each item in the arrayref, and display a
868 line for each name that we have.
869
870 This is the most basic usage, but Template Toolkit is quite powerful,
871 and allows you to truly keep your presentation logic separate from the
872 rest of your application.
873
874 =head3 $c->uri_for()
875
876 One of my favorite things about Catalyst is the ability to move an
877 application around without having to worry that everything is going to
878 break. One of the areas that used to be a problem was with the http
879 links in your template files. For example, suppose you have an
880 application installed at http://www.domain.com/Calendar. The links point
881 to "/Calendar", "/Calendar/2005", "/Calendar/2005/10", etc.  If you move
882 the application to be at http://www.mydomain.com/Tools/Calendar, then
883 all of those links will suddenly break.
884
885 That's where $c->uri_for() comes in. This function will merge its
886 parameters with either the base location for the app, or its current
887 namespace. Let's take a look at a couple of examples.
888
889 In your template, you can use the following:
890
891     <a href="[% c.uri_for('/login') %]">Login Here</a>
892
893 Although the parameter starts with a forward slash, this is relative to the application root, not the webserver root. This is important to remember. So, if your application is installed at http://www.domain.com/Calendar, then the link would be http://www.mydomain.com/Calendar/Login. If you move your application to a different domain or path, then that link will still be correct.
894
895 Likewise,
896
897     <a href="[% c.uri_for('2005','10', '24') %]">October, 24 2005</a>
898
899 The first parameter does NOT have a forward slash, and so it will be relative to the current namespace. If the application is installed at http://www.domain.com/Calendar. and if the template is called from MyApp::Controller::Display, then the link would become http://www.domain.com/Calendar/Display/2005/10/24.
900
901 Once again, this allows you to move your application around without having to worry about broken links. But there's something else, as well. Since the links are generated by uri_for, you can use the same template file by several different controllers, and each controller will get the links that its supposed to. Since we believe in Don't Repeat Yourself, this is particularly helpful if you have common elements in your site that you want to keep in one file.
902
903 Further Reading:
904
905 L<http://search.cpan.org/perldoc?Catalyst>
906
907 L<http://search.cpan.org/perldoc?Catalyst%3A%3AView%3A%3ATT>
908
909 L<http://search.cpan.org/perldoc?Template>
910
911 =head2 Adding RSS feeds 
912
913 Adding RSS feeds to your Catalyst applications is simple. We'll see two
914 different aproaches here, but the basic premise is that you forward to
915 the normal view action first to get the objects, then handle the output
916 differently.
917
918 =head3 Using TT templates
919
920 This is the aproach used in Agave (L<http://dev.rawmode.org/>).
921
922     sub rss : Local {
923         my ($self,$c) = @_;
924         $c->forward('view');
925         $c->stash->{template}='rss.tt';
926     }
927
928 Then you need a template. Here's the one from Agave: 
929
930     <?xml version="1.0" encoding="UTF-8"?>
931     <rss version="2.0" xmlns:dc="http://purl.org/dc/elements/1.1/">
932       <channel>
933         <title>[ [% blog.name || c.config.name || "Agave" %] ] RSS Feed</title>
934         <link>[% base %]</link>
935         <description>Recent posts</description>
936         <language>en-us</language>
937         <ttl>40</ttl>
938      [% WHILE (post = posts.next) %]
939       <item>
940         <title>[% post.title %]</title>
941         <description>[% post.formatted_teaser|html%]</description>    
942         <pubDate>[% post.pub_date %]</pubDate>
943         <guid>[% post.full_uri %]</guid>
944         <link>[% post.full_uri %]</link>
945         <dc:creator>[% post.author.screenname %]</dc:creator>
946       </item>
947     [% END %]
948       </channel>
949     </rss> 
950
951 =head3 Using XML::Feed
952
953 A more robust solution is to use XML::Feed, as was done in the Catalyst
954 Advent Calendar. Assuming we have a C<view> action that populates
955 'entries' with some DBIx::Class iterator, the code would look something
956 like this:
957
958     sub rss : Local {
959         my ($self,$c) = @_;
960         $c->forward('view'); # get the entries
961
962         my $feed = XML::Feed->new('RSS');
963         $feed->title( $c->config->{name} . ' RSS Feed' );
964         $feed->link( $c->req->base ); # link to the site.
965         $feed->description('Catalyst advent calendar'); Some description
966
967         # Process the entries
968         while( my $entry = $c->stash->{entries}->next ) {
969             my $feed_entry = XML::Feed::Entry->new('RSS');
970             $feed_entry->title($entry->title);
971             $feed_entry->link( $c->uri_for($entry->link) );
972             $feed_entry->issued( DateTime->from_epoch(epoch => $entry->created) );
973             $feed->add_entry($feed_entry);
974         }
975         $c->res->body( $feed->as_xml );
976    }
977
978 A little more code in the controller, but with this approach you're
979 pretty sure to get something that validates. 
980
981 Note that for both of the above aproaches, you'll need to set the
982 content type like this:
983
984     $c->res->content_type('application/rss+xml');
985
986 =head3 Final words
987
988 You could generalize the second variant easily by replacing 'RSS' with a
989 variable, so you can generate Atom feeds with the same code.
990
991 Now, go ahead and make RSS feeds for all your stuff. The world *needs*
992 updates on your goldfish!
993
994 =head2 Forcing the browser to download content
995  
996 Sometimes you need your application to send content for download. For
997 example, you can generate a comma-separated values (CSV) file for your
998 users to download and import into their spreadsheet program.
999  
1000 Let's say you have an C<Orders> controller which generates a CSV file
1001 in the C<export> action (i.e., C<http://localhost:3000/orders/export>):
1002
1003     sub export : Local Args(0) {
1004         my ( $self, $c ) = @_;
1005
1006         # In a real application, you'd generate this from the database
1007         my $csv = "1,5.99\n2,29.99\n3,3.99\n";
1008
1009         $c->res->content_type('text/comma-separated-values');
1010         $c->res->body($csv);
1011     }
1012
1013 Normally the browser uses the last part of the URI to generate a
1014 filename for data it cannot display. In this case your browser would
1015 likely ask you to save a file named C<export>.
1016
1017 Luckily you can have the browser download the content with a specific
1018 filename by setting the C<Content-Disposition> header:
1019
1020     my $filename = 'Important Orders.csv';
1021     $c->res->header('Content-Disposition', qq[attachment; filename="$filename"]);
1022
1023 Note the use of quotes around the filename; this ensures that any
1024 spaces in the filename are handled by the browser.
1025
1026 Put this right before calling C<< $c->res->body >> and your browser
1027 will download a file named C<Important Orders.csv> instead of
1028 C<export>.
1029
1030 You can also use this to have the browser download content which it
1031 normally displays, such as JPEG images or even HTML. Just be sure to
1032 set the appropriate content type and disposition.
1033
1034
1035 =head1 Controllers
1036
1037 Controllers are the main point of communication between the web server
1038 and your application.  Here we explore some aspects of how they work.
1039
1040 =head2 Extending RenderView (formerly DefaultEnd)
1041
1042 The recommended approach for an C<end> action is to use
1043 L<Catalyst::Action::RenderView> (taking the place of
1044 L<Catalyst::Plugin::DefaultEnd>), which does what you usually need.
1045 However there are times when you need to add a bit to it, but don't want
1046 to write your own C<end> action.
1047
1048 You can extend it like this:
1049
1050 To add something to an C<end> action that is called before rendering
1051 (this is likely to be what you want), simply place it in the C<end>
1052 method:
1053
1054     sub end : ActionClass('RenderView') {
1055       my ( $self, $c ) = @_;
1056       # do stuff here; the RenderView action is called afterwards
1057     }
1058
1059 To add things to an C<end> action that are called I<after> rendering,
1060 you can set it up like this:
1061
1062     sub render : ActionClass('RenderView') { }
1063
1064     sub end : Private { 
1065       my ( $self, $c ) = @_;
1066       $c->forward('render');
1067       # do stuff here
1068     }
1069   
1070 =head2 Action Types
1071
1072 =head3 Introduction
1073
1074 A Catalyst application is driven by one or more Controller modules. There are
1075 a number of ways that Catalyst can decide which of the methods in your
1076 controller modules it should call. Controller methods are also called actions,
1077 because they determine how your catalyst application should (re-)act to any
1078 given URL. When the application is started up, catalyst looks at all your
1079 actions, and decides which URLs they map to.
1080
1081 =head3 Type attributes
1082
1083 Each action is a normal method in your controller, except that it has an
1084 L<attribute|http://search.cpan.org/~nwclark/perl-5.8.7/lib/attributes.pm>
1085 attached. These can be one of several types.
1086
1087 Assume our Controller module starts with the following package declaration:
1088
1089  package MyApp::Controller::Buckets;
1090
1091 and we are running our application on localhost, port 3000 (the test
1092 server default).
1093
1094 =over 4
1095
1096 =item Path
1097
1098 A Path attribute also takes an argument, this can be either a relative
1099 or an absolute path. A relative path will be relative to the controller
1100 namespace, an absolute path will represent an exact matching URL.
1101
1102  sub my_handles : Path('handles') { .. }
1103
1104 becomes
1105
1106  http://localhost:3000/buckets/handles
1107
1108 and
1109
1110  sub my_handles : Path('/handles') { .. }
1111
1112 becomes 
1113
1114  http://localhost:3000/handles
1115
1116 =item Local
1117
1118 When using a Local attribute, no parameters are needed, instead, the name of
1119 the action is matched in the URL. The namespaces created by the name of the
1120 controller package is always part of the URL.
1121
1122  sub my_handles : Local { .. }
1123
1124 becomes
1125
1126  http://localhost:3000/buckets/my_handles
1127
1128 =item Global
1129
1130 A Global attribute is similar to a Local attribute, except that the namespace
1131 of the controller is ignored, and matching starts at root.
1132
1133  sub my_handles : Global { .. }
1134
1135 becomes
1136
1137  http://localhost:3000/my_handles
1138
1139 =item Regex
1140
1141 By now you should have figured that a Regex attribute is just what it sounds
1142 like. This one takes a regular expression, and matches starting from
1143 root. These differ from the rest as they can match multiple URLs.
1144
1145  sub my_handles : Regex('^handles') { .. }
1146
1147 matches
1148
1149  http://localhost:3000/handles
1150
1151 and 
1152
1153  http://localhost:3000/handles_and_other_parts
1154
1155 etc.
1156
1157 =item LocalRegex
1158
1159 A LocalRegex is similar to a Regex, except it only matches below the current
1160 controller namespace.
1161
1162  sub my_handles : LocalRegex(^handles') { .. }
1163
1164 matches
1165
1166  http://localhost:3000/buckets/handles
1167
1168 and
1169
1170  http://localhost:3000/buckets/handles_and_other_parts
1171
1172 etc.
1173
1174 =item Private
1175
1176 Last but not least, there is the Private attribute, which allows you to create
1177 your own internal actions, which can be forwarded to, but won't be matched as
1178 URLs.
1179
1180  sub my_handles : Private { .. }
1181
1182 becomes nothing at all..
1183
1184 Catalyst also predefines some special Private actions, which you can override,
1185 these are:
1186
1187 =over 4
1188
1189 =item default
1190
1191 The default action will be called, if no other matching action is found. If
1192 you don't have one of these in your namespace, or any sub part of your
1193 namespace, you'll get an error page instead. If you want to find out where it
1194 was the user was trying to go, you can look in the request object using 
1195 C<< $c->req->path >>.
1196
1197  sub default : Private { .. }
1198
1199 works for all unknown URLs, in this controller namespace, or every one if put
1200 directly into MyApp.pm.
1201
1202 =item index 
1203
1204 The index action is called when someone tries to visit the exact namespace of
1205 your controller. If index, default and matching Path actions are defined, then
1206 index will be used instead of default and Path.
1207
1208  sub index : Private { .. }
1209
1210 becomes
1211
1212  http://localhost:3000/buckets
1213
1214 =item begin
1215
1216 The begin action is called at the beginning of every request involving this
1217 namespace directly, before other matching actions are called. It can be used
1218 to set up variables/data for this particular part of your app. A single begin
1219 action is called, its always the one most relevant to the current namespace.
1220
1221  sub begin : Private { .. }
1222
1223 is called once when 
1224
1225  http://localhost:3000/bucket/(anything)?
1226
1227 is visited.
1228
1229 =item end
1230
1231 Like begin, this action is always called for the namespace it is in, after
1232 every other action has finished. It is commonly used to forward processing to
1233 the View component. A single end action is called, its always the one most
1234 relevant to the current namespace. 
1235
1236
1237  sub end : Private { .. }
1238
1239 is called once after any actions when
1240
1241  http://localhost:3000/bucket/(anything)?
1242
1243 is visited.
1244
1245 =item auto
1246
1247 Lastly, the auto action is magic in that B<every> auto action in
1248 the chain of paths up to and including the ending namespace, will be
1249 called. (In contrast, only one of the begin/end/default actions will be
1250 called, the relevant one).
1251
1252  package MyApp.pm;
1253  sub auto : Private { .. }
1254
1255 and 
1256
1257  sub auto : Private { .. }
1258
1259 will both be called when visiting 
1260
1261  http://localhost:3000/bucket/(anything)?
1262
1263 =back
1264
1265 =back
1266
1267 =head3 A word of warning
1268
1269 Due to possible namespace conflicts with Plugins, it is advised to only put the
1270 pre-defined Private actions in your main MyApp.pm file, all others should go
1271 in a Controller module.
1272
1273 =head3 More Information
1274
1275 L<http://search.cpan.org/author/SRI/Catalyst-5.61/lib/Catalyst/Manual/Intro.pod>
1276
1277 L<http://dev.catalyst.perl.org/wiki/FlowChart>
1278
1279 =head2 Component-based Subrequests
1280
1281 See L<Catalyst::Plugin::SubRequest>.
1282
1283 =head2 File uploads
1284
1285 =head3 Single file upload with Catalyst
1286
1287 To implement uploads in Catalyst, you need to have a HTML form similar to
1288 this:
1289
1290     <form action="/upload" method="post" enctype="multipart/form-data">
1291       <input type="hidden" name="form_submit" value="yes">
1292       <input type="file" name="my_file">
1293       <input type="submit" value="Send">
1294     </form>
1295
1296 It's very important not to forget C<enctype="multipart/form-data"> in
1297 the form.
1298
1299 Catalyst Controller module 'upload' action:
1300
1301     sub upload : Global {
1302         my ($self, $c) = @_;
1303
1304         if ( $c->request->parameters->{form_submit} eq 'yes' ) {
1305
1306             if ( my $upload = $c->request->upload('my_file') ) {
1307
1308                 my $filename = $upload->filename;
1309                 my $target   = "/tmp/upload/$filename";
1310
1311                 unless ( $upload->link_to($target) || $upload->copy_to($target) ) {
1312                     die( "Failed to copy '$filename' to '$target': $!" );
1313                 }
1314             }
1315         }
1316
1317         $c->stash->{template} = 'file_upload.html';
1318     }
1319
1320 =head3 Multiple file upload with Catalyst
1321
1322 Code for uploading multiple files from one form needs a few changes:
1323
1324 The form should have this basic structure:
1325
1326     <form action="/upload" method="post" enctype="multipart/form-data">
1327       <input type="hidden" name="form_submit" value="yes">
1328       <input type="file" name="file1" size="50"><br>
1329       <input type="file" name="file2" size="50"><br>
1330       <input type="file" name="file3" size="50"><br>
1331       <input type="submit" value="Send">
1332     </form>
1333
1334 And in the controller:
1335
1336     sub upload : Local {
1337         my ($self, $c) = @_;
1338
1339         if ( $c->request->parameters->{form_submit} eq 'yes' ) {
1340
1341             for my $field ( $c->req->upload ) {
1342
1343                 my $upload   = $c->req->upload($field);
1344                 my $filename = $upload->filename;
1345                 my $target   = "/tmp/upload/$filename";
1346
1347                 unless ( $upload->link_to($target) || $upload->copy_to($target) ) {
1348                     die( "Failed to copy '$filename' to '$target': $!" );
1349                 }
1350             }
1351         }
1352
1353         $c->stash->{template} = 'file_upload.html';
1354     }
1355
1356 C<for my $field ($c-E<gt>req->upload)> loops automatically over all file
1357 input fields and gets input names. After that is basic file saving code,
1358 just like in single file upload.
1359
1360 Notice: C<die>ing might not be what you want to do, when an error
1361 occurs, but it works as an example. A better idea would be to store
1362 error C<$!> in $c->stash->{error} and show a custom error template
1363 displaying this message.
1364
1365 For more information about uploads and usable methods look at
1366 L<Catalyst::Request::Upload> and L<Catalyst::Request>.
1367
1368 =head2 Forwarding with arguments
1369
1370 Sometimes you want to pass along arguments when forwarding to another
1371 action. As of version 5.30, arguments can be passed in the call to
1372 C<forward>; in earlier versions, you can manually set the arguments in
1373 the Catalyst Request object:
1374
1375   # version 5.30 and later:
1376   $c->forward('/wherever', [qw/arg1 arg2 arg3/]);
1377
1378   # pre-5.30
1379   $c->req->args([qw/arg1 arg2 arg3/]);
1380   $c->forward('/wherever');
1381
1382 (See the L<Catalyst::Manual::Intro> Flow_Control section for more 
1383 information on passing arguments via C<forward>.)
1384
1385
1386 =head1 Deployment
1387
1388 The recipes below describe aspects of the deployment process,
1389 including web server engines and tips to improve application efficiency.
1390
1391 =head2 mod_perl Deployment
1392
1393 mod_perl is the best solution for many applications, but we'll list some pros
1394 and cons so you can decide for yourself.  The other production deployment
1395 option is FastCGI, for which see below.
1396
1397 =head3 Pros
1398
1399 =head4 Speed
1400
1401 mod_perl is very fast and your app will benefit from being loaded in memory
1402 within each Apache process.
1403
1404 =head4 Shared memory for multiple apps
1405
1406 If you need to run several Catalyst apps on the same server, mod_perl will
1407 share the memory for common modules.
1408
1409 =head3 Cons
1410
1411 =head4 Memory usage
1412
1413 Since your application is fully loaded in memory, every Apache process will
1414 be rather large.  This means a large Apache process will be tied up while
1415 serving static files, large files, or dealing with slow clients.  For this
1416 reason, it is best to run a two-tiered web architecture with a lightweight
1417 frontend server passing dynamic requests to a large backend mod_perl
1418 server.
1419
1420 =head4 Reloading
1421
1422 Any changes made to the core code of your app require a full Apache restart.
1423 Catalyst does not support Apache::Reload or StatINC.  This is another good
1424 reason to run a frontend web server where you can set up an
1425 C<ErrorDocument 502> page to report that your app is down for maintenance.
1426
1427 =head4 Cannot run multiple versions of the same app
1428
1429 It is not possible to run two different versions of the same application in
1430 the same Apache instance because the namespaces will collide.
1431
1432 =head4 Setup
1433
1434 Now that we have that out of the way, let's talk about setting up mod_perl
1435 to run a Catalyst app.
1436
1437 =head4 1. Install Catalyst::Engine::Apache
1438
1439 You should install the latest versions of both Catalyst and 
1440 Catalyst::Engine::Apache.  The Apache engines were separated from the
1441 Catalyst core in version 5.50 to allow for updates to the engine without
1442 requiring a new Catalyst release.
1443
1444 =head4 2. Install Apache with mod_perl
1445
1446 Both Apache 1.3 and Apache 2 are supported, although Apache 2 is highly
1447 recommended.  With Apache 2, make sure you are using the prefork MPM and not
1448 the worker MPM.  The reason for this is that many Perl modules are not
1449 thread-safe and may have problems running within the threaded worker
1450 environment.  Catalyst is thread-safe however, so if you know what you're
1451 doing, you may be able to run using worker.
1452
1453 In Debian, the following commands should get you going.
1454
1455     apt-get install apache2-mpm-prefork
1456     apt-get install libapache2-mod-perl2
1457
1458 =head4 3. Configure your application
1459
1460 Every Catalyst application will automagically become a mod_perl handler
1461 when run within mod_perl.  This makes the configuration extremely easy.
1462 Here is a basic Apache 2 configuration.
1463
1464     PerlSwitches -I/var/www/MyApp/lib
1465     PerlModule MyApp
1466     
1467     <Location />
1468         SetHandler          modperl
1469         PerlResponseHandler MyApp
1470     </Location>
1471
1472 The most important line here is C<PerlModule MyApp>.  This causes mod_perl
1473 to preload your entire application into shared memory, including all of your
1474 controller, model, and view classes and configuration.  If you have -Debug
1475 mode enabled, you will see the startup output scroll by when you first
1476 start Apache.
1477
1478 For an example Apache 1.3 configuration, please see the documentation for
1479 L<Catalyst::Engine::Apache::MP13>.
1480
1481 =head3 Test It
1482
1483 That's it, your app is now a full-fledged mod_perl application!  Try it out
1484 by going to http://your.server.com/.
1485
1486 =head3 Other Options
1487
1488 =head4 Non-root location
1489
1490 You may not always want to run your app at the root of your server or virtual
1491 host.  In this case, it's a simple change to run at any non-root location
1492 of your choice.
1493
1494     <Location /myapp>
1495         SetHandler          modperl
1496         PerlResponseHandler MyApp
1497     </Location>
1498     
1499 When running this way, it is best to make use of the C<uri_for> method in
1500 Catalyst for constructing correct links.
1501
1502 =head4 Static file handling
1503
1504 Static files can be served directly by Apache for a performance boost.
1505
1506     DocumentRoot /var/www/MyApp/root
1507     <Location /static>
1508         SetHandler default-handler
1509     </Location>
1510     
1511 This will let all files within root/static be handled directly by Apache.  In
1512 a two-tiered setup, the frontend server should handle static files.
1513 The configuration to do this on the frontend will vary.
1514
1515 =head2 Catalyst on shared hosting
1516
1517 So, you want to put your Catalyst app out there for the whole world to
1518 see, but you don't want to break the bank. There is an answer - if you
1519 can get shared hosting with FastCGI and a shell, you can install your
1520 Catalyst app in a local directory on your shared host. First, run
1521
1522     perl -MCPAN -e shell
1523
1524 and go through the standard CPAN configuration process. Then exit out
1525 without installing anything. Next, open your .bashrc and add
1526
1527     export PATH=$HOME/local/bin:$HOME/local/script:$PATH
1528     perlversion=`perl -v | grep 'built for' | awk '{print $4}' | sed -e 's/v//;'`
1529     export PERL5LIB=$HOME/local/share/perl/$perlversion:$HOME/local/lib/perl/$perlversion:$HOME/local/lib:$PERL5LIB
1530
1531 and log out, then back in again (or run C<". .bashrc"> if you
1532 prefer). Finally, edit C<.cpan/CPAN/MyConfig.pm> and add
1533
1534     'make_install_arg' => qq[SITEPREFIX=$ENV{HOME}/local],
1535     'makepl_arg' => qq[INSTALLDIRS=site install_base=$ENV{HOME}/local],
1536
1537 Now you can install the modules you need using CPAN as normal; they
1538 will be installed into your local directory, and perl will pick them
1539 up. Finally, change directory into the root of your virtual host and
1540 symlink your application's script directory in:
1541
1542     cd path/to/mydomain.com
1543     ln -s ~/lib/MyApp/script script
1544
1545 And add the following lines to your .htaccess file (assuming the server
1546 is setup to handle .pl as fcgi - you may need to rename the script to
1547 myapp_fastcgi.fcgi and/or use a SetHandler directive):
1548
1549   RewriteEngine On
1550   RewriteCond %{REQUEST_URI} !^/?script/myapp_fastcgi.pl
1551   RewriteRule ^(.*)$ script/myapp_fastcgi.pl/$1 [PT,L]
1552
1553 Now C<http://mydomain.com/> should now Just Work. Congratulations, now
1554 you can tell your friends about your new website (or in our case, tell
1555 the client it's time to pay the invoice :) )
1556
1557 =head2 FastCGI Deployment
1558
1559 FastCGI is a high-performance extension to CGI. It is suitable
1560 for production environments.
1561
1562 =head3 Pros
1563
1564 =head4 Speed
1565
1566 FastCGI performs equally as well as mod_perl.  Don't let the 'CGI' fool you;
1567 your app runs as multiple persistent processes ready to receive connections
1568 from the web server.
1569
1570 =head4 App Server
1571
1572 When using external FastCGI servers, your application runs as a standalone
1573 application server.  It may be restarted independently from the web server.
1574 This allows for a more robust environment and faster reload times when
1575 pushing new app changes.  The frontend server can even be configured to
1576 display a friendly "down for maintenance" page while the application is
1577 restarting.
1578
1579 =head4 Load-balancing
1580
1581 You can launch your application on multiple backend servers and allow the
1582 frontend web server to load-balance between all of them.  And of course, if
1583 one goes down, your app continues to run fine.
1584
1585 =head4 Multiple versions of the same app
1586
1587 Each FastCGI application is a separate process, so you can run different
1588 versions of the same app on a single server.
1589
1590 =head4 Can run with threaded Apache
1591
1592 Since your app is not running inside of Apache, the faster mpm_worker module
1593 can be used without worrying about the thread safety of your application.
1594
1595 =head3 Cons
1596
1597 =head4 More complex environment
1598
1599 With FastCGI, there are more things to monitor and more processes running
1600 than when using mod_perl.
1601
1602 =head3 Setup
1603
1604 =head4 1. Install Apache with mod_fastcgi
1605
1606 mod_fastcgi for Apache is a third party module, and can be found at
1607 L<http://www.fastcgi.com/>.  It is also packaged in many distributions,
1608 for example, libapache2-mod-fastcgi in Debian.
1609
1610 =head4 2. Configure your application
1611
1612     # Serve static content directly
1613     DocumentRoot  /var/www/MyApp/root
1614     Alias /static /var/www/MyApp/root/static
1615
1616     FastCgiServer /var/www/MyApp/script/myapp_fastcgi.pl -processes 3
1617     Alias /myapp/ /var/www/MyApp/script/myapp_fastcgi.pl/
1618     
1619     # Or, run at the root
1620     Alias / /var/www/MyApp/script/myapp_fastcgi.pl/
1621     
1622 The above commands will launch 3 app processes and make the app available at
1623 /myapp/
1624
1625 =head3 Standalone server mode
1626
1627 While not as easy as the previous method, running your app as an external
1628 server gives you much more flexibility.
1629
1630 First, launch your app as a standalone server listening on a socket.
1631
1632     script/myapp_fastcgi.pl -l /tmp/myapp.socket -n 5 -p /tmp/myapp.pid -d
1633     
1634 You can also listen on a TCP port if your web server is not on the same
1635 machine.
1636
1637     script/myapp_fastcgi.pl -l :8080 -n 5 -p /tmp/myapp.pid -d
1638     
1639 You will probably want to write an init script to handle starting/stopping
1640 of the app using the pid file.
1641
1642 Now, we simply configure Apache to connect to the running server.
1643
1644     # 502 is a Bad Gateway error, and will occur if the backend server is down
1645     # This allows us to display a friendly static page that says "down for
1646     # maintenance"
1647     Alias /_errors /var/www/MyApp/root/error-pages
1648     ErrorDocument 502 /_errors/502.html
1649
1650     FastCgiExternalServer /tmp/myapp -socket /tmp/myapp.socket
1651     Alias /myapp/ /tmp/myapp/
1652     
1653     # Or, run at the root
1654     Alias / /tmp/myapp/
1655     
1656 =head3 More Info
1657
1658 L<Catalyst::Engine::FastCGI>.
1659
1660 =head2 Quick deployment: Building PAR Packages
1661
1662 You have an application running on your development box, but then you
1663 have to quickly move it to another one for
1664 demonstration/deployment/testing...
1665
1666 PAR packages can save you from a lot of trouble here. They are usual Zip
1667 files that contain a blib tree; you can even include all prereqs and a
1668 perl interpreter by setting a few flags!
1669
1670 =head3 Follow these few points to try it out!
1671
1672 1. Install Catalyst and PAR 0.89 (or later)
1673
1674     % perl -MCPAN -e 'install Catalyst'
1675     ...
1676     % perl -MCPAN -e 'install PAR'
1677     ...
1678
1679 2. Create a application
1680
1681     % catalyst.pl MyApp
1682     ...
1683     % cd MyApp
1684
1685 Recent versions of Catalyst (5.62 and up) include
1686 L<Module::Install::Catalyst>, which simplifies the process greatly.  From the shell in your application directory:
1687
1688     % perl Makefile.PL
1689     % make catalyst_par
1690
1691 Congratulations! Your package "myapp.par" is ready, the following
1692 steps are just optional.
1693
1694 3. Test your PAR package with "parl" (no typo)
1695
1696     % parl myapp.par
1697     Usage:
1698         [parl] myapp[.par] [script] [arguments]
1699
1700       Examples:
1701         parl myapp.par myapp_server.pl -r
1702         myapp myapp_cgi.pl
1703
1704       Available scripts:
1705         myapp_cgi.pl
1706         myapp_create.pl
1707         myapp_fastcgi.pl
1708         myapp_server.pl
1709         myapp_test.pl
1710
1711     % parl myapp.par myapp_server.pl
1712     You can connect to your server at http://localhost:3000
1713
1714 Yes, this nifty little starter application gets automatically included.
1715 You can also use "catalyst_par_script('myapp_server.pl')" to set a
1716 default script to execute.
1717
1718 6. Want to create a binary that includes the Perl interpreter?
1719
1720     % pp -o myapp myapp.par
1721     % ./myapp myapp_server.pl
1722     You can connect to your server at http://localhost:3000
1723
1724 =head2 Serving static content
1725
1726 Serving static content in Catalyst used to be somewhat tricky; the use
1727 of L<Catalyst::Plugin::Static::Simple> makes everything much easier.
1728 This plugin will automatically serve your static content during development,
1729 but allows you to easily switch to Apache (or other server) in a
1730 production environment.
1731
1732 =head3 Introduction to Static::Simple
1733
1734 Static::Simple is a plugin that will help to serve static content for your
1735 application. By default, it will serve most types of files, excluding some
1736 standard Template Toolkit extensions, out of your B<root> file directory. All
1737 files are served by path, so if B<images/me.jpg> is requested, then
1738 B<root/images/me.jpg> is found and served.
1739
1740 =head3 Usage
1741
1742 Using the plugin is as simple as setting your use line in MyApp.pm to include:
1743
1744  use Catalyst qw/Static::Simple/;
1745
1746 and already files will be served.
1747
1748 =head3 Configuring
1749
1750 Static content is best served from a single directory within your root
1751 directory. Having many different directories such as C<root/css> and
1752 C<root/images> requires more code to manage, because you must separately
1753 identify each static directory--if you decide to add a C<root/js>
1754 directory, you'll need to change your code to account for it. In
1755 contrast, keeping all static directories as subdirectories of a main
1756 C<root/static> directory makes things much easier to manage. Here's an
1757 example of a typical root directory structure:
1758
1759     root/
1760     root/content.tt
1761     root/controller/stuff.tt
1762     root/header.tt
1763     root/static/
1764     root/static/css/main.css
1765     root/static/images/logo.jpg
1766     root/static/js/code.js
1767
1768
1769 All static content lives under C<root/static>, with everything else being
1770 Template Toolkit files.
1771
1772 =over 4
1773
1774 =item Include Path
1775
1776 You may of course want to change the default locations, and make
1777 Static::Simple look somewhere else, this is as easy as:
1778
1779  MyApp->config->{static}->{include_path} = [
1780   MyApp->config->{root},
1781   '/path/to/my/files' 
1782  ];
1783
1784 When you override include_path, it will not automatically append the
1785 normal root path, so you need to add it yourself if you still want
1786 it. These will be searched in order given, and the first matching file
1787 served.
1788
1789 =item Static directories
1790
1791 If you want to force some directories to be only static, you can set
1792 them using paths relative to the root dir, or regular expressions:
1793
1794  MyApp->config->{static}->{dirs} = [
1795    'static',
1796    qr/^(images|css)/,
1797  ];
1798
1799 =item File extensions
1800
1801 By default, the following extensions are not served (that is, they will
1802 be processed by Catalyst): B<tmpl, tt, tt2, html, xhtml>. This list can
1803 be replaced easily:
1804
1805  MyApp->config->{static}->{ignore_extensions} = [
1806     qw/tmpl tt tt2 html xhtml/ 
1807  ];
1808
1809 =item Ignoring directories
1810
1811 Entire directories can be ignored. If used with include_path,
1812 directories relative to the include_path dirs will also be ignored:
1813
1814  MyApp->config->{static}->{ignore_dirs} = [ qw/tmpl css/ ];
1815
1816 =back
1817
1818 =head3 More information
1819
1820 L<http://search.cpan.org/dist/Catalyst-Plugin-Static-Simple/>
1821
1822 =head3 Serving manually with the Static plugin with HTTP::Daemon (myapp_server.pl)
1823
1824 In some situations you might want to control things more directly,
1825 using L<Catalyst::Plugin::Static>.
1826
1827 In your main application class (MyApp.pm), load the plugin:
1828
1829     use Catalyst qw/-Debug FormValidator Static OtherPlugin/;
1830
1831 You will also need to make sure your end method does I<not> forward
1832 static content to the view, perhaps like this:
1833
1834     sub end : Private {
1835         my ( $self, $c ) = @_;
1836
1837         $c->forward( 'MyApp::View::TT' ) 
1838           unless ( $c->res->body || !$c->stash->{template} );
1839     }
1840
1841 This code will only forward to the view if a template has been
1842 previously defined by a controller and if there is not already data in
1843 C<$c-E<gt>res-E<gt>body>.
1844
1845 Next, create a controller to handle requests for the /static path. Use
1846 the Helper to save time. This command will create a stub controller as
1847 C<lib/MyApp/Controller/Static.pm>.
1848
1849     $ script/myapp_create.pl controller Static
1850
1851 Edit the file and add the following methods:
1852
1853     # serve all files under /static as static files
1854     sub default : Path('/static') {
1855         my ( $self, $c ) = @_;
1856
1857         # Optional, allow the browser to cache the content
1858         $c->res->headers->header( 'Cache-Control' => 'max-age=86400' );
1859
1860         $c->serve_static; # from Catalyst::Plugin::Static
1861     }
1862
1863     # also handle requests for /favicon.ico
1864     sub favicon : Path('/favicon.ico') {
1865         my ( $self, $c ) = @_;
1866
1867         $c->serve_static;
1868     }
1869
1870 You can also define a different icon for the browser to use instead of
1871 favicon.ico by using this in your HTML header:
1872
1873     <link rel="icon" href="/static/myapp.ico" type="image/x-icon" />
1874
1875 =head3 Common problems with the Static plugin
1876
1877 The Static plugin makes use of the C<shared-mime-info> package to
1878 automatically determine MIME types. This package is notoriously
1879 difficult to install, especially on win32 and OS X. For OS X the easiest
1880 path might be to install Fink, then use C<apt-get install
1881 shared-mime-info>. Restart the server, and everything should be fine.
1882
1883 Make sure you are using the latest version (>= 0.16) for best
1884 results. If you are having errors serving CSS files, or if they get
1885 served as text/plain instead of text/css, you may have an outdated
1886 shared-mime-info version. You may also wish to simply use the following
1887 code in your Static controller:
1888
1889     if ($c->req->path =~ /css$/i) {
1890         $c->serve_static( "text/css" );
1891     } else {
1892         $c->serve_static;
1893     }
1894
1895 =head3 Serving Static Files with Apache
1896
1897 When using Apache, you can bypass Catalyst and any Static
1898 plugins/controllers controller by intercepting requests for the
1899 C<root/static> path at the server level. All that is required is to
1900 define a DocumentRoot and add a separate Location block for your static
1901 content. Here is a complete config for this application under mod_perl
1902 1.x:
1903
1904     <Perl>
1905         use lib qw(/var/www/MyApp/lib);
1906     </Perl>
1907     PerlModule MyApp
1908
1909     <VirtualHost *>
1910         ServerName myapp.example.com
1911         DocumentRoot /var/www/MyApp/root
1912         <Location />
1913             SetHandler perl-script
1914             PerlHandler MyApp
1915         </Location>
1916         <LocationMatch "/(static|favicon.ico)">
1917             SetHandler default-handler
1918         </LocationMatch>
1919     </VirtualHost>
1920
1921 And here's a simpler example that'll get you started:
1922
1923     Alias /static/ "/my/static/files/"
1924     <Location "/static">
1925         SetHandler none
1926     </Location>
1927
1928 =head2 Caching
1929
1930 Catalyst makes it easy to employ several different types of caching to
1931 speed up your applications.
1932
1933 =head3 Cache Plugins
1934
1935 There are three wrapper plugins around common CPAN cache modules:
1936 Cache::FastMmap, Cache::FileCache, and Cache::Memcached.  These can be
1937 used to cache the result of slow operations.
1938
1939 This very page you're viewing makes use of the FileCache plugin to cache the
1940 rendered XHTML version of the source POD document.  This is an ideal
1941 application for a cache because the source document changes infrequently but
1942 may be viewed many times.
1943
1944     use Catalyst qw/Cache::FileCache/;
1945     
1946     ...
1947     
1948     use File::stat;
1949     sub render_pod : Local {
1950         my ( self, $c ) = @_;
1951         
1952         # the cache is keyed on the filename and the modification time
1953         # to check for updates to the file.
1954         my $file  = $c->path_to( 'root', '2005', '11.pod' );
1955         my $mtime = ( stat $file )->mtime;
1956         
1957         my $cached_pod = $c->cache->get("$file $mtime");
1958         if ( !$cached_pod ) {
1959             $cached_pod = do_slow_pod_rendering();
1960             # cache the result for 12 hours
1961             $c->cache->set( "$file $mtime", $cached_pod, '12h' );
1962         }
1963         $c->stash->{pod} = $cached_pod;
1964     }
1965     
1966 We could actually cache the result forever, but using a value such as 12 hours
1967 allows old entries to be automatically expired when they are no longer needed.
1968
1969 =head3 Page Caching
1970
1971 Another method of caching is to cache the entire HTML page.  While this is
1972 traditionally handled by a front-end proxy server like Squid, the Catalyst
1973 PageCache plugin makes it trivial to cache the entire output from
1974 frequently-used or slow actions.
1975
1976 Many sites have a busy content-filled front page that might look something
1977 like this.  It probably takes a while to process, and will do the exact same
1978 thing for every single user who views the page.
1979
1980     sub front_page : Path('/') {
1981         my ( $self, $c ) = @_;
1982         
1983         $c->forward( 'get_news_articles' );
1984         $c->forward( 'build_lots_of_boxes' );
1985         $c->forward( 'more_slow_stuff' );
1986         
1987         $c->stash->{template} = 'index.tt';
1988     }
1989
1990 We can add the PageCache plugin to speed things up.
1991
1992     use Catalyst qw/Cache::FileCache PageCache/;
1993     
1994     sub front_page : Path ('/') {
1995         my ( $self, $c ) = @_;
1996         
1997         $c->cache_page( 300 );
1998         
1999         # same processing as above
2000     }
2001     
2002 Now the entire output of the front page, from <html> to </html>, will be
2003 cached for 5 minutes.  After 5 minutes, the next request will rebuild the
2004 page and it will be re-cached.
2005
2006 Note that the page cache is keyed on the page URI plus all parameters, so
2007 requests for / and /?foo=bar will result in different cache items.  Also,
2008 only GET requests will be cached by the plugin.
2009
2010 You can even get that front-end Squid proxy to help out by enabling HTTP
2011 headers for the cached page.
2012
2013     MyApp->config->{page_cache}->{set_http_headers} = 1;
2014     
2015 This would now set the following headers so proxies and browsers may cache
2016 the content themselves.
2017
2018     Cache-Control: max-age=($expire_time - time)
2019     Expires: $expire_time
2020     Last-Modified: $cache_created_time
2021     
2022 =head3 Template Caching
2023
2024 Template Toolkit provides support for caching compiled versions of your
2025 templates.  To enable this in Catalyst, use the following configuration.
2026 TT will cache compiled templates keyed on the file mtime, so changes will
2027 still be automatically detected.
2028
2029     package MyApp::View::TT;
2030     
2031     use strict;
2032     use warnings;
2033     use base 'Catalyst::View::TT';
2034     
2035     __PACKAGE__->config(
2036         COMPILE_DIR => '/tmp/template_cache',
2037     );
2038     
2039     1;
2040     
2041 =head3 More Info
2042
2043 See the documentation for each cache plugin for more details and other
2044 available configuration options.
2045
2046 L<Catalyst::Plugin::Cache::FastMmap>
2047 L<Catalyst::Plugin::Cache::FileCache>
2048 L<Catalyst::Plugin::Cache::Memcached>
2049 L<Catalyst::Plugin::PageCache>
2050 L<http://search.cpan.org/dist/Template-Toolkit/lib/Template/Manual/Config.pod#Caching_and_Compiling_Options>
2051
2052 =head1 Testing
2053
2054 Testing is an integral part of the web application development
2055 process.  Tests make multi developer teams easier to coordinate, and
2056 they help ensure that there are no nasty surprises after upgrades or
2057 alterations.
2058
2059 =head2 Testing
2060
2061 Catalyst provides a convenient way of testing your application during 
2062 development and before deployment in a real environment.
2063
2064 C<Catalyst::Test> makes it possible to run the same tests both locally 
2065 (without an external daemon) and against a remote server via HTTP.
2066
2067 =head3 Tests
2068
2069 Let's examine a skeleton application's C<t/> directory:
2070
2071     mundus:~/MyApp chansen$ ls -l t/
2072     total 24
2073     -rw-r--r--  1 chansen  chansen   95 18 Dec 20:50 01app.t
2074     -rw-r--r--  1 chansen  chansen  190 18 Dec 20:50 02pod.t
2075     -rw-r--r--  1 chansen  chansen  213 18 Dec 20:50 03podcoverage.t
2076
2077 =over 4
2078
2079 =item C<01app.t>
2080
2081 Verifies that the application loads, compiles, and returns a successful
2082 response.
2083
2084 =item C<02pod.t>
2085
2086 Verifies that all POD is free from errors. Only executed if the C<TEST_POD> 
2087 environment variable is true.
2088
2089 =item C<03podcoverage.t>
2090
2091 Verifies that all methods/functions have POD coverage. Only executed if the
2092 C<TEST_POD> environment variable is true.
2093
2094 =back
2095
2096 =head3 Creating tests
2097
2098     mundus:~/MyApp chansen$ cat t/01app.t | perl -ne 'printf( "%2d  %s", $., $_ )'
2099     1  use Test::More tests => 2;
2100     2  use_ok( Catalyst::Test, 'MyApp' );
2101     3
2102     4  ok( request('/')->is_success );
2103
2104 The first line declares how many tests we are going to run, in this case
2105 two. The second line tests and loads our application in test mode. The
2106 fourth line verifies that our application returns a successful response.
2107
2108 C<Catalyst::Test> exports two functions, C<request> and C<get>. Each can
2109 take three different arguments:
2110
2111 =over 4
2112
2113 =item A string which is a relative or absolute URI.
2114
2115     request('/my/path');
2116     request('http://www.host.com/my/path');
2117
2118 =item An instance of C<URI>.
2119
2120     request( URI->new('http://www.host.com/my/path') );
2121
2122 =item An instance of C<HTTP::Request>.
2123
2124     request( HTTP::Request->new( GET => 'http://www.host.com/my/path') );
2125
2126 =back
2127
2128 C<request> returns an instance of C<HTTP::Response> and C<get> returns the 
2129 content (body) of the response.
2130
2131 =head3 Running tests locally
2132
2133     mundus:~/MyApp chansen$ CATALYST_DEBUG=0 TEST_POD=1 prove --lib lib/ t/
2134     t/01app............ok                                                        
2135     t/02pod............ok                                                        
2136     t/03podcoverage....ok                                                        
2137     All tests successful.
2138     Files=3, Tests=4,  2 wallclock secs ( 1.60 cusr +  0.36 csys =  1.96 CPU)
2139  
2140 C<CATALYST_DEBUG=0> ensures that debugging is off; if it's enabled you
2141 will see debug logs between tests.
2142
2143 C<TEST_POD=1> enables POD checking and coverage.
2144
2145 C<prove> A command-line tool that makes it easy to run tests. You can
2146 find out more about it from the links below.
2147
2148 =head3 Running tests remotely
2149
2150     mundus:~/MyApp chansen$ CATALYST_SERVER=http://localhost:3000/ prove --lib lib/ t/01app.t
2151     t/01app....ok                                                                
2152     All tests successful.
2153     Files=1, Tests=2,  0 wallclock secs ( 0.40 cusr +  0.01 csys =  0.41 CPU)
2154
2155 C<CATALYST_SERVER=http://localhost:3000/> is the absolute deployment URI of 
2156 your application. In C<CGI> or C<FastCGI> it should be the host and path 
2157 to the script.
2158
2159 =head3 C<Test::WWW::Mechanize> and Catalyst
2160
2161 Be sure to check out C<Test::WWW::Mechanize::Catalyst>. It makes it easy to
2162 test HTML, forms and links. A short example of usage:
2163
2164     use Test::More tests => 6;
2165     use_ok( Test::WWW::Mechanize::Catalyst, 'MyApp' );
2166
2167     my $mech = Test::WWW::Mechanize::Catalyst->new;
2168     $mech->get_ok("http://localhost/", 'Got index page');
2169     $mech->title_like( qr/^MyApp on Catalyst/, 'Got right index title' );
2170     ok( $mech->find_link( text_regex => qr/^Wiki/i ), 'Found link to Wiki' );
2171     ok( $mech->find_link( text_regex => qr/^Mailing-List/i ), 'Found link to Mailing-List' );
2172     ok( $mech->find_link( text_regex => qr/^IRC channel/i ), 'Found link to IRC channel' );
2173
2174 =head3 Further Reading
2175
2176 =over 4
2177
2178 =item Catalyst::Test
2179
2180 L<http://search.cpan.org/dist/Catalyst/lib/Catalyst/Test.pm>
2181
2182 =item Test::WWW::Mechanize::Catalyst
2183
2184 L<http://search.cpan.org/dist/Test-WWW-Mechanize-Catalyst/lib/Test/WWW/Mechanize/Catalyst.pm>
2185
2186 =item Test::WWW::Mechanize
2187
2188 L<http://search.cpan.org/dist/Test-WWW-Mechanize/Mechanize.pm>
2189
2190 =item WWW::Mechanize
2191
2192 L<http://search.cpan.org/dist/WWW-Mechanize/lib/WWW/Mechanize.pm>
2193
2194 =item LWP::UserAgent
2195
2196 L<http://search.cpan.org/dist/libwww-perl/lib/LWP/UserAgent.pm>
2197
2198 =item HTML::Form
2199
2200 L<http://search.cpan.org/dist/libwww-perl/lib/HTML/Form.pm>
2201
2202 =item HTTP::Message
2203
2204 L<http://search.cpan.org/dist/libwww-perl/lib/HTTP/Message.pm>
2205
2206 =item HTTP::Request
2207
2208 L<http://search.cpan.org/dist/libwww-perl/lib/HTTP/Request.pm>
2209
2210 =item HTTP::Request::Common
2211
2212 L<http://search.cpan.org/dist/libwww-perl/lib/HTTP/Request/Common.pm>
2213
2214 =item HTTP::Response
2215
2216 L<http://search.cpan.org/dist/libwww-perl/lib/HTTP/Response.pm>
2217
2218 =item HTTP::Status
2219
2220 L<http://search.cpan.org/dist/libwww-perl/lib/HTTP/Status.pm>
2221
2222 =item URI
2223
2224 L<http://search.cpan.org/dist/URI/URI.pm>
2225
2226 =item Test::More
2227
2228 L<http://search.cpan.org/dist/Test-Simple/lib/Test/More.pm>
2229
2230 =item Test::Pod
2231
2232 L<http://search.cpan.org/dist/Test-Pod/Pod.pm>
2233
2234 =item Test::Pod::Coverage
2235
2236 L<http://search.cpan.org/dist/Test-Pod-Coverage/Coverage.pm>
2237
2238 =item prove (Test::Harness)
2239
2240 L<http://search.cpan.org/dist/Test-Harness/bin/prove>
2241
2242 =back
2243
2244 =head3 More Information
2245
2246 L<http://search.cpan.org/perldoc?Catalyst::Plugin::Authorization::Roles>
2247 L<http://search.cpan.org/perldoc?Catalyst::Plugin::Authorization::ACL>
2248
2249 =head1 AUTHORS
2250
2251 Sebastian Riedel C<sri@oook.de>
2252
2253 Danijel Milicevic C<me@danijel.de>
2254
2255 Viljo Marrandi C<vilts@yahoo.com>  
2256
2257 Marcus Ramberg C<mramberg@cpan.org>
2258
2259 Jesse Sheidlower C<jester@panix.com>
2260
2261 Andy Grundman C<andy@hybridized.org> 
2262
2263 Chisel Wright C<pause@herlpacker.co.uk>
2264
2265 Will Hawes C<info@whawes.co.uk>
2266
2267 Gavin Henry C<ghenry@perl.me.uk>
2268
2269 Kieren Diment C<kd@totaldatasolution.com>
2270
2271 =head1 COPYRIGHT
2272
2273 This document is free, you can redistribute it and/or modify it
2274 under the same terms as Perl itself.
2275