lib/Catalyst/Engine/CGI.pm

   1 package Catalyst::Engine::CGI;
   2
   3 use strict;
   4 use base 'Catalyst::Engine';
   5 use NEXT;
   6 use URI;
   7
   8 __PACKAGE__->mk_accessors( 'env' );
   9
  10 =head1 NAME
  11
  12 Catalyst::Engine::CGI - The CGI Engine
  13
  14 =head1 SYNOPSIS
  15
  16 A script using the Catalyst::Engine::CGI module might look like:
  17
  18     #!/usr/bin/perl -w
  19
  20     use strict;
  21     use lib '/path/to/MyApp/lib';
  22     use MyApp;
  23
  24     MyApp->run;
  25
  26 The application module (C<MyApp>) would use C<Catalyst>, which loads the
  27 appropriate engine module.
  28
  29 =head1 DESCRIPTION
  30
  31 This is the Catalyst engine specialized for the CGI environment.
  32
  33 =head1 OVERLOADED METHODS
  34
  35 This class overloads some methods from C<Catalyst::Engine>.
  36
  37 =over 4
  38
  39 =item $self->finalize_headers($c)
  40
  41 =cut
  42
  43 sub finalize_headers {
  44     my ( $self, $c ) = @_;
  45
  46     $c->response->header( Status => $c->response->status );
  47
  48     print $c->response->headers->as_string("\015\012");
  49     print "\015\012";
  50 }
  51
  52 =item $self->prepare_connection($c)
  53
  54 =cut
  55
  56 sub prepare_connection {
  57     my ( $self, $c ) = @_;
  58     local(*ENV) = $self->env || \%ENV;
  59
  60     $c->request->address( $ENV{REMOTE_ADDR} );
  61
  62   PROXY_CHECK:
  63     {
  64         unless ( $c->config->{using_frontend_proxy} ) {
  65             last PROXY_CHECK if $ENV{REMOTE_ADDR} ne '127.0.0.1';
  66             last PROXY_CHECK if $c->config->{ignore_frontend_proxy};
  67         }
  68         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_FOR};
  69
  70         # If we are running as a backend server, the user will always appear
  71         # as 127.0.0.1. Select the most recent upstream IP (last in the list)
  72         my ($ip) = $ENV{HTTP_X_FORWARDED_FOR} =~ /([^,\s]+)$/;
  73         $c->request->address($ip);
  74     }
  75
  76     $c->request->hostname( $ENV{REMOTE_HOST} );
  77     $c->request->protocol( $ENV{SERVER_PROTOCOL} );
  78     $c->request->user( $ENV{REMOTE_USER} );
  79     $c->request->method( $ENV{REQUEST_METHOD} );
  80
  81     if ( $ENV{HTTPS} && uc( $ENV{HTTPS} ) eq 'ON' ) {
  82         $c->request->secure(1);
  83     }
  84
  85     if ( $ENV{SERVER_PORT} == 443 ) {
  86         $c->request->secure(1);
  87     }
  88 }
  89
  90 =item $self->prepare_headers($c)
  91
  92 =cut
  93
  94 sub prepare_headers {
  95     my ( $self, $c ) = @_;
  96     local(*ENV) = $self->env || \%ENV;
  97
  98     # Read headers from %ENV
  99     while ( my ( $header, $value ) = each %ENV ) {
 100         next unless $header =~ /^(?:HTTP|CONTENT|COOKIE)/i;
 101         ( my $field = $header ) =~ s/^HTTPS?_//;
 102         $c->req->headers->header( $field => $value );
 103     }
 104 }
 105
 106 =item $self->prepare_path($c)
 107
 108 =cut
 109
 110 sub prepare_path {
 111     my ( $self, $c ) = @_;
 112     local(*ENV) = $self->env || \%ENV;
 113
 114     my $scheme = $c->request->secure ? 'https' : 'http';
 115     my $host      = $ENV{HTTP_HOST}   || $ENV{SERVER_NAME};
 116     my $port      = $ENV{SERVER_PORT} || 80;
 117     my $base_path = $ENV{SCRIPT_NAME} || '/';
 118
 119     # If we are running as a backend proxy, get the true hostname
 120   PROXY_CHECK:
 121     {
 122         unless ( $c->config->{using_frontend_proxy} ) {
 123             last PROXY_CHECK if $host !~ /localhost|127.0.0.1/;
 124             last PROXY_CHECK if $c->config->{ignore_frontend_proxy};
 125         }
 126         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_HOST};
 127
 128         $host = $ENV{HTTP_X_FORWARDED_HOST};
 129
 130         # backend could be on any port, so
 131         # assume frontend is on the default port
 132         $port = $c->request->secure ? 443 : 80;
 133     }
 134
 135     my $path = $base_path . $ENV{PATH_INFO};
 136     $path =~ s{^/+}{};
 137
 138     my $uri = URI->new;
 139     $uri->scheme($scheme);
 140     $uri->host($host);
 141     $uri->port($port);
 142     $uri->path($path);
 143     $uri->query( $ENV{QUERY_STRING} ) if $ENV{QUERY_STRING};
 144
 145     # sanitize the URI
 146     $uri = $uri->canonical;
 147     $c->request->uri($uri);
 148
 149     # set the base URI
 150     # base must end in a slash
 151     $base_path .= '/' unless ( $base_path =~ /\/$/ );
 152     my $base = $uri->clone;
 153     $base->path_query($base_path);
 154     $c->request->base($base);
 155 }
 156
 157 =item $self->prepare_query_parameters($c)
 158
 159 =cut
 160
 161 sub prepare_query_parameters {
 162     my ( $self, $c ) = @_;
 163     local(*ENV) = $self->env || \%ENV;
 164
 165     if ( $ENV{QUERY_STRING} ) {
 166         $self->SUPER::prepare_query_parameters( $c, $ENV{QUERY_STRING} );
 167     }
 168 }
 169
 170 =item $self->prepare_request($c, (env => \%env))
 171
 172 =cut
 173
 174 sub prepare_request {
 175     my ( $self, $c, %args ) = @_;
 176
 177     if ( $args{env} ) {
 178        $self->env( $args{env} );
 179     }
 180 }
 181
 182 =item $self->prepare_write($c)
 183
 184 Enable autoflush on the output handle for CGI-based engines.
 185
 186 =cut
 187
 188 sub prepare_write {
 189     my ( $self, $c ) = @_;
 190
 191     # Set the output handle to autoflush
 192     *STDOUT->autoflush(1);
 193
 194     $self->NEXT::prepare_write($c);
 195 }
 196
 197 =item $self->read_chunk($c, $buffer, $length)
 198
 199 =cut
 200
 201 sub read_chunk { shift; shift; *STDIN->sysread(@_); }
 202
 203 =item $self->run
 204
 205 =cut
 206
 207 sub run { shift; shift->handle_request(@_) }
 208
 209 =back
 210
 211 =head1 SEE ALSO
 212
 213 L<Catalyst> L<Catalyst::Engine>.
 214
 215 =head1 AUTHORS
 216
 217 Sebastian Riedel, <sri@cpan.org>
 218
 219 Christian Hansen, <ch@ngmedia.com>
 220
 221 Andy Grundman, <andy@hybridized.org>
 222
 223 =head1 COPYRIGHT
 224
 225 This program is free software, you can redistribute it and/or modify it under
 226 the same terms as Perl itself.
 227
 228 =cut
 229
 230 1;