lib/Catalyst/Engine/HTTP.pm

   1 package Catalyst::Engine::HTTP;
   2
   3 use strict;
   4 use base 'Catalyst::Engine::Test';
   5
   6 use IO::Socket qw(AF_INET SOCK_STREAM SOMAXCONN);
   7
   8 =head1 NAME
   9
  10 Catalyst::Engine::HTTP - Catalyst HTTP Engine
  11
  12 =head1 SYNOPSIS
  13
  14 A script using the Catalyst::Engine::HTTP module might look like:
  15
  16     #!/usr/bin/perl -w
  17
  18     BEGIN {  $ENV{CATALYST_ENGINE} = 'HTTP' }
  19
  20     use strict;
  21     use lib '/path/to/MyApp/lib';
  22     use MyApp;
  23
  24     MyApp->run;
  25
  26 =head1 DESCRIPTION
  27
  28 This is the Catalyst engine specialized for development and testing.
  29
  30 =head1 OVERLOADED METHODS
  31
  32 This class overloads some methods from C<Catalyst::Engine::Test>.
  33
  34 =over 4
  35
  36 =item $c->run
  37
  38 =cut
  39
  40 $SIG{'PIPE'} = 'IGNORE';
  41
  42 sub run {
  43     my $class = shift;
  44     my $port  = shift || 3000;
  45
  46     my $daemon = Catalyst::Engine::HTTP::Catalyst->new(
  47         Listen    => SOMAXCONN,
  48         LocalPort => $port,
  49         ReuseAddr => 1,
  50         Type      => SOCK_STREAM,
  51     );
  52
  53     unless ($daemon) {
  54         die("Failed to create daemon: $!\n");
  55     }
  56
  57     my $base = URI->new( $daemon->url )->canonical;
  58
  59     printf( "You can connect to your server at %s\n", $base );
  60
  61     while ( my $connection = $daemon->accept ) {
  62
  63         while ( my $request = $connection->get_request ) {
  64
  65             $request->uri->scheme('http');    # Force URI::http
  66             $request->uri->host( $base->host );
  67             $request->uri->port( $base->port );
  68
  69             my $lwp = Catalyst::Engine::Test::LWP->new(
  70                 request  => $request,
  71                 address  => $connection->peerhost,
  72                 hostname => gethostbyaddr( $connection->peeraddr, AF_INET )
  73             );
  74
  75             $class->handler($lwp);
  76             $connection->send_response( $lwp->response );
  77         }
  78
  79         $connection->close;
  80         undef($connection);
  81     }
  82 }
  83
  84 =back
  85
  86 =head1 SEE ALSO
  87
  88 L<Catalyst>, L<HTTP::Daemon>.
  89
  90 =head1 AUTHOR
  91
  92 Sebastian Riedel, C<sri@cpan.org>
  93 Christian Hansen, C<ch@ngmedia.com>
  94
  95 =head1 COPYRIGHT
  96
  97 This program is free software, you can redistribute it and/or modify it under
  98 the same terms as Perl itself.
  99
 100 =cut
 101
 102 package Catalyst::Engine::HTTP::Catalyst;
 103
 104 use strict;
 105 use base 'HTTP::Daemon';
 106
 107 sub product_tokens {
 108     "Catalyst/$Catalyst::VERSION";
 109 }
 110
 111 1;