lib/Catalyst/Engine/HTTP.pm

   1 package Catalyst::Engine::HTTP;
   2
   3 use Moose;
   4 extends 'Catalyst::Engine::CGI';
   5
   6 use Data::Dump qw(dump);
   7 use Errno 'EWOULDBLOCK';
   8 use HTTP::Date ();
   9 use HTTP::Headers;
  10 use HTTP::Status;
  11 use Socket;
  12 use IO::Socket::INET ();
  13 use IO::Select       ();
  14
  15 use constant CHUNKSIZE => 64 * 1024;
  16 use constant DEBUG     => $ENV{CATALYST_HTTP_DEBUG} || 0;
  17
  18 use namespace::clean -except => 'meta';
  19
  20 has options => ( is => 'rw' );
  21 has _keepalive => ( is => 'rw', predicate => '_is_keepalive', clearer => '_clear_keepalive' );
  22 has _write_error => ( is => 'rw', predicate => '_has_write_error' );
  23
  24 # Refactoring note - could/should Eliminate all instances of $self->{inputbuf},
  25 # which I haven't touched as it is used as an lvalue in a lot of places, and I guess
  26 # doing it differently could be expensive.. Feel free to refactor and NYTProf :)
  27
  28 =head1 NAME
  29
  30 Catalyst::Engine::HTTP - Catalyst HTTP Engine
  31
  32 =head1 SYNOPSIS
  33
  34 A script using the Catalyst::Engine::HTTP module might look like:
  35
  36     #!/usr/bin/perl -w
  37
  38     BEGIN {  $ENV{CATALYST_ENGINE} = 'HTTP' }
  39
  40     use strict;
  41     use lib '/path/to/MyApp/lib';
  42     use MyApp;
  43
  44     MyApp->run;
  45
  46 =head1 DESCRIPTION
  47
  48 This is the Catalyst engine specialized for development and testing.
  49
  50 =head1 METHODS
  51
  52 =head2 $self->finalize_headers($c)
  53
  54 =cut
  55
  56 sub finalize_headers {
  57     my ( $self, $c ) = @_;
  58     my $protocol = $c->request->protocol;
  59     my $status   = $c->response->status;
  60     my $message  = status_message($status);
  61     my $res_headers = $c->response->headers;
  62
  63     my @headers;
  64     push @headers, "$protocol $status $message";
  65
  66     $res_headers->header( Date => HTTP::Date::time2str(time) );
  67     $res_headers->header( Status => $status );
  68
  69     # Should we keep the connection open?
  70     my $connection = $c->request->header('Connection');
  71     if (   $self->options->{keepalive}
  72         && $connection
  73         && $connection =~ /^keep-alive$/i
  74     ) {
  75         $res_headers->header( Connection => 'keep-alive' );
  76         $self->_keepalive(1);
  77     }
  78     else {
  79         $res_headers->header( Connection => 'close' );
  80     }
  81
  82     push @headers, $res_headers->as_string("\x0D\x0A");
  83
  84     # Buffer the headers so they are sent with the first write() call
  85     # This reduces the number of TCP packets we are sending
  86     $self->_header_buf( join("\x0D\x0A", @headers, '') );
  87 }
  88
  89 =head2 $self->finalize_read($c)
  90
  91 =cut
  92
  93 before finalize_read => sub {
  94     # Never ever remove this, it would result in random length output
  95     # streams if STDIN eq STDOUT (like in the HTTP engine)
  96     *STDIN->blocking(1);
  97 };
  98
  99 =head2 $self->prepare_read($c)
 100
 101 =cut
 102
 103 before prepare_read => sub {
 104     # Set the input handle to non-blocking
 105     *STDIN->blocking(0);
 106 };
 107
 108 =head2 $self->read_chunk($c, $buffer, $length)
 109
 110 =cut
 111
 112 sub read_chunk {
 113     my $self = shift;
 114     my $c    = shift;
 115
 116     # If we have any remaining data in the input buffer, send it back first
 117     if ( $_[0] = delete $self->{inputbuf} ) {
 118         my $read = length( $_[0] );
 119         DEBUG && warn "read_chunk: Read $read bytes from previous input buffer\n";
 120         return $read;
 121     }
 122
 123     # support for non-blocking IO
 124     my $rin = '';
 125     vec( $rin, *STDIN->fileno, 1 ) = 1;
 126
 127   READ:
 128     {
 129         select( $rin, undef, undef, undef );
 130         my $rc = *STDIN->sysread(@_);
 131         if ( defined $rc ) {
 132             DEBUG && warn "read_chunk: Read $rc bytes from socket\n";
 133             return $rc;
 134         }
 135         else {
 136             next READ if $! == EWOULDBLOCK;
 137             return;
 138         }
 139     }
 140 }
 141
 142 =head2 $self->write($c, $buffer)
 143
 144 Writes the buffer to the client.
 145
 146 =cut
 147
 148 around write => sub {
 149     my $orig = shift;
 150     my ( $self, $c, $buffer ) = @_;
 151
 152     # Avoid 'print() on closed filehandle Remote' warnings when using IE
 153     return unless *STDOUT->opened();
 154
 155     # Prepend the headers if they have not yet been sent
 156     if ( $self->_has_header_buf ) {
 157         $self->_warn_on_write_error(
 158             $self->$orig($c, $self->_clear_header_buf)
 159         );
 160     }
 161
 162     $self->_warn_on_write_error($self->$orig($c, $buffer));
 163 };
 164
 165 sub _warn_on_write_error {
 166     my ($self, $ret) = @_;
 167     if ( !defined $ret ) {
 168         $self->_write_error($!);
 169         DEBUG && warn "write: Failed to write response ($!)\n";
 170     }
 171     else {
 172         DEBUG && warn "write: Wrote response ($ret bytes)\n";
 173     }
 174     return $ret;
 175 }
 176
 177 =head2 run
 178
 179 =cut
 180
 181 # A very very simple HTTP server that initializes a CGI environment
 182 sub run {
 183     my ( $self, $class, $port, $host, $options ) = @_;
 184
 185     $options ||= {};
 186
 187     $self->options($options);
 188
 189     if ($options->{background}) {
 190         my $child = fork;
 191         die "Can't fork: $!" unless defined($child);
 192         return $child if $child;
 193     }
 194
 195     my $restart = 0;
 196     local $SIG{CHLD} = 'IGNORE';
 197
 198     my $allowed = $options->{allowed} || { '127.0.0.1' => '255.255.255.255' };
 199     my $addr = $host ? inet_aton($host) : INADDR_ANY;
 200     if ( $addr eq INADDR_ANY ) {
 201         require Sys::Hostname;
 202         $host = lc Sys::Hostname::hostname();
 203     }
 204     else {
 205         $host = gethostbyaddr( $addr, AF_INET ) || inet_ntoa($addr);
 206     }
 207
 208     # Handle requests
 209
 210     # Setup socket
 211     my $daemon = IO::Socket::INET->new(
 212         Listen    => SOMAXCONN,
 213         LocalAddr => inet_ntoa($addr),
 214         LocalPort => $port,
 215         Proto     => 'tcp',
 216         ReuseAddr => 1,
 217         Type      => SOCK_STREAM,
 218       )
 219       or die "Couldn't create daemon: $@";
 220
 221     $port = $daemon->sockport();
 222
 223     my $url = "http://$host";
 224     $url .= ":$port" unless $port == 80;
 225
 226     print "You can connect to your server at $url\n";
 227
 228     if ($options->{background}) {
 229         open STDIN,  "+</dev/null" or die $!;
 230         open STDOUT, ">&STDIN"     or die $!;
 231         open STDERR, ">&STDIN"     or die $!;
 232         if ( $^O !~ /MSWin32/ ) {
 233              require POSIX;
 234              POSIX::setsid()
 235                  or die "Can't start a new session: $!";
 236         }
 237     }
 238
 239     if (my $pidfile = $options->{pidfile}) {
 240         if (! open PIDFILE, "> $pidfile") {
 241             warn("Cannot open: $pidfile: $!");
 242         }
 243         print PIDFILE "$$\n";
 244         close PIDFILE;
 245     }
 246
 247     my $pid = undef;
 248
 249     # Ignore broken pipes as an HTTP server should
 250     local $SIG{PIPE} = 'IGNORE';
 251
 252     # Restart on HUP
 253     local $SIG{HUP} = sub {
 254         $restart = 1;
 255         warn "Restarting server on SIGHUP...\n";
 256     };
 257
 258     LISTEN:
 259     while ( !$restart ) {
 260         while ( accept( Remote, $daemon ) ) {
 261             DEBUG && warn "New connection\n";
 262
 263             select Remote;
 264
 265             Remote->blocking(1);
 266
 267             # Read until we see all headers
 268             $self->{inputbuf} = '';
 269
 270             if ( !$self->_read_headers ) {
 271                 # Error reading, give up
 272                 close Remote;
 273                 next LISTEN;
 274             }
 275
 276             my ( $method, $uri, $protocol ) = $self->_parse_request_line;
 277
 278             DEBUG && warn "Parsed request: $method $uri $protocol\n";
 279             next unless $method;
 280
 281             unless ( uc($method) eq 'RESTART' ) {
 282
 283                 # Fork
 284                 if ( $options->{fork} ) {
 285                     if ( $pid = fork ) {
 286                         DEBUG && warn "Forked child $pid\n";
 287                         next;
 288                     }
 289                 }
 290
 291                 $self->_handler( $class, $port, $method, $uri, $protocol );
 292
 293                 if ( $self->_has_write_error ) {
 294                     close Remote;
 295
 296                     if ( !defined $pid ) {
 297                         next LISTEN;
 298                     }
 299                 }
 300
 301                 if ( defined $pid ) {
 302                     # Child process, close connection and exit
 303                     DEBUG && warn "Child process exiting\n";
 304                     $daemon->close;
 305                     exit;
 306                 }
 307             }
 308             else {
 309                 my $sockdata = $self->_socket_data( \*Remote );
 310                 my $ipaddr   = _inet_addr( $sockdata->{peeraddr} );
 311                 my $ready    = 0;
 312                 foreach my $ip ( keys %$allowed ) {
 313                     my $mask = $allowed->{$ip};
 314                     $ready = ( $ipaddr & _inet_addr($mask) ) == _inet_addr($ip);
 315                     last if $ready;
 316                 }
 317                 if ($ready) {
 318                     $restart = 1;
 319                     last;
 320                 }
 321             }
 322         }
 323         continue {
 324             close Remote;
 325         }
 326     }
 327
 328     $daemon->close;
 329
 330     DEBUG && warn "Shutting down\n";
 331
 332     if ($restart) {
 333         $SIG{CHLD} = 'DEFAULT';
 334         wait;
 335
 336         ### if the standalone server was invoked with perl -I .. we will loose
 337         ### those include dirs upon re-exec. So add them to PERL5LIB, so they
 338         ### are available again for the exec'ed process --kane
 339         use Config;
 340         $ENV{PERL5LIB} .= join $Config{path_sep}, @INC;
 341
 342         exec $^X, $0, @{ $options->{argv} || [] };
 343     }
 344
 345     exit;
 346 }
 347
 348 sub _handler {
 349     my ( $self, $class, $port, $method, $uri, $protocol ) = @_;
 350
 351     local *STDIN  = \*Remote;
 352     local *STDOUT = \*Remote;
 353
 354     # We better be careful and just use 1.0
 355     $protocol = '1.0';
 356
 357     my $sockdata    = $self->_socket_data( \*Remote );
 358     my %copy_of_env = %ENV;
 359
 360     my $sel = IO::Select->new;
 361     $sel->add( \*STDIN );
 362
 363     REQUEST:
 364     while (1) {
 365         my ( $path, $query_string ) = split /\?/, $uri, 2;
 366
 367         # URI is not the same as path. Remove scheme, domain name and port from it
 368         $path =~ s{^https?://[^/?#]+}{};
 369
 370         # Initialize CGI environment
 371         local %ENV = (
 372             PATH_INFO       => $path         || '',
 373             QUERY_STRING    => $query_string || '',
 374             REMOTE_ADDR     => $sockdata->{peeraddr},
 375             REQUEST_METHOD  => $method || '',
 376             SERVER_NAME     => $sockdata->{localname},
 377             SERVER_PORT     => $port,
 378             SERVER_PROTOCOL => "HTTP/$protocol",
 379             %copy_of_env,
 380         );
 381
 382         # Parse headers
 383         if ( $protocol >= 1 ) {
 384             $self->_parse_headers;
 385         }
 386
 387         # Pass flow control to Catalyst
 388         {
 389             # FIXME: don't ignore SIGCHLD while handling requests so system()
 390             # et al. work within actions. it might be a little risky to do that
 391             # this far out, but then again it's only the dev server anyway.
 392             local $SIG{CHLD} = 'DEFAULT';
 393
 394             $class->handle_request( env => \%ENV );
 395         }
 396
 397         DEBUG && warn "Request done\n";
 398
 399         # Allow keepalive requests, this is a hack but we'll support it until
 400         # the next major release.
 401         if ( $self->_is_keepalive ) {
 402             $self->_clear_keepalive;
 403
 404             DEBUG && warn "Reusing previous connection for keep-alive request\n";
 405
 406             if ( $sel->can_read(1) ) {
 407                 if ( !$self->_read_headers ) {
 408                     # Error reading, give up
 409                     last REQUEST;
 410                 }
 411
 412                 ( $method, $uri, $protocol ) = $self->_parse_request_line;
 413
 414                 DEBUG && warn "Parsed request: $method $uri $protocol\n";
 415
 416                 # Force HTTP/1.0
 417                 $protocol = '1.0';
 418
 419                 next REQUEST;
 420             }
 421
 422             DEBUG && warn "No keep-alive request within 1 second\n";
 423         }
 424
 425         last REQUEST;
 426     }
 427
 428     DEBUG && warn "Closing connection\n";
 429
 430     close Remote;
 431 }
 432
 433 sub _read_headers {
 434     my $self = shift;
 435
 436     while (1) {
 437         my $read = sysread Remote, my $buf, CHUNKSIZE;
 438
 439         if ( !defined $read ) {
 440             next if $! == EWOULDBLOCK;
 441             DEBUG && warn "Error reading headers: $!\n";
 442             return;
 443         } elsif ( $read == 0 ) {
 444             DEBUG && warn "EOF\n";
 445             return;
 446         }
 447
 448         DEBUG && warn "Read $read bytes\n";
 449         $self->{inputbuf} .= $buf;
 450         last if $self->{inputbuf} =~ /(\x0D\x0A?\x0D\x0A?|\x0A\x0D?\x0A\x0D?)/s;
 451     }
 452
 453     return 1;
 454 }
 455
 456 sub _parse_request_line {
 457     my $self = shift;
 458
 459     # Parse request line
 460     # Leading CRLF sometimes sent by buggy IE versions
 461     if ( $self->{inputbuf} !~ s/^(?:\x0D\x0A)?(\w+)[ \t]+(\S+)(?:[ \t]+(HTTP\/\d+\.\d+))?[^\012]*\012// ) {
 462         return ();
 463     }
 464
 465     my $method = $1;
 466     my $uri    = $2;
 467     my $proto  = $3 || 'HTTP/0.9';
 468
 469     return ( $method, $uri, $proto );
 470 }
 471
 472 sub _parse_headers {
 473     my $self = shift;
 474
 475     # Copy the buffer for header parsing, and remove the header block
 476     # from the content buffer.
 477     my $buf = $self->{inputbuf};
 478     $self->{inputbuf} =~ s/.*?(\x0D\x0A?\x0D\x0A?|\x0A\x0D?\x0A\x0D?)//s;
 479
 480     # Parse headers
 481     my $headers = HTTP::Headers->new;
 482     my ($key, $val);
 483     HEADER:
 484     while ( $buf =~ s/^([^\012]*)\012// ) {
 485         $_ = $1;
 486         s/\015$//;
 487         if ( /^([\w\-~]+)\s*:\s*(.*)/ ) {
 488             $headers->push_header( $key, $val ) if $key;
 489             ($key, $val) = ($1, $2);
 490         }
 491         elsif ( /^\s+(.*)/ ) {
 492             $val .= " $1";
 493         }
 494         else {
 495             last HEADER;
 496         }
 497     }
 498     $headers->push_header( $key, $val ) if $key;
 499
 500     DEBUG && warn "Parsed headers: " . dump($headers) . "\n";
 501
 502     # Convert headers into ENV vars
 503     $headers->scan( sub {
 504         my ( $key, $val ) = @_;
 505
 506         $key = uc $key;
 507         $key = 'COOKIE' if $key eq 'COOKIES';
 508         $key =~ tr/-/_/;
 509         $key = 'HTTP_' . $key
 510             unless $key =~ m/\A(?:CONTENT_(?:LENGTH|TYPE)|COOKIE)\z/;
 511
 512         if ( exists $ENV{$key} ) {
 513             $ENV{$key} .= ", $val";
 514         }
 515         else {
 516             $ENV{$key} = $val;
 517         }
 518     } );
 519 }
 520
 521 sub _socket_data {
 522     my ( $self, $handle ) = @_;
 523
 524     my $remote_sockaddr       = getpeername($handle);
 525     my ( undef, $iaddr )      = $remote_sockaddr
 526         ? sockaddr_in($remote_sockaddr)
 527         : (undef, undef);
 528
 529     my $local_sockaddr        = getsockname($handle);
 530     my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);
 531
 532     # This mess is necessary to keep IE from crashing the server
 533     my $data = {
 534         peeraddr  => $iaddr
 535             ? ( inet_ntoa($iaddr) || '127.0.0.1' )
 536             : '127.0.0.1',
 537         localname => _gethostbyaddr( $localiaddr ),
 538         localaddr => inet_ntoa($localiaddr) || '127.0.0.1',
 539     };
 540
 541     return $data;
 542 }
 543
 544 {   # If you have a crappy DNS server then these can be slow, so cache 'em
 545     my %hostname_cache;
 546     sub _gethostbyaddr {
 547         my $ip = shift;
 548         $hostname_cache{$ip} ||= gethostbyaddr( $ip, AF_INET ) || 'localhost';
 549     }
 550 }
 551
 552 sub _inet_addr { unpack "N*", inet_aton( $_[0] ) }
 553
 554 =head2 options
 555
 556 Options hash passed to the http engine to control things like if keepalive
 557 is supported.
 558
 559 =head1 SEE ALSO
 560
 561 L<Catalyst>, L<Catalyst::Engine>
 562
 563 =head1 AUTHORS
 564
 565 Catalyst Contributors, see Catalyst.pm
 566
 567 =head1 THANKS
 568
 569 Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.
 570
 571 =head1 COPYRIGHT
 572
 573 This library is free software. You can redistribute it and/or modify it under
 574 the same terms as Perl itself.
 575
 576 =cut
 577
 578 1;