lib/Catalyst/Engine/HTTP.pm

   1 package Catalyst::Engine::HTTP;
   2
   3 use strict;
   4 use base 'Catalyst::Engine::CGI';
   5 use Errno 'EWOULDBLOCK';
   6 use HTTP::Status;
   7 use NEXT;
   8 use Socket;
   9 use IO::Socket::INET ();
  10 use IO::Select       ();
  11
  12 # For PAR
  13 require Catalyst::Engine::HTTP::Restarter;
  14 require Catalyst::Engine::HTTP::Restarter::Watcher;
  15
  16 =head1 NAME
  17
  18 Catalyst::Engine::HTTP - Catalyst HTTP Engine
  19
  20 =head1 SYNOPSIS
  21
  22 A script using the Catalyst::Engine::HTTP module might look like:
  23
  24     #!/usr/bin/perl -w
  25
  26     BEGIN {  $ENV{CATALYST_ENGINE} = 'HTTP' }
  27
  28     use strict;
  29     use lib '/path/to/MyApp/lib';
  30     use MyApp;
  31
  32     MyApp->run;
  33
  34 =head1 DESCRIPTION
  35
  36 This is the Catalyst engine specialized for development and testing.
  37
  38 =head1 METHODS
  39
  40 =head2 $self->finalize_headers($c)
  41
  42 =cut
  43
  44 sub finalize_headers {
  45     my ( $self, $c ) = @_;
  46     my $protocol = $c->request->protocol;
  47     my $status   = $c->response->status;
  48     my $message  = status_message($status);
  49     print "$protocol $status $message\015\012";
  50     $c->response->headers->date(time);
  51     $c->response->headers->header(
  52         Connection => $self->_keep_alive ? 'keep-alive' : 'close' );
  53     $self->NEXT::finalize_headers($c);
  54 }
  55
  56 =head2 $self->finalize_read($c)
  57
  58 =cut
  59
  60 sub finalize_read {
  61     my ( $self, $c ) = @_;
  62
  63     # Never ever remove this, it would result in random length output
  64     # streams if STDIN eq STDOUT (like in the HTTP engine)
  65     *STDIN->blocking(1);
  66
  67     return $self->NEXT::finalize_read($c);
  68 }
  69
  70 =head2 $self->prepare_read($c)
  71
  72 =cut
  73
  74 sub prepare_read {
  75     my ( $self, $c ) = @_;
  76
  77     # Set the input handle to non-blocking
  78     *STDIN->blocking(0);
  79
  80     return $self->NEXT::prepare_read($c);
  81 }
  82
  83 =head2 $self->read_chunk($c, $buffer, $length)
  84
  85 =cut
  86
  87 sub read_chunk {
  88     my $self = shift;
  89     my $c    = shift;
  90
  91     # support for non-blocking IO
  92     my $rin = '';
  93     vec( $rin, *STDIN->fileno, 1 ) = 1;
  94
  95   READ:
  96     {
  97         select( $rin, undef, undef, undef );
  98         my $rc = *STDIN->sysread(@_);
  99         if ( defined $rc ) {
 100             return $rc;
 101         }
 102         else {
 103             next READ if $! == EWOULDBLOCK;
 104             return;
 105         }
 106     }
 107 }
 108
 109 =head2 run
 110
 111 =cut
 112
 113 # A very very simple HTTP server that initializes a CGI environment
 114 sub run {
 115     my ( $self, $class, $port, $host, $options ) = @_;
 116
 117     $options ||= {};
 118
 119     my $restart = 0;
 120     local $SIG{CHLD} = 'IGNORE';
 121
 122     my $allowed = $options->{allowed} || { '127.0.0.1' => '255.255.255.255' };
 123     my $addr = $host ? inet_aton($host) : INADDR_ANY;
 124     if ( $addr eq INADDR_ANY ) {
 125         require Sys::Hostname;
 126         $host = lc Sys::Hostname::hostname();
 127     }
 128     else {
 129         $host = gethostbyaddr( $addr, AF_INET ) || inet_ntoa($addr);
 130     }
 131
 132     # Handle requests
 133
 134     # Setup socket
 135     my $daemon = IO::Socket::INET->new(
 136         Listen    => SOMAXCONN,
 137         LocalAddr => inet_ntoa($addr),
 138         LocalPort => $port,
 139         Proto     => 'tcp',
 140         ReuseAddr => 1,
 141         Type      => SOCK_STREAM,
 142       )
 143       or die "Couldn't create daemon: $!";
 144
 145     my $url = "http://$host";
 146     $url .= ":$port" unless $port == 80;
 147
 148     print "You can connect to your server at $url\n";
 149
 150     $self->_keep_alive( $options->{keepalive} || 0 );
 151
 152     my $parent = $$;
 153     my $pid    = undef;
 154     while ( accept( Remote, $daemon ) )
 155     {    # TODO: get while ( my $remote = $daemon->accept ) to work
 156
 157         select Remote;
 158
 159         # Request data
 160
 161         Remote->blocking(1);
 162
 163         next
 164           unless my ( $method, $uri, $protocol ) =
 165           $self->_parse_request_line( \*Remote );
 166
 167         unless ( uc($method) eq 'RESTART' ) {
 168
 169             # Fork
 170             if ( $options->{fork} ) { next if $pid = fork }
 171
 172             $self->_handler( $class, $port, $method, $uri, $protocol );
 173
 174             $daemon->close if defined $pid;
 175
 176         }
 177         else {
 178             my $sockdata = $self->_socket_data( \*Remote );
 179             my $ipaddr   = _inet_addr( $sockdata->{peeraddr} );
 180             my $ready    = 0;
 181             foreach my $ip ( keys %$allowed ) {
 182                 my $mask = $allowed->{$ip};
 183                 $ready = ( $ipaddr & _inet_addr($mask) ) == _inet_addr($ip);
 184                 last if $ready;
 185             }
 186             if ($ready) {
 187                 $restart = 1;
 188                 last;
 189             }
 190         }
 191
 192         exit if defined $pid;
 193     }
 194     continue {
 195         close Remote;
 196     }
 197     $daemon->close;
 198
 199     if ($restart) {
 200         $SIG{CHLD} = 'DEFAULT';
 201         wait;
 202
 203         ### if the standalone server was invoked with perl -I .. we will loose
 204         ### those include dirs upon re-exec. So add them to PERL5LIB, so they
 205         ### are available again for the exec'ed process --kane
 206         use Config;
 207         $ENV{PERL5LIB} .= join $Config{path_sep}, @INC;
 208
 209         exec $^X . ' "' . $0 . '" ' . join( ' ', @{ $options->{argv} } );
 210     }
 211
 212     exit;
 213 }
 214
 215 sub _handler {
 216     my ( $self, $class, $port, $method, $uri, $protocol ) = @_;
 217
 218     # Ignore broken pipes as an HTTP server should
 219     local $SIG{PIPE} = sub { close Remote };
 220
 221     local *STDIN  = \*Remote;
 222     local *STDOUT = \*Remote;
 223
 224     # We better be careful and just use 1.0
 225     $protocol = '1.0';
 226
 227     my $sockdata    = $self->_socket_data( \*Remote );
 228     my %copy_of_env = %ENV;
 229
 230     my $sel = IO::Select->new;
 231     $sel->add( \*STDIN );
 232
 233     while (1) {
 234         my ( $path, $query_string ) = split /\?/, $uri, 2;
 235
 236         # Initialize CGI environment
 237         local %ENV = (
 238             PATH_INFO    => $path         || '',
 239             QUERY_STRING => $query_string || '',
 240             REMOTE_ADDR     => $sockdata->{peeraddr},
 241             REMOTE_HOST     => $sockdata->{peername},
 242             REQUEST_METHOD  => $method || '',
 243             SERVER_NAME     => $sockdata->{localname},
 244             SERVER_PORT     => $port,
 245             SERVER_PROTOCOL => "HTTP/$protocol",
 246             %copy_of_env,
 247         );
 248
 249         # Parse headers
 250         if ( $protocol >= 1 ) {
 251             while (1) {
 252                 my $line = $self->_get_line( \*STDIN );
 253                 last if $line eq '';
 254                 next
 255                   unless my ( $name, $value ) =
 256                   $line =~ m/\A(\w(?:-?\w+)*):\s(.+)\z/;
 257
 258                 $name = uc $name;
 259                 $name = 'COOKIE' if $name eq 'COOKIES';
 260                 $name =~ tr/-/_/;
 261                 $name = 'HTTP_' . $name
 262                   unless $name =~ m/\A(?:CONTENT_(?:LENGTH|TYPE)|COOKIE)\z/;
 263                 if ( exists $ENV{$name} ) {
 264                     $ENV{$name} .= "; $value";
 265                 }
 266                 else {
 267                     $ENV{$name} = $value;
 268                 }
 269             }
 270         }
 271
 272         # Pass flow control to Catalyst
 273         $class->handle_request;
 274
 275         my $connection = lc $ENV{HTTP_CONNECTION};
 276         last
 277           unless $self->_keep_alive()
 278           && index( $connection, 'keep-alive' ) > -1
 279           && index( $connection, 'te' ) == -1          # opera stuff
 280           && $sel->can_read(5);
 281
 282         last
 283           unless ( $method, $uri, $protocol ) =
 284           $self->_parse_request_line( \*STDIN );
 285     }
 286
 287     close Remote;
 288 }
 289
 290 sub _keep_alive {
 291     my ( $self, $keepalive ) = @_;
 292
 293     my $r = $self->{_keepalive} || 0;
 294     $self->{_keepalive} = $keepalive if defined $keepalive;
 295
 296     return $r;
 297
 298 }
 299
 300 sub _parse_request_line {
 301     my ( $self, $handle ) = @_;
 302
 303     # Parse request line
 304     my $line = $self->_get_line($handle);
 305     return ()
 306       unless my ( $method, $uri, $protocol ) =
 307       $line =~ m/\A(\w+)\s+(\S+)(?:\s+HTTP\/(\d+(?:\.\d+)?))?\z/;
 308     return ( $method, $uri, $protocol );
 309 }
 310
 311 sub _socket_data {
 312     my ( $self, $handle ) = @_;
 313
 314     my $remote_sockaddr = getpeername($handle);
 315     my ( undef, $iaddr ) = sockaddr_in($remote_sockaddr);
 316     my $local_sockaddr = getsockname($handle);
 317     my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);
 318
 319     my $data = {
 320         peername => gethostbyaddr( $iaddr, AF_INET ) || "localhost",
 321         peeraddr => inet_ntoa($iaddr) || "127.0.0.1",
 322         localname => gethostbyaddr( $localiaddr, AF_INET ) || "localhost",
 323         localaddr => inet_ntoa($localiaddr) || "127.0.0.1",
 324     };
 325
 326     return $data;
 327 }
 328
 329 sub _get_line {
 330     my ( $self, $handle ) = @_;
 331
 332     my $line = '';
 333
 334     while ( sysread( $handle, my $byte, 1 ) ) {
 335         last if $byte eq "\012";    # eol
 336         $line .= $byte;
 337     }
 338
 339     1 while $line =~ s/\s\z//;
 340
 341     return $line;
 342 }
 343
 344 sub _inet_addr { unpack "N*", inet_aton( $_[0] ) }
 345
 346 =head1 SEE ALSO
 347
 348 L<Catalyst>, L<Catalyst::Engine>.
 349
 350 =head1 AUTHORS
 351
 352 Sebastian Riedel, <sri@cpan.org>
 353
 354 Dan Kubb, <dan.kubb-cpan@onautopilot.com>
 355
 356 Sascha Kiefer, <esskar@cpan.org>
 357
 358 =head1 THANKS
 359
 360 Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.
 361
 362 =head1 COPYRIGHT
 363
 364 This program is free software, you can redistribute it and/or modify it under
 365 the same terms as Perl itself.
 366
 367 =cut
 368
 369 1;