lib/Catalyst/Engine/CGI.pm

   1 package Catalyst::Engine::CGI;
   2
   3 use Moose;
   4 extends 'Catalyst::Engine';
   5
   6 has _header_buf => (is => 'rw', clearer => '_clear_header_buf', predicate => '_has_header_buf');
   7
   8 =head1 NAME
   9
  10 Catalyst::Engine::CGI - The CGI Engine
  11
  12 =head1 SYNOPSIS
  13
  14 A script using the Catalyst::Engine::CGI module might look like:
  15
  16     #!/usr/bin/perl -w
  17
  18     use strict;
  19     use lib '/path/to/MyApp/lib';
  20     use MyApp;
  21
  22     MyApp->run;
  23
  24 The application module (C<MyApp>) would use C<Catalyst>, which loads the
  25 appropriate engine module.
  26
  27 =head1 DESCRIPTION
  28
  29 This is the Catalyst engine specialized for the CGI environment.
  30
  31 =head1 OVERLOADED METHODS
  32
  33 This class overloads some methods from C<Catalyst::Engine>.
  34
  35 =head2 $self->finalize_headers($c)
  36
  37 =cut
  38
  39 sub finalize_headers {
  40     my ( $self, $c ) = @_;
  41
  42     $c->response->header( Status => $c->response->status );
  43
  44     $self->_header_buf($c->response->headers->as_string("\015\012") . "\015\012");
  45 }
  46
  47 =head2 $self->prepare_connection($c)
  48
  49 =cut
  50
  51 sub prepare_connection {
  52     my ( $self, $c ) = @_;
  53     local (*ENV) = $self->env || \%ENV;
  54
  55     my $request = $c->request;
  56     $request->address( $ENV{REMOTE_ADDR} );
  57
  58   PROXY_CHECK:
  59     {
  60         unless ( ref($c)->config->{using_frontend_proxy} ) {
  61             last PROXY_CHECK if $ENV{REMOTE_ADDR} ne '127.0.0.1';
  62             last PROXY_CHECK if ref($c)->config->{ignore_frontend_proxy};
  63         }
  64         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_FOR};
  65
  66         # If we are running as a backend server, the user will always appear
  67         # as 127.0.0.1. Select the most recent upstream IP (last in the list)
  68         my ($ip) = $ENV{HTTP_X_FORWARDED_FOR} =~ /([^,\s]+)$/;
  69         $request->address($ip);
  70         if ( defined $ENV{HTTP_X_FORWARDED_PORT} ) {
  71             $ENV{SERVER_PORT} = $ENV{HTTP_X_FORWARDED_PORT};
  72         }
  73     }
  74
  75     $request->hostname( $ENV{REMOTE_HOST} ) if exists $ENV{REMOTE_HOST};
  76     $request->protocol( $ENV{SERVER_PROTOCOL} );
  77     $request->user( $ENV{REMOTE_USER} );  # XXX: Deprecated. See Catalyst::Request for removal information
  78     $request->remote_user( $ENV{REMOTE_USER} );
  79     $request->method( $ENV{REQUEST_METHOD} );
  80
  81     if ( $ENV{HTTPS} && uc( $ENV{HTTPS} ) eq 'ON' ) {
  82         $request->secure(1);
  83     }
  84
  85     if ( $ENV{SERVER_PORT} == 443 ) {
  86         $request->secure(1);
  87     }
  88     binmode(STDOUT); # Ensure we are sending bytes.
  89 }
  90
  91 =head2 $self->prepare_headers($c)
  92
  93 =cut
  94
  95 sub prepare_headers {
  96     my ( $self, $c ) = @_;
  97     local (*ENV) = $self->env || \%ENV;
  98     my $headers = $c->request->headers;
  99     # Read headers from %ENV
 100     foreach my $header ( keys %ENV ) {
 101         next unless $header =~ /^(?:HTTP|CONTENT|COOKIE)/i;
 102         ( my $field = $header ) =~ s/^HTTPS?_//;
 103         $headers->header( $field => $ENV{$header} );
 104     }
 105 }
 106
 107 =head2 $self->prepare_path($c)
 108
 109 =cut
 110
 111 # Please don't touch this method without adding tests in
 112 # t/aggregate/unit_core_engine_cgi-prepare_path.t
 113 sub prepare_path {
 114     my ( $self, $c ) = @_;
 115     local (*ENV) = $self->env || \%ENV;
 116
 117     my $scheme = $c->request->secure ? 'https' : 'http';
 118     my $host      = $ENV{HTTP_HOST}   || $ENV{SERVER_NAME};
 119     my $port      = $ENV{SERVER_PORT} || 80;
 120     my $script_name = $ENV{SCRIPT_NAME};
 121     $script_name =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go if $script_name;
 122
 123     my $base_path;
 124     if ( exists $ENV{REDIRECT_URL} ) {
 125         $base_path = $ENV{REDIRECT_URL};
 126         $base_path =~ s/$ENV{PATH_INFO}$//;
 127     }
 128     else {
 129         $base_path = $script_name || '/';
 130     }
 131 #    $base_path .= '/' unless $base_path =~ m{/$};
 132
 133     # If we are running as a backend proxy, get the true hostname
 134   PROXY_CHECK:
 135     {
 136         unless ( ref($c)->config->{using_frontend_proxy} ) {
 137             last PROXY_CHECK if $host !~ /localhost|127.0.0.1/;
 138             last PROXY_CHECK if ref($c)->config->{ignore_frontend_proxy};
 139         }
 140         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_HOST};
 141
 142         $host = $ENV{HTTP_X_FORWARDED_HOST};
 143
 144         # backend could be on any port, so
 145         # assume frontend is on the default port
 146         $port = $c->request->secure ? 443 : 80;
 147         if ( $ENV{HTTP_X_FORWARDED_PORT} ) {
 148             $port = $ENV{HTTP_X_FORWARDED_PORT};
 149         }
 150     }
 151
 152     # RFC 3875: "Unlike a URI path, the PATH_INFO is not URL-encoded,
 153     # and cannot contain path-segment parameters." This means PATH_INFO
 154     # is always decoded, and the script can't distinguish / vs %2F.
 155     # See https://issues.apache.org/bugzilla/show_bug.cgi?id=35256
 156     # Here we try to resurrect the original encoded URI from REQUEST_URI.
 157     my $path_info   = $ENV{PATH_INFO};
 158     if (my $req_uri = $ENV{REQUEST_URI}) {
 159         $req_uri =~ s/^\Q$base_path\E//;
 160         $req_uri =~ s/\?.*$//;
 161         if ($req_uri && $req_uri ne '/') {
 162             # This means that REQUEST_URI needs information from PATH_INFO
 163             # prepending to it to be useful, otherwise the sub path which is
 164             # being redirected to becomes the app base address which is
 165             # incorrect.
 166             my ($match) = $req_uri =~ m{^(/?[^/]+)};
 167             my ($path_info_part) = $path_info =~ m|^(.*?\Q$match\E)|;
 168             substr($req_uri, 0, length($match), $path_info_part)
 169                 if $path_info_part;
 170             $path_info = $req_uri;
 171         }
 172     }
 173
 174     # set the request URI
 175     my $path = $base_path . ( $path_info || '' );
 176     $path =~ s{^/+}{};
 177
 178     # Using URI directly is way too slow, so we construct the URLs manually
 179     my $uri_class = "URI::$scheme";
 180
 181     # HTTP_HOST will include the port even if it's 80/443
 182     $host =~ s/:(?:80|443)$//;
 183
 184     if ( $port !~ /^(?:80|443)$/ && $host !~ /:/ ) {
 185         $host .= ":$port";
 186     }
 187
 188     # Escape the path
 189     $path =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
 190     $path =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 191
 192     my $query = $ENV{QUERY_STRING} ? '?' . $ENV{QUERY_STRING} : '';
 193     my $uri   = $scheme . '://' . $host . '/' . $path . $query;
 194
 195     $c->request->uri( bless(\$uri, $uri_class)->canonical );
 196
 197     # set the base URI
 198     # base must end in a slash
 199     $base_path .= '/' unless $base_path =~ m{/$};
 200
 201     my $base_uri = $scheme . '://' . $host . $base_path;
 202
 203     $c->request->base( bless \$base_uri, $uri_class );
 204 }
 205
 206 =head2 $self->prepare_query_parameters($c)
 207
 208 =cut
 209
 210 around prepare_query_parameters => sub {
 211     my $orig = shift;
 212     my ( $self, $c ) = @_;
 213     local (*ENV) = $self->env || \%ENV;
 214
 215     if ( $ENV{QUERY_STRING} ) {
 216         $self->$orig( $c, $ENV{QUERY_STRING} );
 217     }
 218 };
 219
 220 =head2 $self->prepare_request($c, (env => \%env))
 221
 222 =cut
 223
 224 sub prepare_request {
 225     my ( $self, $c, %args ) = @_;
 226
 227     if ( $args{env} ) {
 228         $self->env( $args{env} );
 229     }
 230 }
 231
 232 =head2 $self->prepare_write($c)
 233
 234 Enable autoflush on the output handle for CGI-based engines.
 235
 236 =cut
 237
 238 around prepare_write => sub {
 239     *STDOUT->autoflush(1);
 240     return shift->(@_);
 241 };
 242
 243 =head2 $self->write($c, $buffer)
 244
 245 Writes the buffer to the client.
 246
 247 =cut
 248
 249 around write => sub {
 250     my $orig = shift;
 251     my ( $self, $c, $buffer ) = @_;
 252
 253     # Prepend the headers if they have not yet been sent
 254     if ( $self->_has_header_buf ) {
 255         $buffer = $self->_clear_header_buf . $buffer;
 256     }
 257
 258     return $self->$orig( $c, $buffer );
 259 };
 260
 261 =head2 $self->read_chunk($c, $buffer, $length)
 262
 263 =cut
 264
 265 sub read_chunk { shift; shift; *STDIN->sysread(@_); }
 266
 267 =head2 $self->run
 268
 269 =cut
 270
 271 sub run { shift; shift->handle_request( env => \%ENV ) }
 272
 273 =head1 SEE ALSO
 274
 275 L<Catalyst>, L<Catalyst::Engine>
 276
 277 =head1 AUTHORS
 278
 279 Catalyst Contributors, see Catalyst.pm
 280
 281 =head1 COPYRIGHT
 282
 283 This library is free software. You can redistribute it and/or modify it under
 284 the same terms as Perl itself.
 285
 286 =cut
 287 no Moose;
 288
 289 1;