lib/Catalyst/Engine/CGI.pm

   1 package Catalyst::Engine::CGI;
   2
   3 use Moose;
   4 extends 'Catalyst::Engine';
   5
   6 has _header_buf => (is => 'rw', clearer => '_clear_header_buf', predicate => '_has_header_buf');
   7
   8 =head1 NAME
   9
  10 Catalyst::Engine::CGI - The CGI Engine
  11
  12 =head1 SYNOPSIS
  13
  14 A script using the Catalyst::Engine::CGI module might look like:
  15
  16     #!/usr/bin/perl -w
  17
  18     use strict;
  19     use lib '/path/to/MyApp/lib';
  20     use MyApp;
  21
  22     MyApp->run;
  23
  24 The application module (C<MyApp>) would use C<Catalyst>, which loads the
  25 appropriate engine module.
  26
  27 =head1 DESCRIPTION
  28
  29 This is the Catalyst engine specialized for the CGI environment.
  30
  31 =head1 OVERLOADED METHODS
  32
  33 This class overloads some methods from C<Catalyst::Engine>.
  34
  35 =head2 $self->finalize_headers($c)
  36
  37 =cut
  38
  39 sub finalize_headers {
  40     my ( $self, $c ) = @_;
  41
  42     $c->response->header( Status => $c->response->status );
  43
  44     $self->_header_buf($c->response->headers->as_string("\015\012") . "\015\012");
  45 }
  46
  47 =head2 $self->prepare_connection($c)
  48
  49 =cut
  50
  51 sub prepare_connection {
  52     my ( $self, $c ) = @_;
  53     local (*ENV) = $self->env || \%ENV;
  54
  55     my $request = $c->request;
  56     $request->address( $ENV{REMOTE_ADDR} );
  57
  58   PROXY_CHECK:
  59     {
  60         unless ( ref($c)->config->{using_frontend_proxy} ) {
  61             last PROXY_CHECK if $ENV{REMOTE_ADDR} ne '127.0.0.1';
  62             last PROXY_CHECK if ref($c)->config->{ignore_frontend_proxy};
  63         }
  64         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_FOR};
  65
  66         # If we are running as a backend server, the user will always appear
  67         # as 127.0.0.1. Select the most recent upstream IP (last in the list)
  68         my ($ip) = $ENV{HTTP_X_FORWARDED_FOR} =~ /([^,\s]+)$/;
  69         $request->address($ip);
  70         if ( defined $ENV{HTTP_X_FORWARDED_PORT} ) {
  71             $ENV{SERVER_PORT} = $ENV{HTTP_X_FORWARDED_PORT};
  72         }
  73     }
  74
  75     $request->hostname( $ENV{REMOTE_HOST} ) if exists $ENV{REMOTE_HOST};
  76     $request->protocol( $ENV{SERVER_PROTOCOL} );
  77     $request->user( $ENV{REMOTE_USER} );  # XXX: Deprecated. See Catalyst::Request for removal information
  78     $request->remote_user( $ENV{REMOTE_USER} );
  79     $request->method( $ENV{REQUEST_METHOD} );
  80
  81     if ( $ENV{HTTPS} && uc( $ENV{HTTPS} ) eq 'ON' ) {
  82         $request->secure(1);
  83     }
  84
  85     if ( $ENV{SERVER_PORT} == 443 ) {
  86         $request->secure(1);
  87     }
  88     binmode(STDOUT); # Ensure we are sending bytes.
  89 }
  90
  91 =head2 $self->prepare_headers($c)
  92
  93 =cut
  94
  95 sub prepare_headers {
  96     my ( $self, $c ) = @_;
  97     local (*ENV) = $self->env || \%ENV;
  98     my $headers = $c->request->headers;
  99     # Read headers from %ENV
 100     foreach my $header ( keys %ENV ) {
 101         next unless $header =~ /^(?:HTTP|CONTENT|COOKIE)/i;
 102         ( my $field = $header ) =~ s/^HTTPS?_//;
 103         $headers->header( $field => $ENV{$header} );
 104     }
 105 }
 106
 107 =head2 $self->prepare_path($c)
 108
 109 =cut
 110
 111 sub prepare_path {
 112     my ( $self, $c ) = @_;
 113     local (*ENV) = $self->env || \%ENV;
 114
 115     my $scheme = $c->request->secure ? 'https' : 'http';
 116     my $host      = $ENV{HTTP_HOST}   || $ENV{SERVER_NAME};
 117     my $port      = $ENV{SERVER_PORT} || 80;
 118     my $base_path;
 119     if ( exists $ENV{REDIRECT_URL} ) {
 120         $base_path = $ENV{REDIRECT_URL};
 121         $base_path =~ s/$ENV{PATH_INFO}$//;
 122     }
 123     else {
 124         $base_path = $ENV{SCRIPT_NAME} || '/';
 125     }
 126
 127     # If we are running as a backend proxy, get the true hostname
 128   PROXY_CHECK:
 129     {
 130         unless ( ref($c)->config->{using_frontend_proxy} ) {
 131             last PROXY_CHECK if $host !~ /localhost|127.0.0.1/;
 132             last PROXY_CHECK if ref($c)->config->{ignore_frontend_proxy};
 133         }
 134         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_HOST};
 135
 136         $host = $ENV{HTTP_X_FORWARDED_HOST};
 137
 138         # backend could be on any port, so
 139         # assume frontend is on the default port
 140         $port = $c->request->secure ? 443 : 80;
 141         if ( $ENV{HTTP_X_FORWARDED_PORT} ) {
 142             $port = $ENV{HTTP_X_FORWARDED_PORT};
 143         }
 144     }
 145
 146     # set the request URI
 147     my $path = $base_path . ( $ENV{PATH_INFO} || '' );
 148     $path =~ s{^/+}{};
 149
 150     # Using URI directly is way too slow, so we construct the URLs manually
 151     my $uri_class = "URI::$scheme";
 152
 153     # HTTP_HOST will include the port even if it's 80/443
 154     $host =~ s/:(?:80|443)$//;
 155
 156     if ( $port !~ /^(?:80|443)$/ && $host !~ /:/ ) {
 157         $host .= ":$port";
 158     }
 159
 160     # Escape the path
 161     $path =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
 162     $path =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 163
 164     my $query = $ENV{QUERY_STRING} ? '?' . $ENV{QUERY_STRING} : '';
 165     my $uri   = $scheme . '://' . $host . '/' . $path . $query;
 166
 167     $c->request->uri( bless \$uri, $uri_class );
 168
 169     # set the base URI
 170     # base must end in a slash
 171     $base_path .= '/' unless $base_path =~ m{/$};
 172
 173     my $base_uri = $scheme . '://' . $host . $base_path;
 174
 175     $c->request->base( bless \$base_uri, $uri_class );
 176 }
 177
 178 =head2 $self->prepare_query_parameters($c)
 179
 180 =cut
 181
 182 around prepare_query_parameters => sub {
 183     my $orig = shift;
 184     my ( $self, $c ) = @_;
 185     local (*ENV) = $self->env || \%ENV;
 186
 187     if ( $ENV{QUERY_STRING} ) {
 188         $self->$orig( $c, $ENV{QUERY_STRING} );
 189     }
 190 };
 191
 192 =head2 $self->prepare_request($c, (env => \%env))
 193
 194 =cut
 195
 196 sub prepare_request {
 197     my ( $self, $c, %args ) = @_;
 198
 199     if ( $args{env} ) {
 200         $self->env( $args{env} );
 201     }
 202 }
 203
 204 =head2 $self->prepare_write($c)
 205
 206 Enable autoflush on the output handle for CGI-based engines.
 207
 208 =cut
 209
 210 around prepare_write => sub {
 211     *STDOUT->autoflush(1);
 212     return shift->(@_);
 213 };
 214
 215 =head2 $self->write($c, $buffer)
 216
 217 Writes the buffer to the client.
 218
 219 =cut
 220
 221 around write => sub {
 222     my $orig = shift;
 223     my ( $self, $c, $buffer ) = @_;
 224
 225     # Prepend the headers if they have not yet been sent
 226     if ( $self->_has_header_buf ) {
 227         $buffer = $self->_clear_header_buf . $buffer;
 228     }
 229
 230     return $self->$orig( $c, $buffer );
 231 };
 232
 233 =head2 $self->read_chunk($c, $buffer, $length)
 234
 235 =cut
 236
 237 sub read_chunk { shift; shift; *STDIN->sysread(@_); }
 238
 239 =head2 $self->run
 240
 241 =cut
 242
 243 sub run { shift; shift->handle_request( env => \%ENV ) }
 244
 245 =head1 SEE ALSO
 246
 247 L<Catalyst>, L<Catalyst::Engine>
 248
 249 =head1 AUTHORS
 250
 251 Catalyst Contributors, see Catalyst.pm
 252
 253 =head1 COPYRIGHT
 254
 255 This library is free software. You can redistribute it and/or modify it under
 256 the same terms as Perl itself.
 257
 258 =cut
 259 no Moose;
 260
 261 1;