lib/Catalyst/Engine/CGI.pm

   1 package Catalyst::Engine::CGI;
   2
   3 use Moose;
   4 extends 'Catalyst::Engine';
   5
   6 has _header_buf => (is => 'rw', clearer => '_clear_header_buf', predicate => '_has_header_buf');
   7
   8 =head1 NAME
   9
  10 Catalyst::Engine::CGI - The CGI Engine
  11
  12 =head1 SYNOPSIS
  13
  14 A script using the Catalyst::Engine::CGI module might look like:
  15
  16     #!/usr/bin/perl -w
  17
  18     use strict;
  19     use lib '/path/to/MyApp/lib';
  20     use MyApp;
  21
  22     MyApp->run;
  23
  24 The application module (C<MyApp>) would use C<Catalyst>, which loads the
  25 appropriate engine module.
  26
  27 =head1 DESCRIPTION
  28
  29 This is the Catalyst engine specialized for the CGI environment.
  30
  31 =head1 OVERLOADED METHODS
  32
  33 This class overloads some methods from C<Catalyst::Engine>.
  34
  35 =head2 $self->finalize_headers($c)
  36
  37 =cut
  38
  39 sub finalize_headers {
  40     my ( $self, $c ) = @_;
  41
  42     $c->response->header( Status => $c->response->status );
  43
  44     $self->_header_buf($c->response->headers->as_string("\015\012") . "\015\012");
  45 }
  46
  47 =head2 $self->prepare_connection($c)
  48
  49 =cut
  50
  51 sub prepare_connection {
  52     my ( $self, $c ) = @_;
  53     local (*ENV) = $self->env || \%ENV;
  54
  55     my $request = $c->request;
  56     $request->address( $ENV{REMOTE_ADDR} );
  57
  58   PROXY_CHECK:
  59     {
  60         unless ( ref($c)->config->{using_frontend_proxy} ) {
  61             last PROXY_CHECK if $ENV{REMOTE_ADDR} ne '127.0.0.1';
  62             last PROXY_CHECK if ref($c)->config->{ignore_frontend_proxy};
  63         }
  64         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_FOR};
  65
  66         # If we are running as a backend server, the user will always appear
  67         # as 127.0.0.1. Select the most recent upstream IP (last in the list)
  68         my ($ip) = $ENV{HTTP_X_FORWARDED_FOR} =~ /([^,\s]+)$/;
  69         $request->address($ip);
  70         if ( defined $ENV{HTTP_X_FORWARDED_PORT} ) {
  71             $ENV{SERVER_PORT} = $ENV{HTTP_X_FORWARDED_PORT};
  72         }
  73     }
  74
  75     $request->hostname( $ENV{REMOTE_HOST} ) if exists $ENV{REMOTE_HOST};
  76     $request->protocol( $ENV{SERVER_PROTOCOL} );
  77     $request->user( $ENV{REMOTE_USER} );  # XXX: Deprecated. See Catalyst::Request for removal information
  78     $request->remote_user( $ENV{REMOTE_USER} );
  79     $request->method( $ENV{REQUEST_METHOD} );
  80
  81     if ( $ENV{HTTPS} && uc( $ENV{HTTPS} ) eq 'ON' ) {
  82         $request->secure(1);
  83     }
  84
  85     if ( $ENV{SERVER_PORT} == 443 ) {
  86         $request->secure(1);
  87     }
  88     binmode(STDOUT); # Ensure we are sending bytes.
  89 }
  90
  91 =head2 $self->prepare_headers($c)
  92
  93 =cut
  94
  95 sub prepare_headers {
  96     my ( $self, $c ) = @_;
  97     local (*ENV) = $self->env || \%ENV;
  98     my $headers = $c->request->headers;
  99     # Read headers from %ENV
 100     foreach my $header ( keys %ENV ) {
 101         next unless $header =~ /^(?:HTTP|CONTENT|COOKIE)/i;
 102         ( my $field = $header ) =~ s/^HTTPS?_//;
 103         $headers->header( $field => $ENV{$header} );
 104     }
 105 }
 106
 107 =head2 $self->prepare_path($c)
 108
 109 =cut
 110
 111 # Please don't touch this method without adding tests in
 112 # t/aggregate/unit_core_engine_cgi-prepare_path.t
 113 sub prepare_path {
 114     my ( $self, $c ) = @_;
 115     local (*ENV) = $self->env || \%ENV;
 116
 117     my $scheme = $c->request->secure ? 'https' : 'http';
 118     my $host      = $ENV{HTTP_HOST}   || $ENV{SERVER_NAME};
 119     my $port      = $ENV{SERVER_PORT} || 80;
 120
 121     # fix up for IIS
 122     if ($ENV{SERVER_SOFTWARE} && $ENV{SERVER_SOFTWARE} =~ m{IIS/[6-9]\.\d}) {
 123         $ENV{PATH_INFO} =~ s/^\Q$ENV{SCRIPT_NAME}\E//;
 124     }
 125
 126     my $script_name = $ENV{SCRIPT_NAME};
 127     $script_name =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go if $script_name;
 128
 129     my $base_path;
 130     if ( exists $ENV{REDIRECT_URL} ) {
 131         $base_path = $ENV{REDIRECT_URL};
 132         $base_path =~ s/$ENV{PATH_INFO}$//;
 133     }
 134     else {
 135         $base_path = $script_name || '/';
 136     }
 137
 138     # If we are running as a backend proxy, get the true hostname
 139   PROXY_CHECK:
 140     {
 141         unless ( ref($c)->config->{using_frontend_proxy} ) {
 142             last PROXY_CHECK if $host !~ /localhost|127.0.0.1/;
 143             last PROXY_CHECK if ref($c)->config->{ignore_frontend_proxy};
 144         }
 145         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_HOST};
 146
 147         $host = $ENV{HTTP_X_FORWARDED_HOST};
 148
 149         # backend could be on any port, so
 150         # assume frontend is on the default port
 151         $port = $c->request->secure ? 443 : 80;
 152         if ( $ENV{HTTP_X_FORWARDED_PORT} ) {
 153             $port = $ENV{HTTP_X_FORWARDED_PORT};
 154         }
 155     }
 156
 157     # RFC 3875: "Unlike a URI path, the PATH_INFO is not URL-encoded,
 158     # and cannot contain path-segment parameters." This means PATH_INFO
 159     # is always decoded, and the script can't distinguish / vs %2F.
 160     # See https://issues.apache.org/bugzilla/show_bug.cgi?id=35256
 161     # Here we try to resurrect the original encoded URI from REQUEST_URI.
 162     my $path_info   = $ENV{PATH_INFO};
 163     if (my $req_uri = $ENV{REQUEST_URI}) {
 164         $req_uri =~ s/^\Q$base_path\E//;
 165         $req_uri =~ s/\?.*$//;
 166         if ($req_uri) {
 167             # Note that if REQUEST_URI doesn't start with a /, then the user
 168             # is probably using mod_rewrite or something to rewrite requests
 169             # into a sub-path of their application..
 170             # This means that REQUEST_URI needs information from PATH_INFO
 171             # prepending to it to be useful, otherwise the sub path which is
 172             # being redirected to becomes the app base address which is
 173             # incorrect.
 174             if (substr($req_uri, 0, 1) ne '/') {
 175                 my ($match) = $req_uri =~ m|^([^/]+)|;
 176                 my ($path_info_part) = $path_info =~ m|^(.*?\Q$match\E)|;
 177                 substr($req_uri, 0, length($match), $path_info_part)
 178                     if $path_info_part;
 179             }
 180             $path_info = $req_uri;
 181         }
 182     }
 183
 184     # set the request URI
 185     my $path = $base_path . ( $path_info || '' );
 186     $path =~ s{^/+}{};
 187
 188     # Using URI directly is way too slow, so we construct the URLs manually
 189     my $uri_class = "URI::$scheme";
 190
 191     # HTTP_HOST will include the port even if it's 80/443
 192     $host =~ s/:(?:80|443)$//;
 193
 194     if ( $port !~ /^(?:80|443)$/ && $host !~ /:/ ) {
 195         $host .= ":$port";
 196     }
 197
 198     # Escape the path
 199     $path =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
 200     $path =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 201
 202     my $query = $ENV{QUERY_STRING} ? '?' . $ENV{QUERY_STRING} : '';
 203     my $uri   = $scheme . '://' . $host . '/' . $path . $query;
 204
 205     $c->request->uri( bless(\$uri, $uri_class)->canonical );
 206
 207     # set the base URI
 208     # base must end in a slash
 209     $base_path .= '/' unless $base_path =~ m{/$};
 210
 211     my $base_uri = $scheme . '://' . $host . $base_path;
 212
 213     $c->request->base( bless \$base_uri, $uri_class );
 214 }
 215
 216 =head2 $self->prepare_query_parameters($c)
 217
 218 =cut
 219
 220 around prepare_query_parameters => sub {
 221     my $orig = shift;
 222     my ( $self, $c ) = @_;
 223     local (*ENV) = $self->env || \%ENV;
 224
 225     if ( $ENV{QUERY_STRING} ) {
 226         $self->$orig( $c, $ENV{QUERY_STRING} );
 227     }
 228 };
 229
 230 =head2 $self->prepare_request($c, (env => \%env))
 231
 232 =cut
 233
 234 sub prepare_request {
 235     my ( $self, $c, %args ) = @_;
 236
 237     if ( $args{env} ) {
 238         $self->env( $args{env} );
 239     }
 240 }
 241
 242 =head2 $self->prepare_write($c)
 243
 244 Enable autoflush on the output handle for CGI-based engines.
 245
 246 =cut
 247
 248 around prepare_write => sub {
 249     *STDOUT->autoflush(1);
 250     return shift->(@_);
 251 };
 252
 253 =head2 $self->write($c, $buffer)
 254
 255 Writes the buffer to the client.
 256
 257 =cut
 258
 259 around write => sub {
 260     my $orig = shift;
 261     my ( $self, $c, $buffer ) = @_;
 262
 263     # Prepend the headers if they have not yet been sent
 264     if ( $self->_has_header_buf ) {
 265         $buffer = $self->_clear_header_buf . $buffer;
 266     }
 267
 268     return $self->$orig( $c, $buffer );
 269 };
 270
 271 =head2 $self->read_chunk($c, $buffer, $length)
 272
 273 =cut
 274
 275 sub read_chunk { shift; shift; *STDIN->sysread(@_); }
 276
 277 =head2 $self->run
 278
 279 =cut
 280
 281 sub run { shift; shift->handle_request( env => \%ENV ) }
 282
 283 =head1 SEE ALSO
 284
 285 L<Catalyst>, L<Catalyst::Engine>
 286
 287 =head1 AUTHORS
 288
 289 Catalyst Contributors, see Catalyst.pm
 290
 291 =head1 COPYRIGHT
 292
 293 This library is free software. You can redistribute it and/or modify it under
 294 the same terms as Perl itself.
 295
 296 =cut
 297 no Moose;
 298
 299 1;