lib/Catalyst/IOC/Container.pm

   1 package Catalyst::IOC::Container;
   2 use Bread::Board;
   3 use Moose;
   4 use Config::Any;
   5 use Data::Visitor::Callback;
   6 use Catalyst::Utils ();
   7 use Devel::InnerPackage ();
   8 use Hash::Util qw/lock_hash/;
   9 use MooseX::Types::LoadableClass qw/ LoadableClass /;
  10 use Moose::Util;
  11 use Catalyst::IOC::BlockInjection;
  12 use Catalyst::IOC::ConstructorInjection;
  13 use Module::Pluggable::Object ();
  14 use namespace::autoclean;
  15
  16 extends 'Bread::Board::Container';
  17
  18 has config_local_suffix => (
  19     is      => 'ro',
  20     isa     => 'Str',
  21     default => 'local',
  22 );
  23
  24 has driver => (
  25     is      => 'ro',
  26     isa     => 'HashRef',
  27     default => sub { +{} },
  28 );
  29
  30 has file => (
  31     is      => 'ro',
  32     isa     => 'Str',
  33     default => '',
  34 );
  35
  36 has substitutions => (
  37     is      => 'ro',
  38     isa     => 'HashRef',
  39     default => sub { +{} },
  40 );
  41
  42 has application_name => (
  43     is       => 'ro',
  44     isa      => 'Str',
  45     required => 1,
  46 );
  47
  48 has sub_container_class => (
  49     isa     => LoadableClass,
  50     is      => 'ro',
  51     coerce  => 1,
  52     default => 'Catalyst::IOC::SubContainer',
  53     handles => {
  54         new_sub_container => 'new',
  55     }
  56 );
  57
  58 sub BUILD {
  59     my ( $self, $params ) = @_;
  60
  61     $self->add_service(
  62         $self->${\"build_${_}_service"}
  63     ) for qw/
  64         substitutions
  65         file
  66         driver
  67         application_name
  68         prefix
  69         extensions
  70         path
  71         config
  72         raw_config
  73         global_files
  74         local_files
  75         global_config
  76         local_config
  77         class_config
  78         config_local_suffix
  79         config_path
  80         locate_components
  81     /;
  82
  83     my $config = $self->resolve( service => 'config' );
  84
  85     $self->add_sub_container(
  86         $self->build_component_subcontainer
  87     );
  88
  89     $self->add_sub_container(
  90         $self->build_controller_subcontainer
  91     );
  92
  93     $self->add_sub_container(
  94         $self->build_view_subcontainer(
  95             default_component => $config->{default_view},
  96         )
  97     );
  98
  99     $self->add_sub_container(
 100         $self->build_model_subcontainer(
 101             default_component => $config->{default_model},
 102         )
 103     );
 104 }
 105
 106 sub build_model_subcontainer {
 107     my $self = shift;
 108
 109     return $self->new_sub_container( @_,
 110         name => 'model',
 111     );
 112 }
 113
 114 sub build_view_subcontainer {
 115     my $self = shift;
 116
 117     return $self->new_sub_container( @_,
 118         name => 'view',
 119     );
 120 }
 121
 122 sub build_controller_subcontainer {
 123     my $self = shift;
 124
 125     return $self->new_sub_container(
 126         name => 'controller',
 127     );
 128 }
 129
 130 sub build_component_subcontainer {
 131     my $self = shift;
 132
 133     return Bread::Board::Container->new(
 134         name => 'component',
 135     );
 136 }
 137
 138 sub build_application_name_service {
 139     my $self = shift;
 140
 141     return Bread::Board::Literal->new( name => 'application_name', value => $self->application_name );
 142 }
 143
 144 sub build_driver_service {
 145     my $self = shift;
 146
 147     return Bread::Board::Literal->new( name => 'driver', value => $self->driver );
 148 }
 149
 150 sub build_file_service {
 151     my $self = shift;
 152
 153     return Bread::Board::Literal->new( name => 'file', value => $self->file );
 154 }
 155
 156 sub build_substitutions_service {
 157     my $self = shift;
 158
 159     return Bread::Board::Literal->new( name => 'substitutions', value => $self->substitutions );
 160 }
 161
 162 sub build_extensions_service {
 163     my $self = shift;
 164
 165     return Bread::Board::BlockInjection->new(
 166         lifecycle => 'Singleton',
 167         name => 'extensions',
 168         block => sub {
 169             return \@{Config::Any->extensions};
 170         },
 171     );
 172 }
 173
 174 sub build_prefix_service {
 175     my $self = shift;
 176
 177     return Bread::Board::BlockInjection->new(
 178         lifecycle => 'Singleton',
 179         name => 'prefix',
 180         block => sub {
 181             return Catalyst::Utils::appprefix( shift->param('application_name') );
 182         },
 183         dependencies => [ depends_on('application_name') ],
 184     );
 185 }
 186
 187 sub build_path_service {
 188     my $self = shift;
 189
 190     return Bread::Board::BlockInjection->new(
 191         lifecycle => 'Singleton',
 192         name => 'path',
 193         block => sub {
 194             my $s = shift;
 195
 196             return Catalyst::Utils::env_value( $s->param('application_name'), 'CONFIG' )
 197             || $s->param('file')
 198             || $s->param('application_name')->path_to( $s->param('prefix') );
 199         },
 200         dependencies => [ depends_on('file'), depends_on('application_name'), depends_on('prefix') ],
 201     );
 202 }
 203
 204 sub build_config_service {
 205     my $self = shift;
 206
 207     return Bread::Board::BlockInjection->new(
 208         lifecycle => 'Singleton',
 209         name => 'config',
 210         block => sub {
 211             my $s = shift;
 212
 213             my $v = Data::Visitor::Callback->new(
 214                 plain_value => sub {
 215                     return unless defined $_;
 216                     return $self->_config_substitutions( $s->param('application_name'), $s->param('substitutions'), $_ );
 217                 }
 218
 219             );
 220             $v->visit( $s->param('raw_config') );
 221         },
 222         dependencies => [ depends_on('application_name'), depends_on('raw_config'), depends_on('substitutions') ],
 223     );
 224 }
 225
 226 sub build_raw_config_service {
 227     my $self = shift;
 228
 229     return Bread::Board::BlockInjection->new(
 230         lifecycle => 'Singleton',
 231         name => 'raw_config',
 232         block => sub {
 233             my $s = shift;
 234
 235             my @global = @{$s->param('global_config')};
 236             my @locals = @{$s->param('local_config')};
 237
 238             my $config = $s->param('class_config');
 239
 240             for my $cfg (@global, @locals) {
 241                 for (keys %$cfg) {
 242                     $config = Catalyst::Utils::merge_hashes( $config, $cfg->{$_} );
 243                 }
 244             }
 245
 246             return $config;
 247         },
 248         dependencies => [ depends_on('global_config'), depends_on('local_config'), depends_on('class_config') ],
 249     );
 250 }
 251
 252 sub build_global_files_service {
 253     my $self = shift;
 254
 255     return Bread::Board::BlockInjection->new(
 256         lifecycle => 'Singleton',
 257         name => 'global_files',
 258         block => sub {
 259             my $s = shift;
 260
 261             my ( $path, $extension ) = @{$s->param('config_path')};
 262
 263             my @extensions = @{$s->param('extensions')};
 264
 265             my @files;
 266             if ( $extension ) {
 267                 die "Unable to handle files with the extension '${extension}'" unless grep { $_ eq $extension } @extensions;
 268                 push @files, $path;
 269             } else {
 270                 @files = map { "$path.$_" } @extensions;
 271             }
 272             return \@files;
 273         },
 274         dependencies => [ depends_on('extensions'), depends_on('config_path') ],
 275     );
 276 }
 277
 278 sub build_local_files_service {
 279     my $self = shift;
 280
 281     return Bread::Board::BlockInjection->new(
 282         lifecycle => 'Singleton',
 283         name => 'local_files',
 284         block => sub {
 285             my $s = shift;
 286
 287             my ( $path, $extension ) = @{$s->param('config_path')};
 288             my $suffix = $s->param('config_local_suffix');
 289
 290             my @extensions = @{$s->param('extensions')};
 291
 292             my @files;
 293             if ( $extension ) {
 294                 die "Unable to handle files with the extension '${extension}'" unless grep { $_ eq $extension } @extensions;
 295                 $path =~ s{\.$extension}{_$suffix.$extension};
 296                 push @files, $path;
 297             } else {
 298                 @files = map { "${path}_${suffix}.$_" } @extensions;
 299             }
 300             return \@files;
 301         },
 302         dependencies => [ depends_on('extensions'), depends_on('config_path'), depends_on('config_local_suffix') ],
 303     );
 304 }
 305
 306 sub build_class_config_service {
 307     my $self = shift;
 308
 309     return Bread::Board::BlockInjection->new(
 310         lifecycle => 'Singleton',
 311         name => 'class_config',
 312         block => sub {
 313             my $s   = shift;
 314             my $app = $s->param('application_name');
 315
 316             # Container might be called outside Catalyst context
 317             return {} unless Class::MOP::is_class_loaded($app);
 318
 319             # config might not have been defined
 320             return $app->config || {};
 321         },
 322         dependencies => [ depends_on('application_name') ],
 323     );
 324 }
 325
 326 sub build_global_config_service {
 327     my $self = shift;
 328
 329     return Bread::Board::BlockInjection->new(
 330         lifecycle => 'Singleton',
 331         name => 'global_config',
 332         block => sub {
 333             my $s = shift;
 334
 335             return Config::Any->load_files({
 336                 files       => $s->param('global_files'),
 337                 filter      => \&_fix_syntax,
 338                 use_ext     => 1,
 339                 driver_args => $s->param('driver'),
 340             });
 341         },
 342         dependencies => [ depends_on('global_files') ],
 343     );
 344 }
 345
 346 sub build_local_config_service {
 347     my $self = shift;
 348
 349     return Bread::Board::BlockInjection->new(
 350         lifecycle => 'Singleton',
 351         name => 'local_config',
 352         block => sub {
 353             my $s = shift;
 354
 355             return Config::Any->load_files({
 356                 files       => $s->param('local_files'),
 357                 filter      => \&_fix_syntax,
 358                 use_ext     => 1,
 359                 driver_args => $s->param('driver'),
 360             });
 361         },
 362         dependencies => [ depends_on('local_files') ],
 363     );
 364 }
 365
 366 sub build_config_path_service {
 367     my $self = shift;
 368
 369     return Bread::Board::BlockInjection->new(
 370         lifecycle => 'Singleton',
 371         name => 'config_path',
 372         block => sub {
 373             my $s = shift;
 374
 375             my $path = $s->param('path');
 376             my $prefix = $s->param('prefix');
 377
 378             my ( $extension ) = ( $path =~ m{\.(.{1,4})$} );
 379
 380             if ( -d $path ) {
 381                 $path =~ s{[\/\\]$}{};
 382                 $path .= "/$prefix";
 383             }
 384
 385             return [ $path, $extension ];
 386         },
 387         dependencies => [ depends_on('prefix'), depends_on('path') ],
 388     );
 389 }
 390
 391 sub build_config_local_suffix_service {
 392     my $self = shift;
 393
 394     return Bread::Board::BlockInjection->new(
 395         lifecycle => 'Singleton',
 396         name => 'config_local_suffix',
 397         block => sub {
 398             my $s = shift;
 399             my $suffix = Catalyst::Utils::env_value( $s->param('application_name'), 'CONFIG_LOCAL_SUFFIX' ) || $self->config_local_suffix;
 400
 401             return $suffix;
 402         },
 403         dependencies => [ depends_on('application_name') ],
 404     );
 405 }
 406
 407 sub build_locate_components_service {
 408     my $self = shift;
 409
 410     return Bread::Board::BlockInjection->new(
 411         lifecycle => 'Singleton',
 412         name      => 'locate_components',
 413         block     => sub {
 414             my $s      = shift;
 415             my $class  = $s->param('application_name');
 416             my $config = $s->param('config')->{ setup_components };
 417
 418             Catalyst::Exception->throw(
 419                 qq{You are using search_extra config option. That option is\n} .
 420                 qq{deprecated, please refer to the documentation for\n} .
 421                 qq{other ways of achieving the same results.\n}
 422             ) if delete $config->{ search_extra };
 423
 424             my @paths = qw( ::Controller ::C ::Model ::M ::View ::V );
 425
 426             my $locator = Module::Pluggable::Object->new(
 427                 search_path => [ map { s/^(?=::)/$class/; $_; } @paths ],
 428                 %$config
 429             );
 430
 431             return [ $locator->plugins ];
 432         },
 433         dependencies => [ depends_on('application_name'), depends_on('config') ],
 434     );
 435 }
 436
 437 sub setup_components {
 438     my $self = shift;
 439     my $class = $self->resolve( service => 'application_name' );
 440     my @comps = @{ $self->resolve( service => 'locate_components' ) };
 441     my %comps = map { $_ => 1 } @comps;
 442     my $deprecatedcatalyst_component_names = 0;
 443
 444     for my $component ( @comps ) {
 445
 446         # We pass ignore_loaded here so that overlay files for (e.g.)
 447         # Model::DBI::Schema sub-classes are loaded - if it's in @comps
 448         # we know M::P::O found a file on disk so this is safe
 449
 450         Catalyst::Utils::ensure_class_loaded( $component, { ignore_loaded => 1 } );
 451     }
 452
 453     for my $component (@comps) {
 454         $self->add_component( $component );
 455         # FIXME - $instance->expand_modules() is broken
 456         my @expanded_components = $self->expand_component_module( $component );
 457
 458         if (
 459             !$deprecatedcatalyst_component_names &&
 460             ($deprecatedcatalyst_component_names = $component =~ m/::[CMV]::/) ||
 461             ($deprecatedcatalyst_component_names = grep { /::[CMV]::/ } @expanded_components)
 462         ) {
 463             # FIXME - should I be calling warn here?
 464             # Maybe it's time to remove it, or become fatal
 465             $class->log->warn(qq{Your application is using the deprecated ::[MVC]:: type naming scheme.\n}.
 466                 qq{Please switch your class names to ::Model::, ::View:: and ::Controller: as appropriate.\n}
 467             );
 468         }
 469
 470         for my $component (@expanded_components) {
 471             $self->add_component( $component )
 472                 unless $comps{$component};
 473         }
 474     }
 475
 476     $self->get_sub_container('model')->make_single_default;
 477     $self->get_sub_container('view')->make_single_default;
 478 }
 479
 480 sub _fix_syntax {
 481     my $config     = shift;
 482     my @components = (
 483         map +{
 484             prefix => $_ eq 'Component' ? '' : $_ . '::',
 485             values => delete $config->{ lc $_ } || delete $config->{ $_ }
 486         },
 487         grep { ref $config->{ lc $_ } || ref $config->{ $_ } }
 488             qw( Component Model M View V Controller C Plugin )
 489     );
 490
 491     foreach my $comp ( @components ) {
 492         my $prefix = $comp->{ prefix };
 493         foreach my $element ( keys %{ $comp->{ values } } ) {
 494             $config->{ "$prefix$element" } = $comp->{ values }->{ $element };
 495         }
 496     }
 497 }
 498
 499 sub _config_substitutions {
 500     my ( $self, $name, $subs, $arg ) = @_;
 501
 502     $subs->{ HOME } ||= sub { shift->path_to( '' ); };
 503     $subs->{ ENV } ||=
 504         sub {
 505             my ( $c, $v ) = @_;
 506             if (! defined($ENV{$v})) {
 507                 Catalyst::Exception->throw( message =>
 508                     "Missing environment variable: $v" );
 509                 return "";
 510             } else {
 511                 return $ENV{ $v };
 512             }
 513         };
 514     $subs->{ path_to } ||= sub { shift->path_to( @_ ); };
 515     $subs->{ literal } ||= sub { return $_[ 1 ]; };
 516     my $subsre = join( '|', keys %$subs );
 517
 518     $arg =~ s{__($subsre)(?:\((.+?)\))?__}{ $subs->{ $1 }->( $name, $2 ? split( /,/, $2 ) : () ) }eg;
 519     return $arg;
 520 }
 521
 522 sub get_component_from_sub_container {
 523     my ( $self, $sub_container_name, $name, $c, @args ) = @_;
 524
 525     my $sub_container = $self->get_sub_container( $sub_container_name );
 526
 527     if (!$name) {
 528         my $default = $sub_container->default_component;
 529
 530         return $sub_container->get_component( $default, $c, @args )
 531             if $default && $sub_container->has_service( $default );
 532
 533         # FIXME - should I be calling $c->log->warn here?
 534         # this is never a controller, so this is safe
 535         $c->log->warn( "Calling \$c->$sub_container_name() is not supported unless you specify one of:" );
 536         $c->log->warn( "* \$c->config(default_$sub_container_name => 'the name of the default $sub_container_name to use')" );
 537         $c->log->warn( "* \$c->stash->{current_$sub_container_name} # the name of the view to use for this request" );
 538         $c->log->warn( "* \$c->stash->{current_${sub_container_name}_instance} # the instance of the $sub_container_name to use for this request" );
 539
 540         return;
 541     }
 542
 543     return $sub_container->get_component_regexp( $name, $c, @args )
 544         if ref $name;
 545
 546     return $sub_container->get_component( $name, $c, @args )
 547         if $sub_container->has_service( $name );
 548
 549     $c->log->warn(
 550         "Attempted to use $sub_container_name '$name', " .
 551         "but it does not exist"
 552     );
 553
 554     return;
 555 }
 556
 557 sub find_component {
 558     my ( $self, $component, @args ) = @_;
 559     my ( $type, $name ) = _get_component_type_name($component);
 560     my @result;
 561
 562     return $self->get_component_from_sub_container(
 563         $type, $name, @args
 564     ) if $type;
 565
 566     my $query = ref $component
 567               ? $component
 568               : qr{^$component$}
 569               ;
 570
 571     for my $subcontainer_name (qw/model view controller/) {
 572         my $subcontainer = $self->get_sub_container( $subcontainer_name );
 573         my @components   = $subcontainer->get_service_list;
 574         @result          = grep { m{$component} } @components;
 575
 576         return map { $subcontainer->get_component( $_, @args ) } @result
 577             if @result;
 578     }
 579
 580     # one last search for things like $c->comp(qr/::M::/)
 581     @result = $self->find_component_regexp(
 582         $component, @args
 583     ) if !@result and ref $component;
 584
 585     # it expects an empty list on failed searches
 586     return @result;
 587 }
 588
 589 sub find_component_regexp {
 590     my ( $self, $component, @args ) = @_;
 591     my @result;
 592
 593     my @components = grep { m{$component} } keys %{ $self->get_all_components };
 594
 595     for (@components) {
 596         my ($type, $name) = _get_component_type_name($_);
 597
 598         push @result, $self->get_component_from_sub_container(
 599             $type, $name, @args
 600         ) if $type;
 601     }
 602
 603     return @result;
 604 }
 605
 606 sub get_all_components {
 607     my $self = shift;
 608     my %components;
 609
 610     my $container = $self->get_sub_container('component');
 611
 612     for my $component ($container->get_service_list) {
 613         my $comp = $container->resolve(
 614             service => $component
 615         );
 616         my $comp_name = ref $comp || $comp;
 617         $components{$comp_name} = $comp;
 618     }
 619
 620     return lock_hash %components;
 621 }
 622
 623 sub add_component {
 624     my ( $self, $component ) = @_;
 625     my ( $type, $name ) = _get_component_type_name($component);
 626
 627     return unless $type;
 628
 629     my $component_service_name = "${type}_${name}";
 630
 631     # The 'component' sub-container will create the object, and store it's
 632     # instance, which, by default, will live throughout the application.
 633     # The model/view/controller sub-containers only reference the instance
 634     # held in the aforementioned sub-container, and execute the ACCEPT_CONTEXT
 635     # sub every time they are called, when it exists.
 636     my $instance_container       = $self->get_sub_container('component');
 637     my $accept_context_container = $self->get_sub_container($type);
 638
 639     $instance_container->add_service(
 640         Catalyst::IOC::ConstructorInjection->new(
 641             name      => $component_service_name,
 642             class     => $component,
 643             lifecycle => 'Singleton',
 644             dependencies => [
 645                 depends_on( '/application_name' ),
 646                 depends_on( '/config' ),
 647             ],
 648         )
 649     ) unless $instance_container->has_service( $component_service_name );
 650     # ^ custom containers might have added the service already.
 651     # we don't want to override that.
 652
 653     $accept_context_container->add_service(
 654         Catalyst::IOC::BlockInjection->new(
 655             name         => $name,
 656             dependencies => [
 657                 depends_on( "/component/$component_service_name" ),
 658             ],
 659             block => sub { shift->param($component_service_name) },
 660         )
 661     ) unless $accept_context_container->has_service( $name );
 662     # ^ same as above
 663 }
 664
 665 # FIXME: should this sub exist?
 666 # should it be moved to Catalyst::Utils,
 667 # or replaced by something already existing there?
 668 sub _get_component_type_name {
 669     my ( $component ) = @_;
 670
 671     my @parts = split /::/, $component;
 672
 673     while (my $type = shift @parts) {
 674         return ('controller', join '::', @parts)
 675             if $type =~ /^(c|controller)$/i;
 676
 677         return ('model', join '::', @parts)
 678             if $type =~ /^(m|model)$/i;
 679
 680         return ('view', join '::', @parts)
 681             if $type =~ /^(v|view)$/i;
 682     }
 683
 684     return (undef, $component);
 685 }
 686
 687 sub expand_component_module {
 688     my ( $class, $module ) = @_;
 689     return Devel::InnerPackage::list_packages( $module );
 690 }
 691
 692 1;
 693
 694 __END__
 695
 696 =pod
 697
 698 =head1 NAME
 699
 700 Catalyst::Container - IOC for Catalyst components
 701
 702 =head1 SYNOPSIS
 703
 704 =head1 DESCRIPTION
 705
 706 =head1 METHODS
 707
 708 =head1 Building Containers
 709
 710 =head2 build_component_subcontainer
 711
 712 Container that stores all components, i.e. all models, views and controllers
 713 together. Each service is an instance of the actual component, and by default
 714 it lives while the application is running. Retrieving components from this
 715 subcontainer will instantiate the component, if it hasn't been instantiated
 716 already, but will not execute ACCEPT_CONTEXT.
 717
 718 =head2 build_model_subcontainer
 719
 720 Container that stores references for all models that are inside the components
 721 subcontainer. Retrieving a model triggers ACCEPT_CONTEXT, if it exists.
 722
 723 =head2 build_view_subcontainer
 724
 725 Same as L<build_model_subcontainer>, but for views.
 726
 727 =head2 build_controller_subcontainer
 728
 729 Same as L<build_model_subcontainer>, but for controllers.
 730
 731 =head1 Building Services
 732
 733 =head2 build_application_name_service
 734
 735 Name of the application (such as MyApp).
 736
 737 =head2 build_driver_service
 738
 739 Config options passed directly to the driver being used.
 740
 741 =head2 build_file_service
 742
 743 ?
 744
 745 =head2 build_substitutions_service
 746
 747 This method substitutes macros found with calls to a function. There are a
 748 number of default macros:
 749
 750 =over
 751
 752 =item * C<__HOME__> - replaced with C<$c-E<gt>path_to('')>
 753
 754 =item * C<__ENV(foo)__> - replaced with the value of C<$ENV{foo}>
 755
 756 =item * C<__path_to(foo/bar)__> - replaced with C<$c-E<gt>path_to('foo/bar')>
 757
 758 =item * C<__literal(__FOO__)__> - leaves __FOO__ alone (allows you to use
 759 C<__DATA__> as a config value, for example)
 760
 761 =back
 762
 763 The parameter list is split on comma (C<,>). You can override this method to
 764 do your own string munging, or you can define your own macros in
 765 C<< <MyApp->config( 'Plugin::ConfigLoader' => { substitutions => { ... } } ) >>.
 766 Example:
 767
 768     MyApp->config( 'Plugin::ConfigLoader' => {
 769         substitutions => {
 770             baz => sub { my $c = shift; qux( @_ ); },
 771         },
 772     });
 773
 774 The above will respond to C<__baz(x,y)__> in config strings.
 775
 776 =head2 build_extensions_service
 777
 778 Config::Any's available config file extensions (e.g. xml, json, pl, etc).
 779
 780 =head2 build_prefix_service
 781
 782 The prefix, based on the application name, that will be used to lookup the
 783 config files (which will be in the format $prefix.$extension). If the app is
 784 MyApp::Foo, the prefix will be myapp_foo.
 785
 786 =head2 build_path_service
 787
 788 The path to the config file (or environment variable, if defined).
 789
 790 =head2 build_config_service
 791
 792 The resulting configuration for the application, after it has successfully
 793 been loaded, and all substitutions have been made.
 794
 795 =head2 build_raw_config_service
 796
 797 The merge of local_config and global_config hashes, before substitutions.
 798
 799 =head2 build_global_files_service
 800
 801 Gets all files for config that don't have the local_suffix, such as myapp.conf.
 802
 803 =head2 build_local_files_service
 804
 805 Gets all files for config that have the local_suffix, such as myapp_local.conf.
 806
 807 =head2 build_global_config_service
 808
 809 Reads config from global_files.
 810
 811 =head2 build_local_config_service
 812
 813 Reads config from local_files.
 814
 815 =head2 build_class_config_service
 816
 817 Reads config set from the application's class attribute config,
 818 i.e. MyApp->config( name => 'MyApp', ... )
 819
 820 =head2 build_config_path_service
 821
 822 Splits the path to the config file, and returns on array ref containing
 823 the path to the config file minus the extension in the first position,
 824 and the extension in the second.
 825
 826 =head2 build_config_local_suffix_service
 827
 828 Determines the suffix of files used to override the main config. By default
 829 this value is C<local>, which will load C<myapp_local.conf>.  The suffix can
 830 be specified in the following order of preference:
 831
 832 =over
 833
 834 =item * C<$ENV{ MYAPP_CONFIG_LOCAL_SUFFIX }>
 835
 836 =item * C<$ENV{ CATALYST_CONFIG_LOCAL_SUFFIX }>
 837
 838 =back
 839
 840 The first one of these values found replaces the default of C<local> in the
 841 name of the local config file to be loaded.
 842
 843 For example, if C< $ENV{ MYAPP_CONFIG_LOCAL_SUFFIX }> is set to C<testing>,
 844 ConfigLoader will try and load C<myapp_testing.conf> instead of
 845 C<myapp_local.conf>.
 846
 847 =head2 build_locate_components_service
 848
 849 This method is meant to provide a list of component modules that should be
 850 setup for the application.  By default, it will use L<Module::Pluggable>.
 851
 852 Specify a C<setup_components> config option to pass additional options directly
 853 to L<Module::Pluggable>.
 854
 855 =head1 Other methods
 856
 857 =head2 get_component_from_sub_container($sub_container, $name, $c, @args)
 858
 859 Looks for components in a given subcontainer (such as controller, model or
 860 view), and returns the searched component. If $name is undef, it returns the
 861 default component (such as default_view, if $sub_container is 'view'). If
 862 $name is a regexp, it returns an array of matching components. Otherwise, it
 863 looks for the component with name $name.
 864
 865 =head2 get_components_names_types
 866
 867 Gets all components from all containers and returns them as an array of
 868 arrayrefs containing the component name and the component type (i.e., whether
 869 it's an instance or a class).
 870
 871 =head2 get_all_components
 872
 873 Fetches all the components, in each of the sub_containers model, view and
 874 controller, and returns a readonly hash. The keys are the class names, and
 875 the values are the blessed objects. This is what is returned by $c->components.
 876
 877 =head2 add_component
 878
 879 Adds a component to the appropriate subcontainer. The subcontainer is guessed
 880 by the component name given.
 881
 882 =head2 find_component
 883
 884 Searches for components in all containers. If $component is the full class
 885 name, the subcontainer is guessed, and it gets the searched component in there.
 886 Otherwise, it looks for a component with that name in all subcontainers. If
 887 $component is a regexp, it calls the method below, find_component_regexp,
 888 and matches all components against that regexp.
 889
 890 =head2 find_component_regexp
 891
 892 Finds components that match a given regexp. Used internally, by find_component.
 893
 894 =head2 expand_component_module
 895
 896 Components found by C<locate_components> will be passed to this method, which
 897 is expected to return a list of component (package) names to be set up.
 898
 899 =head2 setup_components
 900
 901 =head1 AUTHORS
 902
 903 Catalyst Contributors, see Catalyst.pm
 904
 905 =head1 COPYRIGHT
 906
 907 This library is free software. You can redistribute it and/or modify it under
 908 the same terms as Perl itself.
 909
 910 =cut