lib/Catalyst/IOC/ConstructorInjection.pm

   1 package Catalyst::IOC::ConstructorInjection;
   2 use Moose;
   3 use Try::Tiny;
   4 use Catalyst::Utils ();
   5 extends 'Bread::Board::ConstructorInjection';
   6
   7 with 'Bread::Board::Service::WithClass',
   8      'Bread::Board::Service::WithParameters',
   9      'Bread::Board::Service::WithDependencies';
  10
  11 has config => (
  12     is         => 'ro',
  13     isa        => 'HashRef',
  14     required => 1,
  15 );
  16
  17 sub get {
  18     my $self = shift;
  19
  20     my $component   = $self->class;
  21     my %config = (%{ $self->config }, %{ $self->params });
  22
  23     # FIXME - Is depending on the application name to pass into constructors here a good idea?
  24     #         This makes app/ctx split harder I think.. Need to think more here, but I think
  25     #         we want to pass the application in as a parameter when building the service
  26     #         rather than depending on the app name, so that later, when the app becomes an instance
  27     #         then it'll get passed in, and components can stash themselves 'per app instance'
  28     my $app_name    = $self->param('application_name');
  29
  30     # Stash catalyst_component_name in the config here, so that custom COMPONENT
  31     # methods also pass it. local to avoid pointlessly shitting in config
  32     # for the debug screen, as $component is already the key name.
  33     # XXX FIXME - WRONG!!! MyApp::Model::Foo may be an instance of something
  34     #             totally diferent, ergo it should get a catalyst_component_name
  35     #             of MyApp::Model::Foo.. Write failing tests for this in master?
  36     $config{catalyst_component_name} = $component;
  37
  38     unless ( $component->can( 'COMPONENT' ) ) {
  39         # FIXME - make some deprecation warnings
  40         return $component;
  41     }
  42
  43     my $instance;
  44     try {
  45         $instance = $component->COMPONENT( $app_name, \%config );
  46     }
  47     catch {
  48         Catalyst::Exception->throw(
  49             message => qq/Couldn't instantiate component "$component", "$_"/
  50         );
  51     };
  52
  53     return $instance
  54         if blessed $instance;
  55
  56     my $metaclass = Moose::Util::find_meta($component);
  57     my $method_meta = $metaclass->find_method_by_name('COMPONENT');
  58     my $component_method_from = $method_meta->associated_metaclass->name;
  59     my $value = defined($instance) ? $instance : 'undef';
  60     Catalyst::Exception->throw(
  61         message =>
  62         qq/Couldn't instantiate component "$component", COMPONENT method (from $component_method_from) didn't return an object-like value (value was $value)./
  63     );
  64 }
  65
  66 __PACKAGE__->meta->make_immutable;
  67
  68 no Moose; 1;
  69
  70 __END__
  71
  72 =pod
  73
  74 =head1 NAME
  75
  76 Catalyst::IOC::ConstructorInjection
  77
  78 =head1 SYNOPSIS
  79
  80 =head1 DESCRIPTION
  81
  82 =head1 AUTHORS
  83
  84 Catalyst Contributors, see Catalyst.pm
  85
  86 =head1 COPYRIGHT
  87
  88 This library is free software. You can redistribute it and/or modify it under
  89 the same terms as Perl itself.
  90
  91 =cut