lib/Catalyst/Engine/HTTP.pm

   1 package Catalyst::Engine::HTTP;
   2
   3 use strict;
   4 use base 'Catalyst::Engine::CGI';
   5 use Data::Dump qw(dump);
   6 use Errno 'EWOULDBLOCK';
   7 use HTTP::Date ();
   8 use HTTP::Headers;
   9 use HTTP::Status;
  10 use NEXT;
  11 use Socket;
  12 use IO::Socket::INET ();
  13 use IO::Select       ();
  14
  15 # For PAR
  16 require Catalyst::Engine::HTTP::Restarter;
  17 require Catalyst::Engine::HTTP::Restarter::Watcher;
  18
  19 use constant CHUNKSIZE => 64 * 1024;
  20 use constant DEBUG     => $ENV{CATALYST_HTTP_DEBUG} || 0;
  21
  22 =head1 NAME
  23
  24 Catalyst::Engine::HTTP - Catalyst HTTP Engine
  25
  26 =head1 SYNOPSIS
  27
  28 A script using the Catalyst::Engine::HTTP module might look like:
  29
  30     #!/usr/bin/perl -w
  31
  32     BEGIN {  $ENV{CATALYST_ENGINE} = 'HTTP' }
  33
  34     use strict;
  35     use lib '/path/to/MyApp/lib';
  36     use MyApp;
  37
  38     MyApp->run;
  39
  40 =head1 DESCRIPTION
  41
  42 This is the Catalyst engine specialized for development and testing.
  43
  44 =head1 METHODS
  45
  46 =head2 $self->finalize_headers($c)
  47
  48 =cut
  49
  50 sub finalize_headers {
  51     my ( $self, $c ) = @_;
  52     my $protocol = $c->request->protocol;
  53     my $status   = $c->response->status;
  54     my $message  = status_message($status);
  55
  56     my @headers;
  57     push @headers, "$protocol $status $message";
  58
  59     $c->response->headers->header( Date => HTTP::Date::time2str(time) );
  60     $c->response->headers->header( Status => $status );
  61
  62     # Should we keep the connection open?
  63     my $connection = $c->request->header('Connection');
  64     if (   $self->{options}->{keepalive}
  65         && $connection
  66         && $connection =~ /^keep-alive$/i
  67     ) {
  68         $c->response->headers->header( Connection => 'keep-alive' );
  69         $self->{_keepalive} = 1;
  70     }
  71     else {
  72         $c->response->headers->header( Connection => 'close' );
  73     }
  74
  75     push @headers, $c->response->headers->as_string("\x0D\x0A");
  76
  77     # Buffer the headers so they are sent with the first write() call
  78     # This reduces the number of TCP packets we are sending
  79     $self->{_header_buf} = join("\x0D\x0A", @headers, '');
  80 }
  81
  82 =head2 $self->finalize_read($c)
  83
  84 =cut
  85
  86 sub finalize_read {
  87     my ( $self, $c ) = @_;
  88
  89     # Never ever remove this, it would result in random length output
  90     # streams if STDIN eq STDOUT (like in the HTTP engine)
  91     *STDIN->blocking(1);
  92
  93     return $self->NEXT::finalize_read($c);
  94 }
  95
  96 =head2 $self->prepare_read($c)
  97
  98 =cut
  99
 100 sub prepare_read {
 101     my ( $self, $c ) = @_;
 102
 103     # Set the input handle to non-blocking
 104     *STDIN->blocking(0);
 105
 106     return $self->NEXT::prepare_read($c);
 107 }
 108
 109 =head2 $self->read_chunk($c, $buffer, $length)
 110
 111 =cut
 112
 113 sub read_chunk {
 114     my $self = shift;
 115     my $c    = shift;
 116
 117     # If we have any remaining data in the input buffer, send it back first
 118     if ( $_[0] = delete $self->{inputbuf} ) {
 119         my $read = length( $_[0] );
 120         DEBUG && warn "read_chunk: Read $read bytes from previous input buffer\n";
 121         return $read;
 122     }
 123
 124     # support for non-blocking IO
 125     my $rin = '';
 126     vec( $rin, *STDIN->fileno, 1 ) = 1;
 127
 128   READ:
 129     {
 130         select( $rin, undef, undef, undef );
 131         my $rc = *STDIN->sysread(@_);
 132         if ( defined $rc ) {
 133             DEBUG && warn "read_chunk: Read $rc bytes from socket\n";
 134             return $rc;
 135         }
 136         else {
 137             next READ if $! == EWOULDBLOCK;
 138             return;
 139         }
 140     }
 141 }
 142
 143 =head2 $self->write($c, $buffer)
 144
 145 Writes the buffer to the client. Can only be called once for a request.
 146
 147 =cut
 148
 149 sub write {
 150     my ( $self, $c, $buffer ) = @_;
 151
 152         # Avoid 'print() on closed filehandle Remote' warnings when using IE
 153         return unless *STDOUT->opened();
 154
 155         my $ret;
 156
 157         # Prepend the headers if they have not yet been sent
 158         if ( my $headers = delete $self->{_header_buf} ) {
 159             DEBUG && warn "write: Wrote headers and first chunk (" . length($headers . $buffer) . " bytes)\n";
 160             $ret = $self->NEXT::write( $c, $headers . $buffer );
 161     }
 162     else {
 163         DEBUG && warn "write: Wrote chunk (" . length($buffer) . " bytes)\n";
 164         $ret = $self->NEXT::write( $c, $buffer );
 165     }
 166
 167     if ( !$ret ) {
 168         $self->{_write_error} = $!;
 169     }
 170
 171     return $ret;
 172 }
 173
 174 =head2 run
 175
 176 =cut
 177
 178 # A very very simple HTTP server that initializes a CGI environment
 179 sub run {
 180     my ( $self, $class, $port, $host, $options ) = @_;
 181
 182     $options ||= {};
 183
 184     $self->{options} = $options;
 185
 186     if ($options->{background}) {
 187         my $child = fork;
 188         die "Can't fork: $!" unless defined($child);
 189         exit if $child;
 190     }
 191
 192     my $restart = 0;
 193     local $SIG{CHLD} = 'IGNORE';
 194
 195     my $allowed = $options->{allowed} || { '127.0.0.1' => '255.255.255.255' };
 196     my $addr = $host ? inet_aton($host) : INADDR_ANY;
 197     if ( $addr eq INADDR_ANY ) {
 198         require Sys::Hostname;
 199         $host = lc Sys::Hostname::hostname();
 200     }
 201     else {
 202         $host = gethostbyaddr( $addr, AF_INET ) || inet_ntoa($addr);
 203     }
 204
 205     # Handle requests
 206
 207     # Setup socket
 208     my $daemon = IO::Socket::INET->new(
 209         Listen    => SOMAXCONN,
 210         LocalAddr => inet_ntoa($addr),
 211         LocalPort => $port,
 212         Proto     => 'tcp',
 213         ReuseAddr => 1,
 214         Type      => SOCK_STREAM,
 215       )
 216       or die "Couldn't create daemon: $!";
 217
 218     my $url = "http://$host";
 219     $url .= ":$port" unless $port == 80;
 220
 221     print "You can connect to your server at $url\n";
 222
 223     if ($options->{background}) {
 224         open STDIN,  "+</dev/null" or die $!;
 225         open STDOUT, ">&STDIN"     or die $!;
 226         open STDERR, ">&STDIN"     or die $!;
 227         if ( $^O !~ /MSWin32/ ) {
 228              require POSIX;
 229              POSIX::setsid()
 230                  or die "Can't start a new session: $!";
 231         }
 232     }
 233
 234     if (my $pidfile = $options->{pidfile}) {
 235         if (! open PIDFILE, "> $pidfile") {
 236             warn("Cannot open: $pidfile: $!");
 237         }
 238         print PIDFILE "$$\n";
 239         close PIDFILE;
 240     }
 241
 242     my $pid = undef;
 243
 244     # Ignore broken pipes as an HTTP server should
 245     local $SIG{PIPE} = 'IGNORE';
 246
 247     # Restart on HUP
 248     local $SIG{HUP} = sub {
 249         $restart = 1;
 250         warn "Restarting server on SIGHUP...\n";
 251     };
 252
 253     LISTEN:
 254     while ( !$restart ) {
 255         while ( accept( Remote, $daemon ) ) {
 256             DEBUG && warn "New connection\n";
 257
 258             select Remote;
 259
 260             Remote->blocking(1);
 261
 262             # Read until we see all headers
 263             $self->{inputbuf} = '';
 264
 265             if ( !$self->_read_headers ) {
 266                 # Error reading, give up
 267                 next LISTEN;
 268             }
 269
 270             my ( $method, $uri, $protocol ) = $self->_parse_request_line;
 271
 272             DEBUG && warn "Parsed request: $method $uri $protocol\n";
 273
 274             next unless $method;
 275
 276             unless ( uc($method) eq 'RESTART' ) {
 277
 278                 # Fork
 279                 if ( $options->{fork} ) { next if $pid = fork }
 280
 281                 $self->_handler( $class, $port, $method, $uri, $protocol );
 282
 283                 if ( my $error = delete $self->{_write_error} ) {
 284                     DEBUG && warn "Write error: $error\n";
 285                     close Remote;
 286                     next LISTEN;
 287                 }
 288
 289                 $daemon->close if defined $pid;
 290             }
 291             else {
 292                 my $sockdata = $self->_socket_data( \*Remote );
 293                 my $ipaddr   = _inet_addr( $sockdata->{peeraddr} );
 294                 my $ready    = 0;
 295                 foreach my $ip ( keys %$allowed ) {
 296                     my $mask = $allowed->{$ip};
 297                     $ready = ( $ipaddr & _inet_addr($mask) ) == _inet_addr($ip);
 298                     last if $ready;
 299                 }
 300                 if ($ready) {
 301                     $restart = 1;
 302                     last;
 303                 }
 304             }
 305
 306             exit if defined $pid;
 307         }
 308         continue {
 309             close Remote;
 310         }
 311     }
 312
 313     $daemon->close;
 314
 315     DEBUG && warn "Shutting down\n";
 316
 317     if ($restart) {
 318         $SIG{CHLD} = 'DEFAULT';
 319         wait;
 320
 321         ### if the standalone server was invoked with perl -I .. we will loose
 322         ### those include dirs upon re-exec. So add them to PERL5LIB, so they
 323         ### are available again for the exec'ed process --kane
 324         use Config;
 325         $ENV{PERL5LIB} .= join $Config{path_sep}, @INC;
 326
 327         exec $^X . ' "' . $0 . '" ' . join( ' ', @{ $options->{argv} } );
 328     }
 329
 330     exit;
 331 }
 332
 333 sub _handler {
 334     my ( $self, $class, $port, $method, $uri, $protocol ) = @_;
 335
 336     local *STDIN  = \*Remote;
 337     local *STDOUT = \*Remote;
 338
 339     # We better be careful and just use 1.0
 340     $protocol = '1.0';
 341
 342     my $sockdata    = $self->_socket_data( \*Remote );
 343     my %copy_of_env = %ENV;
 344
 345     my $sel = IO::Select->new;
 346     $sel->add( \*STDIN );
 347
 348     REQUEST:
 349     while (1) {
 350         my ( $path, $query_string ) = split /\?/, $uri, 2;
 351
 352         # Initialize CGI environment
 353         local %ENV = (
 354             PATH_INFO       => $path         || '',
 355             QUERY_STRING    => $query_string || '',
 356             REMOTE_ADDR     => $sockdata->{peeraddr},
 357             REMOTE_HOST     => $sockdata->{peername},
 358             REQUEST_METHOD  => $method || '',
 359             SERVER_NAME     => $sockdata->{localname},
 360             SERVER_PORT     => $port,
 361             SERVER_PROTOCOL => "HTTP/$protocol",
 362             %copy_of_env,
 363         );
 364
 365         # Parse headers
 366         if ( $protocol >= 1 ) {
 367             $self->_parse_headers;
 368         }
 369
 370         # Pass flow control to Catalyst
 371         $class->handle_request;
 372
 373         DEBUG && warn "Request done\n";
 374
 375         # Allow keepalive requests, this is a hack but we'll support it until
 376         # the next major release.
 377         if ( delete $self->{_keepalive} ) {
 378
 379             DEBUG && warn "Reusing previous connection for keep-alive request\n";
 380
 381             if ( $sel->can_read(1) ) {
 382                 if ( !$self->_read_headers ) {
 383                     # Error reading, give up
 384                     last REQUEST;
 385                 }
 386
 387                 ( $method, $uri, $protocol ) = $self->_parse_request_line;
 388
 389                 DEBUG && warn "Parsed request: $method $uri $protocol\n";
 390
 391                 # Force HTTP/1.0
 392                 $protocol = '1.0';
 393
 394                 next REQUEST;
 395             }
 396
 397             DEBUG && warn "No keep-alive request within 1 second\n";
 398         }
 399
 400         last REQUEST;
 401     }
 402
 403     DEBUG && warn "Closing connection\n";
 404
 405     close Remote;
 406 }
 407
 408 sub _read_headers {
 409     my $self = shift;
 410
 411     while (1) {
 412         my $read = sysread Remote, my $buf, CHUNKSIZE;
 413
 414         if ( !$read ) {
 415             DEBUG && warn "EOF or error: $!\n";
 416             return;
 417         }
 418
 419         DEBUG && warn "Read $read bytes\n";
 420         $self->{inputbuf} .= $buf;
 421         last if $self->{inputbuf} =~ /(\x0D\x0A?\x0D\x0A?|\x0A\x0D?\x0A\x0D?)/s;
 422     }
 423
 424     return 1;
 425 }
 426
 427 sub _parse_request_line {
 428     my $self = shift;
 429
 430     # Parse request line
 431     if ( $self->{inputbuf} !~ s/^(\w+)[ \t]+(\S+)(?:[ \t]+(HTTP\/\d+\.\d+))?[^\012]*\012// ) {
 432         return ();
 433     }
 434
 435     my $method = $1;
 436     my $uri    = $2;
 437     my $proto  = $3 || 'HTTP/0.9';
 438
 439     return ( $method, $uri, $proto );
 440 }
 441
 442 sub _parse_headers {
 443     my $self = shift;
 444
 445     # Copy the buffer for header parsing, and remove the header block
 446     # from the content buffer.
 447     my $buf = $self->{inputbuf};
 448     $self->{inputbuf} =~ s/.*?(\x0D\x0A?\x0D\x0A?|\x0A\x0D?\x0A\x0D?)//s;
 449
 450     # Parse headers
 451     my $headers = HTTP::Headers->new;
 452     my ($key, $val);
 453     HEADER:
 454     while ( $buf =~ s/^([^\012]*)\012// ) {
 455         $_ = $1;
 456         s/\015$//;
 457         if ( /^([\w\-~]+)\s*:\s*(.*)/ ) {
 458             $headers->push_header( $key, $val ) if $key;
 459             ($key, $val) = ($1, $2);
 460         }
 461         elsif ( /^\s+(.*)/ ) {
 462             $val .= " $1";
 463         }
 464         else {
 465             last HEADER;
 466         }
 467     }
 468     $headers->push_header( $key, $val ) if $key;
 469
 470     DEBUG && warn "Parsed headers: " . dump($headers) . "\n";
 471
 472     # Convert headers into ENV vars
 473     $headers->scan( sub {
 474         my ( $key, $val ) = @_;
 475
 476         $key = uc $key;
 477         $key = 'COOKIE' if $key eq 'COOKIES';
 478         $key =~ tr/-/_/;
 479         $key = 'HTTP_' . $key
 480             unless $key =~ m/\A(?:CONTENT_(?:LENGTH|TYPE)|COOKIE)\z/;
 481
 482         if ( exists $ENV{$key} ) {
 483             $ENV{$key} .= ", $val";
 484         }
 485         else {
 486             $ENV{$key} = $val;
 487         }
 488     } );
 489 }
 490
 491 sub _socket_data {
 492     my ( $self, $handle ) = @_;
 493
 494     my $remote_sockaddr       = getpeername($handle);
 495     my ( undef, $iaddr )      = $remote_sockaddr
 496         ? sockaddr_in($remote_sockaddr)
 497         : (undef, undef);
 498
 499     my $local_sockaddr        = getsockname($handle);
 500     my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);
 501
 502     # This mess is necessary to keep IE from crashing the server
 503     my $data = {
 504         peername  => $iaddr
 505             ? ( gethostbyaddr( $iaddr, AF_INET ) || 'localhost' )
 506             : 'localhost',
 507         peeraddr  => $iaddr
 508             ? ( inet_ntoa($iaddr) || '127.0.0.1' )
 509             : '127.0.0.1',
 510         localname => gethostbyaddr( $localiaddr, AF_INET ) || 'localhost',
 511         localaddr => inet_ntoa($localiaddr) || '127.0.0.1',
 512     };
 513
 514     return $data;
 515 }
 516
 517 sub _inet_addr { unpack "N*", inet_aton( $_[0] ) }
 518
 519 =head1 SEE ALSO
 520
 521 L<Catalyst>, L<Catalyst::Engine>.
 522
 523 =head1 AUTHORS
 524
 525 Sebastian Riedel, <sri@cpan.org>
 526
 527 Dan Kubb, <dan.kubb-cpan@onautopilot.com>
 528
 529 Sascha Kiefer, <esskar@cpan.org>
 530
 531 Andy Grundman, <andy@hybridized.org>
 532
 533 =head1 THANKS
 534
 535 Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.
 536
 537 =head1 COPYRIGHT
 538
 539 This program is free software, you can redistribute it and/or modify it under
 540 the same terms as Perl itself.
 541
 542 =cut
 543
 544 1;