lib/Catalyst/Helper.pm

   1 package Catalyst::Helper;
   2
   3 use strict;
   4 use base 'Class::Accessor::Fast';
   5 use Config;
   6 use File::Spec;
   7 use File::Path;
   8 use IO::File;
   9 use FindBin;
  10
  11 =head1 NAME
  12
  13 Catalyst::Helper - Bootstrap a Catalyst application
  14
  15 =head1 SYNOPSIS
  16
  17 See L<Catalyst::Manual::Intro>
  18
  19 =head1 DESCRIPTION
  20
  21 Bootstrap a Catalyst application.
  22
  23 =head2 METHODS
  24
  25 =head3 mk_app
  26
  27 =cut
  28
  29 sub mk_app {
  30     my ( $self, $name ) = @_;
  31     return 0 if $name =~ /[^\w\:]/;
  32     $self->{name} = $name;
  33     $self->{dir}  = $name;
  34     $self->{dir} =~ s/\:\:/-/g;
  35     $self->_mk_dirs;
  36     $self->_mk_appclass;
  37     $self->_mk_makefile;
  38     $self->_mk_readme;
  39     $self->_mk_changes;
  40     $self->_mk_apptest;
  41     $self->_mk_cgi;
  42     $self->_mk_fcgi;
  43     $self->_mk_server;
  44     $self->_mk_test;
  45     $self->_mk_create;
  46     return 1;
  47 }
  48
  49 =head3 mk_component
  50
  51 =cut
  52
  53 sub mk_component {
  54     my $self = shift;
  55     my $app  = shift;
  56     $self->{app} = $app;
  57     $self->{base} = File::Spec->catdir( $FindBin::Bin, '..' );
  58     unless ( $_[0] =~ /^model|m|view|v|controller|c\$/i ) {
  59         my $helper = shift;
  60         my @args   = @_;
  61         my $class  = "Catalyst::Helper::$helper";
  62         eval "require $class";
  63         die qq/Couldn't load helper "$class", "$@"/ if $@;
  64         if ( $class->can('mk_stuff') ) {
  65             return 1 unless $class->mk_stuff( $self, @args );
  66         }
  67     }
  68     else {
  69         my $type   = shift;
  70         my $name   = shift;
  71         my $helper = shift;
  72         my @args   = @_;
  73         return 0 if $name =~ /[^\w\:]/;
  74         $type = 'M' if $type =~ /model|m/i;
  75         $type = 'V' if $type =~ /view|v/i;
  76         $type = 'C' if $type =~ /controller|c/i;
  77         $self->{type}  = $type;
  78         $self->{name}  = $name;
  79         $self->{class} = "$app\::$type\::$name";
  80
  81         # Class
  82         my $appdir = File::Spec->catdir( split /\:\:/, $app );
  83         my $path =
  84           File::Spec->catdir( $FindBin::Bin, '..', 'lib', $appdir, $type );
  85         my $file = $name;
  86         if ( $name =~ /\:/ ) {
  87             my @path = split /\:\:/, $name;
  88             $file = pop @path;
  89             $path = File::Spec->catdir( $path, @path );
  90             mkpath $path;
  91         }
  92         $file = File::Spec->catfile( $path, "$file.pm" );
  93         $self->{file} = $file;
  94
  95         # Test
  96         $self->{test_dir} = File::Spec->catdir( $FindBin::Bin, '..', 't' );
  97         $self->{test}     = $self->next_test;
  98
  99         # Helper
 100         if ($helper) {
 101             my $comp = 'Model';
 102             $comp = 'View'       if $type eq 'V';
 103             $comp = 'Controller' if $type eq 'C';
 104             my $class = "Catalyst::Helper::$comp\::$helper";
 105             eval "require $class";
 106             die qq/Couldn't load helper "$class", "$@"/ if $@;
 107             if ( $class->can('mk_compclass') ) {
 108                 return 1 unless $class->mk_compclass( $self, @args );
 109             }
 110             else { return 1 unless $self->_mk_compclass }
 111
 112             if ( $class->can('mk_comptest') ) {
 113                 $class->mk_comptest( $self, @args );
 114             }
 115             else { $self->_mk_comptest }
 116         }
 117
 118         # Fallback
 119         else {
 120             return 1 unless $self->_mk_compclass;
 121             $self->_mk_comptest;
 122         }
 123     }
 124     return 1;
 125 }
 126
 127 =head3 mk_dir
 128
 129 =cut
 130
 131 sub mk_dir {
 132     my ( $self, $dir ) = @_;
 133     if ( -d $dir ) {
 134         print qq/ exists "$dir"\n/;
 135         return 0;
 136     }
 137     if ( mkpath $dir) {
 138         print qq/created "$dir"\n/;
 139         return 1;
 140     }
 141     die qq/Couldn't create "$dir", "$!"/;
 142 }
 143
 144 =head3 mk_file
 145
 146 =cut
 147
 148 sub mk_file {
 149     my ( $self, $file, $content ) = @_;
 150     if ( -e $file ) {
 151         print qq/ exists "$file"\n/;
 152         return 0;
 153     }
 154     if ( my $f = IO::File->new("> $file") ) {
 155         print $f $content;
 156         print qq/created "$file"\n/;
 157         return 1;
 158     }
 159     die qq/Couldn't create "$file", "$!"/;
 160 }
 161
 162 =head3 next_test
 163
 164 =cut
 165
 166 sub next_test {
 167     my ( $self, $tname ) = @_;
 168     if ($tname) { $tname = "$tname.t" }
 169     else {
 170         my $name   = $self->{name};
 171         my $prefix = $name;
 172         $prefix =~ s/::/_/g;
 173         $prefix         = lc $prefix;
 174         $tname          = $prefix . '.t';
 175         $self->{prefix} = $prefix;
 176     }
 177     my $dir  = $self->{test_dir};
 178     my $type = lc $self->{type};
 179     return File::Spec->catfile( $dir, $type, $tname );
 180 }
 181
 182 sub _mk_dirs {
 183     my $self = shift;
 184     $self->mk_dir( $self->{dir} );
 185     $self->{script} = File::Spec->catdir( $self->{dir}, 'script' );
 186     $self->mk_dir( $self->{script} );
 187     $self->{lib} = File::Spec->catdir( $self->{dir}, 'lib' );
 188     $self->mk_dir( $self->{lib} );
 189     $self->{root} = File::Spec->catdir( $self->{dir}, 'root' );
 190     $self->mk_dir( $self->{root} );
 191     $self->{t} = File::Spec->catdir( $self->{dir}, 't' );
 192     $self->mk_dir( $self->{t} );
 193     $self->mk_dir( File::Spec->catdir( $self->{t}, 'm' ) );
 194     $self->mk_dir( File::Spec->catdir( $self->{t}, 'v' ) );
 195     $self->mk_dir( File::Spec->catdir( $self->{t}, 'c' ) );
 196     $self->{class} = File::Spec->catdir( split( /\:\:/, $self->{name} ) );
 197     $self->{mod} = File::Spec->catdir( $self->{lib}, $self->{class} );
 198     $self->mk_dir( $self->{mod} );
 199     $self->{m} = File::Spec->catdir( $self->{mod}, 'M' );
 200     $self->mk_dir( $self->{m} );
 201     $self->{v} = File::Spec->catdir( $self->{mod}, 'V' );
 202     $self->mk_dir( $self->{v} );
 203     $self->{c} = File::Spec->catdir( $self->{mod}, 'C' );
 204     $self->mk_dir( $self->{c} );
 205     $self->{base} = File::Spec->rel2abs( $self->{dir} );
 206 }
 207
 208 sub _mk_appclass {
 209     my $self = shift;
 210     my $mod  = $self->{mod};
 211     my $name = $self->{name};
 212     my $base = $self->{base};
 213     $self->mk_file( "$mod.pm", <<"EOF");
 214 package $name;
 215
 216 use strict;
 217 use Catalyst qw/-Debug/;
 218
 219 our \$VERSION = '0.01';
 220
 221 $name->config(
 222     name => '$name',
 223     root => '$base/root',
 224 );
 225
 226 $name->action(
 227
 228     '!default' => sub {
 229         my ( \$self, \$c ) = \@_;
 230         \$c->res->output('Congratulations, $name is on Catalyst!');
 231     },
 232
 233 );
 234
 235 =head1 NAME
 236
 237 $name - A very nice application
 238
 239 =head1 SYNOPSIS
 240
 241     Very simple to use
 242
 243 =head1 DESCRIPTION
 244
 245 Very nice application.
 246
 247 =head1 AUTHOR
 248
 249 Clever guy
 250
 251 =head1 LICENSE
 252
 253 This library is free software . You can redistribute it and/or modify it under
 254 the same terms as perl itself.
 255
 256 =cut
 257
 258 1;
 259 EOF
 260 }
 261
 262 sub _mk_makefile {
 263     my $self  = shift;
 264     my $name  = $self->{name};
 265     my $dir   = $self->{dir};
 266     my $class = $self->{class};
 267     $self->mk_file( "$dir\/Makefile.PL", <<"EOF");
 268 use ExtUtils::MakeMaker;
 269
 270 WriteMakefile(
 271     NAME         => '$name',
 272     VERSION_FROM => 'lib/$class.pm',
 273     PREREQ_PM    => { Catalyst => 0 },
 274     test         => { TESTS => join ' ', ( glob('t/*.t'), glob('t/*/*.t') ) }
 275 );
 276 EOF
 277 }
 278
 279 sub _mk_readme {
 280     my $self = shift;
 281     my $dir  = $self->{dir};
 282     $self->mk_file( "$dir\/README", <<"EOF");
 283 Run script/server.pl to test the application.
 284 EOF
 285 }
 286
 287 sub _mk_changes {
 288     my $self = shift;
 289     my $name = $self->{name};
 290     my $dir  = $self->{dir};
 291     my $time = localtime time;
 292     $self->mk_file( "$dir\/Changes", <<"EOF");
 293 This file documents the revision history for Perl extension $name.
 294
 295 0.01  $time
 296         - initial revision, generated by Catalyst
 297 EOF
 298 }
 299
 300 sub _mk_apptest {
 301     my $self = shift;
 302     my $t    = $self->{t};
 303     my $name = $self->{name};
 304     $self->mk_file( "$t\/01app.t", <<"EOF");
 305 use Test::More tests => 2;
 306 use_ok( Catalyst::Test, '$name' );
 307
 308 ok( request('/')->is_success );
 309 EOF
 310     $self->mk_file( "$t\/02podcoverage.t", <<"EOF");
 311 use Test::More;
 312
 313 eval "use Test::Pod::Coverage 1.04";
 314 plan skip_all => 'Test::Pod::Coverage 1.04 required' if \$@;
 315 plan skip_all => 'set TEST_POD to enable this test' unless \$ENV{TEST_POD};
 316
 317 all_pod_coverage_ok();
 318 EOF
 319 }
 320
 321 sub _mk_cgi {
 322     my $self   = shift;
 323     my $name   = $self->{name};
 324     my $script = $self->{script};
 325     $self->mk_file( "$script\/nph-cgi.pl", <<"EOF");
 326 $Config{startperl} -w
 327
 328 BEGIN {
 329     \$ENV{CATALYST_ENGINE} = 'CGI';
 330     \$ENV{CATALYST_TEST}   = 1;
 331 }
 332
 333 use strict;
 334 use FindBin;
 335 use lib "\$FindBin::Bin/../lib";
 336 use $name;
 337
 338 $name->run;
 339
 340 1;
 341 __END__
 342
 343 =head1 NAME
 344
 345 nph-cgi - Catalyst CGI
 346
 347 =head1 SYNOPSIS
 348
 349 See L<Catalyst::Manual>
 350
 351 =head1 DESCRIPTION
 352
 353 Run a Catalyst application as cgi.
 354
 355 =head1 AUTHOR
 356
 357 Sebastian Riedel, C<sri\@oook.de>
 358
 359 =head1 COPYRIGHT
 360
 361 Copyright 2004 Sebastian Riedel. All rights reserved.
 362
 363 This library is free software. You can redistribute it and/or modify it under
 364 the same terms as perl itself.
 365
 366 =cut
 367 EOF
 368     chmod 0700, "$script/nph-cgi.pl";
 369 }
 370
 371 sub _mk_fcgi {
 372     my $self   = shift;
 373     my $name   = $self->{name};
 374     my $script = $self->{script};
 375     $self->mk_file( "$script\/fcgi.pl", <<"EOF");
 376 $Config{startperl} -w
 377
 378 BEGIN {
 379     \$ENV{CATALYST_ENGINE} = 'CGI';
 380     \$ENV{CATALYST_TEST}   = 1;
 381 }
 382
 383 use strict;
 384 use FindBin;
 385 use lib "\$FindBin::Bin/../lib";
 386 use FCGI;
 387 use $name;
 388
 389 my \$request = FCGI::Request();
 390 while ( \$request->Accept() >= 0 ) {
 391     my \$output;
 392     {
 393         local(*STDOUT);
 394         open( STDOUT, '>', \\\$output );
 395         $name->run;
 396     }
 397     \$output =~ s!^HTTP/\\d+.\\d+ \\d\\d\\d.*?\\n!!s;
 398     print \$output;
 399 }
 400
 401 1;
 402 __END__
 403
 404 =head1 NAME
 405
 406 fcgi - Catalyst FCGI
 407
 408 =head1 SYNOPSIS
 409
 410 See L<Catalyst::Manual>
 411
 412 =head1 DESCRIPTION
 413
 414 Run a Catalyst application as fcgi.
 415
 416 =head1 AUTHOR
 417
 418 Sebastian Riedel, C<sri\@oook.de>
 419
 420 =head1 COPYRIGHT
 421
 422 Copyright 2004 Sebastian Riedel. All rights reserved.
 423
 424 This library is free software. You can redistribute it and/or modify it under
 425 the same terms as perl itself.
 426
 427 =cut
 428 EOF
 429     chmod 0700, "$script/fcgi.pl";
 430 }
 431
 432 sub _mk_server {
 433     my $self   = shift;
 434     my $name   = $self->{name};
 435     my $script = $self->{script};
 436     $self->mk_file( "$script\/server.pl", <<"EOF");
 437 $Config{startperl} -w
 438
 439 BEGIN {
 440     \$ENV{CATALYST_ENGINE} = 'Server';
 441     \$ENV{CATALYST_TEST}   = 1;
 442 }
 443
 444 use strict;
 445 use Getopt::Long;
 446 use Pod::Usage;
 447 use FindBin;
 448 use lib "\$FindBin::Bin/../lib";
 449 use $name;
 450
 451 my \$help = 0;
 452 my \$port = 3000;
 453
 454 GetOptions( 'help|?' => \\\$help, 'port=s' => \\\$port );
 455
 456 pod2usage(1) if \$help;
 457
 458 $name->run(\$port);
 459
 460 1;
 461 __END__
 462
 463 =head1 NAME
 464
 465 server - Catalyst Testserver
 466
 467 =head1 SYNOPSIS
 468
 469 server.pl [options]
 470
 471  Options:
 472    -? -help    display this help and exits
 473    -p -port    port (defaults to 3000)
 474
 475  See also:
 476    perldoc Catalyst::Manual
 477    perldoc Catalyst::Manual::Intro
 478
 479 =head1 DESCRIPTION
 480
 481 Run a Catalyst Testserver for this application.
 482
 483 =head1 AUTHOR
 484
 485 Sebastian Riedel, C<sri\@oook.de>
 486
 487 =head1 COPYRIGHT
 488
 489 Copyright 2004 Sebastian Riedel. All rights reserved.
 490
 491 This library is free software. You can redistribute it and/or modify it under
 492 the same terms as perl itself.
 493
 494 =cut
 495 EOF
 496     chmod 0700, "$script/server.pl";
 497 }
 498
 499 sub _mk_test {
 500     my $self   = shift;
 501     my $name   = $self->{name};
 502     my $script = $self->{script};
 503     $self->mk_file( "$script/test.pl", <<"EOF");
 504 $Config{startperl} -w
 505
 506 use strict;
 507 use Getopt::Long;
 508 use Pod::Usage;
 509 use FindBin;
 510 use lib "\$FindBin::Bin/../lib";
 511
 512 my \$help = 0;
 513
 514 GetOptions( 'help|?' => \\\$help );
 515
 516 pod2usage(1) if ( \$help || !\$ARGV[0] );
 517
 518 require Catalyst::Test;
 519 import Catalyst::Test '$name';
 520
 521 print get(\$ARGV[0]) . "\n";
 522
 523 1;
 524 __END__
 525
 526 =head1 NAME
 527
 528 test - Catalyst Test
 529
 530 =head1 SYNOPSIS
 531
 532 test.pl [options] uri
 533
 534  Options:
 535    -help    display this help and exits
 536
 537  Examples:
 538    test.pl http://localhost/some_action
 539    test.pl /some_action
 540
 541  See also:
 542    perldoc Catalyst::Manual
 543    perldoc Catalyst::Manual::Intro
 544
 545 =head1 DESCRIPTION
 546
 547 Run a Catalyst action from the comand line.
 548
 549 =head1 AUTHOR
 550
 551 Sebastian Riedel, C<sri\@oook.de>
 552
 553 =head1 COPYRIGHT
 554
 555 Copyright 2004 Sebastian Riedel. All rights reserved.
 556
 557 This library is free software. You can redistribute it and/or modify it under
 558 the same terms as perl itself.
 559
 560 =cut
 561 EOF
 562     chmod 0700, "$script/test.pl";
 563 }
 564
 565 sub _mk_create {
 566     my $self   = shift;
 567     my $name   = $self->{name};
 568     my $script = $self->{script};
 569     $self->mk_file( "$script\/create.pl", <<"EOF");
 570 $Config{startperl} -w
 571
 572 use strict;
 573 use Getopt::Long;
 574 use Pod::Usage;
 575 use Catalyst::Helper;
 576
 577 my \$help = 0;
 578
 579 GetOptions( 'help|?' => \$help );
 580
 581 pod2usage(1) if ( \$help || !\$ARGV[0] );
 582
 583 my \$helper = Catalyst::Helper->new;
 584 pod2usage(1) unless \$helper->mk_component( '$name', \@ARGV );
 585
 586 1;
 587 __END__
 588
 589 =head1 NAME
 590
 591 create - Create a new Catalyst Component
 592
 593 =head1 SYNOPSIS
 594
 595 create.pl [options] model|view|controller name [helper] [options]
 596
 597  Options:
 598    -help    display this help and exits
 599
 600  Examples:
 601    create.pl controller My::Controller
 602    create.pl view My::View
 603    create.pl view MyView TT
 604    create.pl view TT TT
 605    create.pl model My::Model
 606    create.pl model SomeDB CDBI dbi:SQLite:/tmp/my.db
 607    create.pl model AnotherDB CDBI dbi:Pg:dbname=foo root 4321
 608    create.pl Ajax
 609
 610  See also:
 611    perldoc Catalyst::Manual
 612    perldoc Catalyst::Manual::Intro
 613
 614 =head1 DESCRIPTION
 615
 616 Create a new Catalyst Component.
 617
 618 =head1 AUTHOR
 619
 620 Sebastian Riedel, C<sri\@oook.de>
 621
 622 =head1 COPYRIGHT
 623
 624 Copyright 2004 Sebastian Riedel. All rights reserved.
 625
 626 This library is free software. You can redistribute it and/or modify it under
 627 the same terms as perl itself.
 628
 629 =cut
 630 EOF
 631     chmod 0700, "$script/create.pl";
 632 }
 633
 634 sub _mk_compclass {
 635     my $self   = shift;
 636     my $app    = $self->{app};
 637     my $class  = $self->{class};
 638     my $type   = $self->{type};
 639     my $action = '';
 640     $action = <<"EOF" if $type eq 'C';
 641
 642 $app->action(
 643
 644     '!?default' => sub {
 645         my ( \$self, \$c ) = \@_;
 646         \$c->res->output('Congratulations, $class is on Catalyst!');
 647     },
 648
 649 );
 650 EOF
 651     my $file = $self->{file};
 652     return $self->mk_file( "$file", <<"EOF");
 653 package $class;
 654
 655 use strict;
 656 use base 'Catalyst::Base';
 657 $action
 658 =head1 NAME
 659
 660 $class - A Component
 661
 662 =head1 SYNOPSIS
 663
 664     Very simple to use
 665
 666 =head1 DESCRIPTION
 667
 668 Very nice component.
 669
 670 =head1 AUTHOR
 671
 672 Clever guy
 673
 674 =head1 LICENSE
 675
 676 This library is free software . You can redistribute it and/or modify it under
 677 the same terms as perl itself.
 678
 679 =cut
 680
 681 1;
 682 EOF
 683 }
 684
 685 sub _mk_comptest {
 686     my $self   = shift;
 687     my $prefix = $self->{prefix};
 688     my $type   = $self->{type};
 689     my $class  = $self->{class};
 690     my $app    = $self->{app};
 691     my $test   = $self->{test};
 692     if ( $self->{type} eq 'C' ) {
 693         $self->mk_file( "$test", <<"EOF");
 694 use Test::More tests => 3;
 695 use_ok( Catalyst::Test, '$app' );
 696 use_ok('$class');
 697
 698 ok( request('$prefix')->is_success );
 699 EOF
 700     }
 701     else {
 702         $self->mk_file( "$test", <<"EOF");
 703 use Test::More tests => 1;
 704 use_ok('$class');
 705 EOF
 706     }
 707 }
 708
 709 =head1 HELPERS
 710
 711 Helpers are classes that provide two methods.
 712
 713     * mk_compclass - creates the Component class
 714     * mk_comptest  - creates the Component test
 715
 716 So when you call C<bin/create view MyView TT>, create would try to execute
 717 Catalyst::Helper::View::TT->mk_compclass and
 718 Catalyst::Helper::View::TT->mk_comptest.
 719
 720 See L<Catalyst::Helper::View::TT> and L<Catalyst::Helper::Model::CDBI> for
 721 examples.
 722
 723 All helper classes should be under one of the following namespaces.
 724
 725     Catalyst::Helper::Model::
 726     Catalyst::Helper::View::
 727     Catalyst::Helper::Controller::
 728
 729 =head1 SEE ALSO
 730
 731 L<Catalyst::Manual>, L<Catalyst::Test>, L<Catalyst::Request>,
 732 L<Catalyst::Response>, L<Catalyst>
 733
 734 =head1 AUTHOR
 735
 736 Sebastian Riedel, C<sri@oook.de>
 737
 738 =head1 LICENSE
 739
 740 This library is free software . You can redistribute it and/or modify it under
 741 the same terms as perl itself.
 742
 743 =cut
 744
 745 1;