lib/Catalyst/Engine/CGI.pm

   1 package Catalyst::Engine::CGI;
   2
   3 use Moose;
   4 extends 'Catalyst::Engine';
   5
   6 has _header_buf => (is => 'rw', clearer => '_clear_header_buf', predicate => '_has_header_buf');
   7
   8 =head1 NAME
   9
  10 Catalyst::Engine::CGI - The CGI Engine
  11
  12 =head1 SYNOPSIS
  13
  14 A script using the Catalyst::Engine::CGI module might look like:
  15
  16     #!/usr/bin/perl -w
  17
  18     use strict;
  19     use lib '/path/to/MyApp/lib';
  20     use MyApp;
  21
  22     MyApp->run;
  23
  24 The application module (C<MyApp>) would use C<Catalyst>, which loads the
  25 appropriate engine module.
  26
  27 =head1 DESCRIPTION
  28
  29 This is the Catalyst engine specialized for the CGI environment.
  30
  31 =head1 OVERLOADED METHODS
  32
  33 This class overloads some methods from C<Catalyst::Engine>.
  34
  35 =head2 $self->finalize_headers($c)
  36
  37 =cut
  38
  39 sub finalize_headers {
  40     my ( $self, $c ) = @_;
  41
  42     $c->response->header( Status => $c->response->status );
  43
  44     $self->_header_buf($c->response->headers->as_string("\015\012") . "\015\012");
  45 }
  46
  47 =head2 $self->prepare_connection($c)
  48
  49 =cut
  50
  51 sub prepare_connection {
  52     my ( $self, $c ) = @_;
  53     local (*ENV) = $self->env || \%ENV;
  54
  55     my $request = $c->request;
  56     $request->address( $ENV{REMOTE_ADDR} );
  57
  58   PROXY_CHECK:
  59     {
  60         unless ( ref($c)->config->{using_frontend_proxy} ) {
  61             last PROXY_CHECK if $ENV{REMOTE_ADDR} ne '127.0.0.1';
  62             last PROXY_CHECK if ref($c)->config->{ignore_frontend_proxy};
  63         }
  64         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_FOR};
  65
  66         # If we are running as a backend server, the user will always appear
  67         # as 127.0.0.1. Select the most recent upstream IP (last in the list)
  68         my ($ip) = $ENV{HTTP_X_FORWARDED_FOR} =~ /([^,\s]+)$/;
  69         $request->address($ip);
  70         if ( defined $ENV{HTTP_X_FORWARDED_PORT} ) {
  71             $ENV{SERVER_PORT} = $ENV{HTTP_X_FORWARDED_PORT};
  72         }
  73     }
  74
  75     $request->hostname( $ENV{REMOTE_HOST} ) if exists $ENV{REMOTE_HOST};
  76     $request->protocol( $ENV{SERVER_PROTOCOL} );
  77     $request->user( $ENV{REMOTE_USER} );  # XXX: Deprecated. See Catalyst::Request for removal information
  78     $request->remote_user( $ENV{REMOTE_USER} );
  79     $request->method( $ENV{REQUEST_METHOD} );
  80
  81     if ( $ENV{HTTPS} && uc( $ENV{HTTPS} ) eq 'ON' ) {
  82         $request->secure(1);
  83     }
  84
  85     if ( $ENV{SERVER_PORT} == 443 ) {
  86         $request->secure(1);
  87     }
  88     binmode(STDOUT); # Ensure we are sending bytes.
  89 }
  90
  91 =head2 $self->prepare_headers($c)
  92
  93 =cut
  94
  95 sub prepare_headers {
  96     my ( $self, $c ) = @_;
  97     local (*ENV) = $self->env || \%ENV;
  98     my $headers = $c->request->headers;
  99     # Read headers from %ENV
 100     foreach my $header ( keys %ENV ) {
 101         next unless $header =~ /^(?:HTTP|CONTENT|COOKIE)/i;
 102         ( my $field = $header ) =~ s/^HTTPS?_//;
 103         $headers->header( $field => $ENV{$header} );
 104     }
 105 }
 106
 107 =head2 $self->prepare_path($c)
 108
 109 =cut
 110
 111 # Please don't touch this method without adding tests in
 112 # t/aggregate/unit_core_engine_cgi-prepare_path.t
 113 sub prepare_path {
 114     my ( $self, $c ) = @_;
 115     local (*ENV) = $self->env || \%ENV;
 116
 117     my $scheme = $c->request->secure ? 'https' : 'http';
 118     my $host      = $ENV{HTTP_HOST}   || $ENV{SERVER_NAME};
 119     my $port      = $ENV{SERVER_PORT} || 80;
 120     my $script_name = $ENV{SCRIPT_NAME};
 121     $script_name =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go if $script_name;
 122
 123     my $base_path;
 124     if ( exists $ENV{REDIRECT_URL} ) {
 125         $base_path = $ENV{REDIRECT_URL};
 126         $base_path =~ s/$ENV{PATH_INFO}$//;
 127     }
 128     else {
 129         $base_path = $script_name || '/';
 130     }
 131
 132     # If we are running as a backend proxy, get the true hostname
 133   PROXY_CHECK:
 134     {
 135         unless ( ref($c)->config->{using_frontend_proxy} ) {
 136             last PROXY_CHECK if $host !~ /localhost|127.0.0.1/;
 137             last PROXY_CHECK if ref($c)->config->{ignore_frontend_proxy};
 138         }
 139         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_HOST};
 140
 141         $host = $ENV{HTTP_X_FORWARDED_HOST};
 142
 143         # backend could be on any port, so
 144         # assume frontend is on the default port
 145         $port = $c->request->secure ? 443 : 80;
 146         if ( $ENV{HTTP_X_FORWARDED_PORT} ) {
 147             $port = $ENV{HTTP_X_FORWARDED_PORT};
 148         }
 149     }
 150
 151     # RFC 3875: "Unlike a URI path, the PATH_INFO is not URL-encoded,
 152     # and cannot contain path-segment parameters." This means PATH_INFO
 153     # is always decoded, and the script can't distinguish / vs %2F.
 154     # See https://issues.apache.org/bugzilla/show_bug.cgi?id=35256
 155     # Here we try to resurrect the original encoded URI from REQUEST_URI.
 156     my $path_info   = $ENV{PATH_INFO};
 157     if (my $req_uri = $ENV{REQUEST_URI}) {
 158         $req_uri =~ s/^\Q$base_path\E//;
 159         $req_uri =~ s/\?.*$//;
 160         if ($req_uri) {
 161             # Note that if REQUEST_URI doesn't start with a /, then the user
 162             # is probably using mod_rewrite or something to rewrite requests
 163             # into a sub-path of their application..
 164             # This means that REQUEST_URI needs information from PATH_INFO
 165             # prepending to it to be useful, otherwise the sub path which is
 166             # being redirected to becomes the app base address which is
 167             # incorrect.
 168             if (substr($req_uri, 0, 1) ne '/') {
 169                 my ($match) = $req_uri =~ m|^([^/]+)|;
 170                 my ($path_info_part) = $path_info =~ m|^(.*?\Q$match\E)|;
 171                 substr($req_uri, 0, length($match), $path_info_part);
 172             }
 173             $path_info = $req_uri;
 174         }
 175     }
 176
 177     # set the request URI
 178     my $path = $base_path . ( $path_info || '' );
 179     $path =~ s{^/+}{};
 180
 181     # Using URI directly is way too slow, so we construct the URLs manually
 182     my $uri_class = "URI::$scheme";
 183
 184     # HTTP_HOST will include the port even if it's 80/443
 185     $host =~ s/:(?:80|443)$//;
 186
 187     if ( $port !~ /^(?:80|443)$/ && $host !~ /:/ ) {
 188         $host .= ":$port";
 189     }
 190
 191     # Escape the path
 192     $path =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
 193     $path =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 194
 195     my $query = $ENV{QUERY_STRING} ? '?' . $ENV{QUERY_STRING} : '';
 196     my $uri   = $scheme . '://' . $host . '/' . $path . $query;
 197
 198     $c->request->uri( bless(\$uri, $uri_class)->canonical );
 199
 200     # set the base URI
 201     # base must end in a slash
 202     $base_path .= '/' unless $base_path =~ m{/$};
 203
 204     my $base_uri = $scheme . '://' . $host . $base_path;
 205
 206     $c->request->base( bless(\$base_uri, $uri_class)->canonical );
 207 }
 208
 209 =head2 $self->prepare_query_parameters($c)
 210
 211 =cut
 212
 213 around prepare_query_parameters => sub {
 214     my $orig = shift;
 215     my ( $self, $c ) = @_;
 216     local (*ENV) = $self->env || \%ENV;
 217
 218     if ( $ENV{QUERY_STRING} ) {
 219         $self->$orig( $c, $ENV{QUERY_STRING} );
 220     }
 221 };
 222
 223 =head2 $self->prepare_request($c, (env => \%env))
 224
 225 =cut
 226
 227 sub prepare_request {
 228     my ( $self, $c, %args ) = @_;
 229
 230     if ( $args{env} ) {
 231         $self->env( $args{env} );
 232     }
 233 }
 234
 235 =head2 $self->prepare_write($c)
 236
 237 Enable autoflush on the output handle for CGI-based engines.
 238
 239 =cut
 240
 241 around prepare_write => sub {
 242     *STDOUT->autoflush(1);
 243     return shift->(@_);
 244 };
 245
 246 =head2 $self->write($c, $buffer)
 247
 248 Writes the buffer to the client.
 249
 250 =cut
 251
 252 around write => sub {
 253     my $orig = shift;
 254     my ( $self, $c, $buffer ) = @_;
 255
 256     # Prepend the headers if they have not yet been sent
 257     if ( $self->_has_header_buf ) {
 258         $buffer = $self->_clear_header_buf . $buffer;
 259     }
 260
 261     return $self->$orig( $c, $buffer );
 262 };
 263
 264 =head2 $self->read_chunk($c, $buffer, $length)
 265
 266 =cut
 267
 268 sub read_chunk { shift; shift; *STDIN->sysread(@_); }
 269
 270 =head2 $self->run
 271
 272 =cut
 273
 274 sub run { shift; shift->handle_request( env => \%ENV ) }
 275
 276 =head1 SEE ALSO
 277
 278 L<Catalyst>, L<Catalyst::Engine>
 279
 280 =head1 AUTHORS
 281
 282 Catalyst Contributors, see Catalyst.pm
 283
 284 =head1 COPYRIGHT
 285
 286 This library is free software. You can redistribute it and/or modify it under
 287 the same terms as Perl itself.
 288
 289 =cut
 290 no Moose;
 291
 292 1;