lib/Catalyst/Helper.pm

   1 package Catalyst::Helper;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5 use Config;
   6 use File::Spec;
   7 use File::Path;
   8 use IO::File;
   9 use FindBin;
  10 use Template;
  11 use Catalyst;
  12
  13 my %cache;
  14
  15 =head1 NAME
  16
  17 Catalyst::Helper - Bootstrap a Catalyst application
  18
  19 =head1 SYNOPSIS
  20
  21 See L<Catalyst::Manual::Intro>
  22
  23 =head1 DESCRIPTION
  24
  25 Bootstrap a Catalyst application. Autogenerates scripts
  26
  27 =head2 METHODS
  28
  29 =head3 get_file
  30
  31 Slurp file from DATA.
  32
  33 =cut
  34
  35 sub get_file {
  36     my ( $self, $class, $file ) = @_;
  37     unless ( $cache{$class} ) {
  38         local $/;
  39         $cache{$class} = eval "package $class; <DATA>";
  40     }
  41     my $data = $cache{$class};
  42     my @files = split /^__(.+)__\n/m, $data;
  43     shift @files;
  44     while (@files) {
  45         my ( $name, $content ) = splice @files, 0, 2;
  46         return $content if $name eq $file;
  47     }
  48     return 0;
  49 }
  50
  51 =head3 mk_app
  52
  53 Create the main application skeleton.
  54
  55 =cut
  56
  57 sub mk_app {
  58     my ( $self, $name ) = @_;
  59     return 0 if $name =~ /[^\w\:]/;
  60     $self->{name} = $name;
  61     $self->{dir}  = $name;
  62     $self->{dir} =~ s/\:\:/-/g;
  63     $self->{appprefix} = lc $self->{dir};
  64     $self->{appprefix} =~ s/-/_/g;
  65     $self->{startperl} = $Config{startperl};
  66     $self->{scriptgen} = $Catalyst::CATALYST_SCRIPT_GEN;
  67     $self->{author}    = $self->{author} = $ENV{'AUTHOR'}
  68       || eval { @{ [ getpwuid($<) ] }[6] }
  69       || 'Catalyst developer';
  70     $self->_mk_dirs;
  71     $self->_mk_appclass;
  72     $self->_mk_build;
  73     $self->_mk_makefile;
  74     $self->_mk_readme;
  75     $self->_mk_changes;
  76     $self->_mk_apptest;
  77     $self->_mk_cgi;
  78     $self->_mk_fastcgi;
  79     $self->_mk_server;
  80     $self->_mk_test;
  81     $self->_mk_create;
  82     return 1;
  83 }
  84
  85 =head3 mk_component
  86
  87 This method is called by create.pl to make new components
  88 for your application.
  89
  90 =cut
  91
  92 sub mk_component {
  93     my $self = shift;
  94     my $app  = shift;
  95     $self->{app} = $app;
  96     $self->{author} = $self->{author} = $ENV{'AUTHOR'}
  97       || eval { @{ [ getpwuid($<) ] }[6] }
  98       || 'A clever guy';
  99     $self->{base} = File::Spec->catdir( $FindBin::Bin, '..' );
 100     unless ( $_[0] =~ /^(?:model|m|view|v|controller|c)$/i ) {
 101         my $helper = shift;
 102         my @args   = @_;
 103         my $class  = "Catalyst::Helper::$helper";
 104         eval "require $class";
 105         die qq/Couldn't load helper "$class", "$@"/ if $@;
 106         if ( $class->can('mk_stuff') ) {
 107             return 1 unless $class->mk_stuff( $self, @args );
 108         }
 109     }
 110     else {
 111         my $type   = shift;
 112         my $name   = shift || "Missing name for model/view/controller";
 113         my $helper = shift;
 114         my @args   = @_;
 115         return 0 if $name =~ /[^\w\:]/;
 116         $type = 'M' if $type =~ /model|m/i;
 117         $type = 'V' if $type =~ /view|v/i;
 118         $type = 'C' if $type =~ /controller|c/i;
 119         $self->{type}  = $type;
 120         $self->{name}  = $name;
 121         $self->{class} = "$app\::$type\::$name";
 122
 123         # Class
 124         my $appdir = File::Spec->catdir( split /\:\:/, $app );
 125         my $path =
 126           File::Spec->catdir( $FindBin::Bin, '..', 'lib', $appdir, $type );
 127         my $file = $name;
 128         if ( $name =~ /\:/ ) {
 129             my @path = split /\:\:/, $name;
 130             $file = pop @path;
 131             $path = File::Spec->catdir( $path, @path );
 132             mkpath $path;
 133         }
 134         $file = File::Spec->catfile( $path, "$file.pm" );
 135         $self->{file} = $file;
 136
 137         # Test
 138         $self->{test_dir} = File::Spec->catdir( $FindBin::Bin, '..', 't' );
 139         $self->{test}     = $self->next_test;
 140
 141         # Helper
 142         if ($helper) {
 143             my $comp = 'Model';
 144             $comp = 'View'       if $type eq 'V';
 145             $comp = 'Controller' if $type eq 'C';
 146             my $class = "Catalyst::Helper::$comp\::$helper";
 147             eval "require $class";
 148             die qq/Couldn't load helper "$class", "$@"/ if $@;
 149             if ( $class->can('mk_compclass') ) {
 150                 return 1 unless $class->mk_compclass( $self, @args );
 151             }
 152             else { return 1 unless $self->_mk_compclass }
 153
 154             if ( $class->can('mk_comptest') ) {
 155                 $class->mk_comptest( $self, @args );
 156             }
 157             else { $self->_mk_comptest }
 158         }
 159
 160         # Fallback
 161         else {
 162             return 1 unless $self->_mk_compclass;
 163             $self->_mk_comptest;
 164         }
 165     }
 166     return 1;
 167 }
 168
 169 =head3 mk_dir
 170
 171 Surprisingly, this function makes a directory.
 172
 173 =cut
 174
 175 sub mk_dir {
 176     my ( $self, $dir ) = @_;
 177     if ( -d $dir ) {
 178         print qq/ exists "$dir"\n/;
 179         return 0;
 180     }
 181     if ( mkpath $dir) {
 182         print qq/created "$dir"\n/;
 183         return 1;
 184     }
 185     die qq/Couldn't create "$dir", "$!"/;
 186 }
 187
 188 =head3 mk_file
 189
 190 writes content to a file.
 191
 192 =cut
 193
 194 sub mk_file {
 195     my ( $self, $file, $content ) = @_;
 196     if ( -e $file ) {
 197         print qq/ exists "$file"\n/;
 198         return 0;
 199     }
 200     if ( my $f = IO::File->new("> $file") ) {
 201         print $f $content;
 202         print qq/created "$file"\n/;
 203         return 1;
 204     }
 205     die qq/Couldn't create "$file", "$!"/;
 206 }
 207
 208 =head3 next_test
 209
 210 =cut
 211
 212 sub next_test {
 213     my ( $self, $tname ) = @_;
 214     if ($tname) { $tname = "$tname.t" }
 215     else {
 216         my $name   = $self->{name};
 217         my $prefix = $name;
 218         $prefix =~ s/::/_/g;
 219         $prefix         = lc $prefix;
 220         $tname          = $prefix . '.t';
 221         $self->{prefix} = $prefix;
 222     }
 223     my $dir  = $self->{test_dir};
 224     my $type = lc $self->{type};
 225     return File::Spec->catfile( $dir, $type, $tname );
 226 }
 227
 228 =head3 render_file
 229
 230 Render and create a file from a template in DATA using
 231 Template Toolkit.
 232
 233 =cut
 234
 235 sub render_file {
 236     my ( $self, $file, $path, $vars ) = @_;
 237     $vars ||= {};
 238     my $t = Template->new;
 239     my $template = $self->get_file( ( caller(0) )[0], $file );
 240     return 0 unless $template;
 241     my $output;
 242     $t->process( \$template, { %{$self}, %$vars }, \$output );
 243     $self->mk_file( $path, $output );
 244 }
 245
 246 sub _mk_dirs {
 247     my $self = shift;
 248     $self->mk_dir( $self->{dir} );
 249     $self->{script} = File::Spec->catdir( $self->{dir}, 'script' );
 250     $self->mk_dir( $self->{script} );
 251     $self->{lib} = File::Spec->catdir( $self->{dir}, 'lib' );
 252     $self->mk_dir( $self->{lib} );
 253     $self->{root} = File::Spec->catdir( $self->{dir}, 'root' );
 254     $self->mk_dir( $self->{root} );
 255     $self->{t} = File::Spec->catdir( $self->{dir}, 't' );
 256     $self->mk_dir( $self->{t} );
 257     $self->mk_dir( File::Spec->catdir( $self->{t}, 'm' ) );
 258     $self->mk_dir( File::Spec->catdir( $self->{t}, 'v' ) );
 259     $self->mk_dir( File::Spec->catdir( $self->{t}, 'c' ) );
 260     $self->{class} = File::Spec->catdir( split( /\:\:/, $self->{name} ) );
 261     $self->{mod} = File::Spec->catdir( $self->{lib}, $self->{class} );
 262     $self->mk_dir( $self->{mod} );
 263     $self->{m} = File::Spec->catdir( $self->{mod}, 'M' );
 264     $self->mk_dir( $self->{m} );
 265     $self->{v} = File::Spec->catdir( $self->{mod}, 'V' );
 266     $self->mk_dir( $self->{v} );
 267     $self->{c} = File::Spec->catdir( $self->{mod}, 'C' );
 268     $self->mk_dir( $self->{c} );
 269     $self->{base} = File::Spec->rel2abs( $self->{dir} );
 270 }
 271
 272 sub _mk_appclass {
 273     my $self = shift;
 274     my $mod  = $self->{mod};
 275     $self->render_file( 'appclass', "$mod.pm" );
 276 }
 277
 278 sub _mk_build {
 279     my $self = shift;
 280     my $dir  = $self->{dir};
 281     $self->render_file( 'build', "$dir\/Build.PL" );
 282 }
 283
 284 sub _mk_makefile {
 285     my $self = shift;
 286     my $dir  = $self->{dir};
 287     $self->render_file( 'makefile', "$dir\/Makefile.PL" );
 288 }
 289
 290 sub _mk_readme {
 291     my $self = shift;
 292     my $dir  = $self->{dir};
 293     $self->render_file( 'readme', "$dir\/README" );
 294 }
 295
 296 sub _mk_changes {
 297     my $self = shift;
 298     my $dir  = $self->{dir};
 299     my $time = localtime time;
 300     $self->render_file( 'changes', "$dir\/Changes", { time => $time } );
 301 }
 302
 303 sub _mk_apptest {
 304     my $self = shift;
 305     my $t    = $self->{t};
 306     $self->render_file( 'apptest',         "$t\/01app.t" );
 307     $self->render_file( 'podtest',         "$t\/02pod.t" );
 308     $self->render_file( 'podcoveragetest', "$t\/03podcoverage.t" );
 309 }
 310
 311 sub _mk_cgi {
 312     my $self      = shift;
 313     my $script    = $self->{script};
 314     my $appprefix = $self->{appprefix};
 315     $self->render_file( 'cgi', "$script\/$appprefix\_cgi.pl" );
 316     chmod 0700, "$script/$appprefix\_cgi.pl";
 317 }
 318
 319 sub _mk_fastcgi {
 320     my $self      = shift;
 321     my $script    = $self->{script};
 322     my $appprefix = $self->{appprefix};
 323     $self->render_file( 'fastcgi', "$script\/$appprefix\_fastcgi.pl" );
 324     chmod 0700, "$script/$appprefix\_fastcgi.pl";
 325 }
 326
 327 sub _mk_server {
 328     my $self      = shift;
 329     my $script    = $self->{script};
 330     my $appprefix = $self->{appprefix};
 331     $self->render_file( 'server', "$script\/$appprefix\_server.pl" );
 332     chmod 0700, "$script/$appprefix\_server.pl";
 333 }
 334
 335 sub _mk_test {
 336     my $self      = shift;
 337     my $script    = $self->{script};
 338     my $appprefix = $self->{appprefix};
 339     $self->render_file( 'test', "$script/$appprefix\_test.pl" );
 340     chmod 0700, "$script/$appprefix\_test.pl";
 341 }
 342
 343 sub _mk_create {
 344     my $self      = shift;
 345     my $script    = $self->{script};
 346     my $appprefix = $self->{appprefix};
 347     $self->render_file( 'create', "$script\/$appprefix\_create.pl" );
 348     chmod 0700, "$script/$appprefix\_create.pl";
 349 }
 350
 351 sub _mk_compclass {
 352     my $self = shift;
 353     my $file = $self->{file};
 354     return $self->render_file( 'compclass', "$file" );
 355 }
 356
 357 sub _mk_comptest {
 358     my $self = shift;
 359     my $test = $self->{test};
 360     $self->render_file( 'comptest', "$test" );
 361 }
 362
 363 =head1 HELPERS
 364
 365 Helpers are classes that provide two methods.
 366
 367     * mk_compclass - creates the Component class
 368     * mk_comptest  - creates the Component test
 369
 370 So when you call C<bin/create view MyView TT>, create would try to execute
 371 Catalyst::Helper::View::TT->mk_compclass and
 372 Catalyst::Helper::View::TT->mk_comptest.
 373
 374 See L<Catalyst::Helper::View::TT> and L<Catalyst::Helper::Model::CDBI> for
 375 examples.
 376
 377 All helper classes should be under one of the following namespaces.
 378
 379     Catalyst::Helper::Model::
 380     Catalyst::Helper::View::
 381     Catalyst::Helper::Controller::
 382
 383 =head1 NOTE
 384
 385 The helpers will read author name from /etc/passwd by default.
 386 To override, please export the AUTHOR variable.
 387
 388 =head1 SEE ALSO
 389
 390 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 391 L<Catalyst::Response>, L<Catalyst>
 392
 393 =head1 AUTHOR
 394
 395 Sebastian Riedel, C<sri@oook.de>
 396
 397 =head1 LICENSE
 398
 399 This library is free software . You can redistribute it and/or modify
 400 it under the same terms as perl itself.
 401
 402 =cut
 403
 404 1;
 405 __DATA__
 406
 407 __appclass__
 408 package [% name %];
 409
 410 use strict;
 411 use Catalyst qw/-Debug/;
 412
 413 our $VERSION = '0.01';
 414
 415 [% name %]->config( name => '[% name %]' );
 416
 417 [% name %]->setup;
 418
 419 =head1 NAME
 420
 421 [% name %] - Catalyst based application
 422
 423 =head1 SYNOPSIS
 424
 425     script/[% appprefix %]_server.pl
 426
 427 =head1 DESCRIPTION
 428
 429 Catalyst based application.
 430
 431 =head1 METHODS
 432
 433 =over 4
 434
 435 =item default
 436
 437 =cut
 438
 439 sub default : Private {
 440     my ( $self, $c ) = @_;
 441     $c->res->output('Congratulations, [% name %] is on Catalyst!');
 442 }
 443
 444 =back
 445
 446 =head1 AUTHOR
 447
 448 [%author%]
 449
 450 =head1 LICENSE
 451
 452 This library is free software . You can redistribute it and/or modify
 453 it under the same terms as perl itself.
 454
 455 =cut
 456
 457 1;
 458 __makefile__
 459     unless ( eval "use Module::Build::Compat 0.02; 1" ) {
 460         print "This module requires Module::Build to install itself.\n";
 461
 462         require ExtUtils::MakeMaker;
 463         my $yn =
 464           ExtUtils::MakeMaker::prompt( '  Install Module::Build now from CPAN?',            'y' );
 465
 466         unless ( $yn =~ /^y/i ) {
 467             die " *** Cannot install without Module::Build.  Exiting ...\n";
 468         }
 469
 470         require Cwd;
 471         require File::Spec;
 472         require CPAN;
 473
 474         # Save this 'cause CPAN will chdir all over the place.
 475         my $cwd      = Cwd::cwd();
 476         my $makefile = File::Spec->rel2abs($0);
 477
 478         CPAN::Shell->install('Module::Build::Compat')
 479           or die " *** Cannot install without Module::Build.  Exiting ...\n";
 480
 481         chdir $cwd or die "Cannot chdir() back to $cwd: $!";
 482     }
 483     eval "use Module::Build::Compat 0.02; 1" or die $@;
 484     use lib '_build/lib';
 485     Module::Build::Compat->run_build_pl( args => \@ARGV );
 486     require Module::Build;
 487     Module::Build::Compat->write_makefile( build_class => 'Module::Build' );
 488 __build__
 489 use strict;
 490 use Catalyst::Build;
 491
 492 my $build = Catalyst::Build->new(
 493     create_makefile_pl => 'passthrough',
 494     license            => 'perl',
 495     module_name        => '[% name %]',
 496     requires           => { Catalyst => '5.10' },
 497     create_makefile_pl => 'passthrough',
 498     script_files       => [ glob('script/*') ],
 499     test_files         => [ glob('t/*.t'), glob('t/*/*.t') ]
 500 );
 501 $build->create_build_script;
 502 __readme__
 503 Run script/[% appprefix %]_server.pl to test the application.
 504 __changes__
 505 This file documents the revision history for Perl extension [% name %].
 506 0.01  [% time %]
 507         - initial revision, generated by Catalyst
 508 __apptest__
 509 use Test::More tests => 2;
 510 use_ok( Catalyst::Test, '[% name %]' );
 511
 512 ok( request('/')->is_success );
 513 __podtest__
 514 use Test::More;
 515
 516 eval "use Test::Pod 1.14";
 517 plan skip_all => 'Test::Pod 1.14 required' if $@;
 518 plan skip_all => 'set TEST_POD to enable this test' unless $ENV{TEST_POD};
 519
 520 all_pod_files_ok();
 521 __podcoveragetest__
 522 use Test::More;
 523
 524 eval "use Test::Pod::Coverage 1.04";
 525 plan skip_all => 'Test::Pod::Coverage 1.04 required' if $@;
 526 plan skip_all => 'set TEST_POD to enable this test' unless $ENV{TEST_POD};
 527
 528 all_pod_coverage_ok();
 529 __cgi__
 530 [% startperl %] -w
 531 BEGIN { $ENV{CATALYST_ENGINE} ||= 'CGI' }
 532
 533 use strict;
 534 use FindBin;
 535 use lib "$FindBin::Bin/../lib";
 536 use [% name %];
 537
 538 [% name %]->run;
 539
 540 1;
 541
 542 =head1 NAME
 543
 544 cgi - Catalyst CGI
 545
 546 =head1 SYNOPSIS
 547
 548 See L<Catalyst::Manual>
 549
 550 =head1 DESCRIPTION
 551
 552 Run a Catalyst application as cgi.
 553
 554 =head1 AUTHOR
 555
 556 Sebastian Riedel, C<sri@oook.de>
 557
 558 =head1 COPYRIGHT
 559
 560 Copyright 2004 Sebastian Riedel. All rights reserved.
 561
 562 This library is free software. You can redistribute it and/or modify
 563 it under the same terms as perl itself.
 564
 565 =cut
 566 __fastcgi__
 567 [% startperl %] -w
 568
 569 BEGIN { $ENV{CATALYST_ENGINE} ||= 'FastCGI' }
 570
 571 use strict;
 572 use FindBin;
 573 use lib "$FindBin::Bin/../lib";
 574 use [% name %];
 575
 576 [% name %]->run;
 577
 578 1;
 579
 580 =head1 NAME
 581
 582 fastcgi - Catalyst FastCGI
 583
 584 =head1 SYNOPSIS
 585
 586 See L<Catalyst::Manual>
 587
 588 =head1 DESCRIPTION
 589
 590 Run a Catalyst application as fastcgi.
 591
 592 =head1 AUTHOR
 593
 594 Sebastian Riedel, C<sri@oook.de>
 595
 596 =head1 COPYRIGHT
 597
 598 Copyright 2004 Sebastian Riedel. All rights reserved.
 599
 600 This library is free software. You can redistribute it and/or modify
 601 it under the same terms as perl itself.
 602
 603 =cut
 604 __server__
 605 [% startperl %] -w
 606
 607 BEGIN {
 608     $ENV{CATALYST_ENGINE} ||= 'HTTP';
 609     $ENV{CATALYST_SCRIPT_GEN} = [% scriptgen %];
 610 }
 611
 612 use strict;
 613 use Getopt::Long;
 614 use Pod::Usage;
 615 use FindBin;
 616 use lib "$FindBin::Bin/../lib";
 617 use [% name %];
 618
 619 my $help = 0;
 620 my $port = 3000;
 621
 622 GetOptions( 'help|?' => \$help, 'port=s' => \$port );
 623
 624 pod2usage(1) if $help;
 625
 626 [% name %]->run($port);
 627
 628 1;
 629
 630 =head1 NAME
 631
 632 server - Catalyst Testserver
 633
 634 =head1 SYNOPSIS
 635
 636 server.pl [options]
 637
 638  Options:
 639    -? -help    display this help and exits
 640    -p -port    port (defaults to 3000)
 641
 642  See also:
 643    perldoc Catalyst::Manual
 644    perldoc Catalyst::Manual::Intro
 645
 646 =head1 DESCRIPTION
 647
 648 Run a Catalyst Testserver for this application.
 649
 650 =head1 AUTHOR
 651
 652 Sebastian Riedel, C<sri@oook.de>
 653
 654 =head1 COPYRIGHT
 655
 656 Copyright 2004 Sebastian Riedel. All rights reserved.
 657
 658 This library is free software. You can redistribute it and/or modify
 659 it under the same terms as perl itself.
 660
 661 =cut
 662 __test__
 663 [% startperl %] -w
 664
 665 BEGIN { $ENV{CATALYST_ENGINE} ||= 'Test' }
 666
 667 use strict;
 668 use Getopt::Long;
 669 use Pod::Usage;
 670 use FindBin;
 671 use lib "$FindBin::Bin/../lib";
 672 use [% name %];
 673
 674 my $help = 0;
 675
 676 GetOptions( 'help|?' => \$help );
 677
 678 pod2usage(1) if ( $help || !$ARGV[0] );
 679
 680 print [% name %]->run($ARGV[0])->content . "\n";
 681
 682 1;
 683
 684 =head1 NAME
 685
 686 test - Catalyst Test
 687
 688 =head1 SYNOPSIS
 689
 690 test.pl [options] uri
 691
 692  Options:
 693    -help    display this help and exits
 694
 695  Examples:
 696    test.pl http://localhost/some_action
 697    test.pl /some_action
 698
 699  See also:
 700    perldoc Catalyst::Manual
 701    perldoc Catalyst::Manual::Intro
 702
 703 =head1 DESCRIPTION
 704
 705 Run a Catalyst action from the comand line.
 706
 707 =head1 AUTHOR
 708
 709 Sebastian Riedel, C<sri@oook.de>
 710
 711 =head1 COPYRIGHT
 712
 713 Copyright 2004 Sebastian Riedel. All rights reserved.
 714
 715 This library is free software. You can redistribute it and/or modify
 716 it under the same terms as perl itself.
 717
 718 =cut
 719 __create__
 720 [% startperl %] -w
 721
 722 use strict;
 723 use Getopt::Long;
 724 use Pod::Usage;
 725 use Catalyst::Helper;
 726
 727 my $help = 0;
 728
 729 GetOptions( 'help|?' => \$help );
 730
 731 pod2usage(1) if ( $help || !$ARGV[0] );
 732
 733 my $helper = Catalyst::Helper->new;
 734 pod2usage(1) unless $helper->mk_component( '[% name %]', @ARGV );
 735
 736 1;
 737
 738 =head1 NAME
 739
 740 create - Create a new Catalyst Component
 741
 742 =head1 SYNOPSIS
 743
 744 create.pl [options] model|view|controller name [helper] [options]
 745
 746  Options:
 747    -help    display this help and exits
 748
 749  Examples:
 750    create.pl controller My::Controller
 751    create.pl view My::View
 752    create.pl view MyView TT
 753    create.pl view TT TT
 754    create.pl model My::Model
 755    create.pl model SomeDB CDBI dbi:SQLite:/tmp/my.db
 756    create.pl model AnotherDB CDBI dbi:Pg:dbname=foo root 4321
 757
 758  See also:
 759    perldoc Catalyst::Manual
 760    perldoc Catalyst::Manual::Intro
 761
 762 =head1 DESCRIPTION
 763
 764 Create a new Catalyst Component.
 765
 766 =head1 AUTHOR
 767
 768 Sebastian Riedel, C<sri\@oook.de>
 769
 770 =head1 COPYRIGHT
 771
 772 Copyright 2004 Sebastian Riedel. All rights reserved.
 773
 774 This library is free software. You can redistribute it and/or modify
 775 it under the same terms as perl itself.
 776
 777 =cut
 778 __compclass__
 779 package [% class %];
 780
 781 use strict;
 782 use base 'Catalyst::Base';
 783
 784 =head1 NAME
 785
 786 [% class %] - Catalyst component
 787
 788 =head1 SYNOPSIS
 789
 790 See L<[% app %]>
 791
 792 =head1 DESCRIPTION
 793
 794 Catalyst component.
 795 [% IF type == 'C' %]
 796 =head1 METHODS
 797
 798 =over 4
 799
 800 =item default
 801
 802 =cut
 803
 804 sub default : Private {
 805     my ( $self, $c ) = @_;
 806     $c->res->output('Congratulations, [% class %] is on Catalyst!');
 807 }
 808
 809 =back
 810
 811 [% END %]
 812 =head1 AUTHOR
 813
 814 [%author%]
 815
 816 =head1 LICENSE
 817
 818 This library is free software . You can redistribute it and/or modify
 819 it under the same terms as perl itself.
 820
 821 =cut
 822
 823 1;
 824 __comptest__
 825 [% IF type == 'C' %]
 826 use Test::More tests => 3;
 827 use_ok( Catalyst::Test, '[% app %]' );
 828 use_ok('[% class %]');
 829
 830 ok( request('[% prefix %]')->is_success );
 831 [% ELSE %]
 832 use Test::More tests => 1;
 833 use_ok('[% class %]');
 834 [% END %]