lib/Catalyst/Engine/CGI.pm

   1 package Catalyst::Engine::CGI;
   2
   3 use strict;
   4 use base 'Catalyst::Engine';
   5 use NEXT;
   6
   7 __PACKAGE__->mk_accessors('env');
   8
   9 =head1 NAME
  10
  11 Catalyst::Engine::CGI - The CGI Engine
  12
  13 =head1 SYNOPSIS
  14
  15 A script using the Catalyst::Engine::CGI module might look like:
  16
  17     #!/usr/bin/perl -w
  18
  19     use strict;
  20     use lib '/path/to/MyApp/lib';
  21     use MyApp;
  22
  23     MyApp->run;
  24
  25 The application module (C<MyApp>) would use C<Catalyst>, which loads the
  26 appropriate engine module.
  27
  28 =head1 DESCRIPTION
  29
  30 This is the Catalyst engine specialized for the CGI environment.
  31
  32 =head1 OVERLOADED METHODS
  33
  34 This class overloads some methods from C<Catalyst::Engine>.
  35
  36 =head2 $self->finalize_headers($c)
  37
  38 =cut
  39
  40 sub finalize_headers {
  41     my ( $self, $c ) = @_;
  42
  43     $c->response->header( Status => $c->response->status );
  44
  45     $self->{_header_buf}
  46         = $c->response->headers->as_string("\015\012") . "\015\012";
  47 }
  48
  49 =head2 $self->prepare_connection($c)
  50
  51 =cut
  52
  53 sub prepare_connection {
  54     my ( $self, $c ) = @_;
  55     local (*ENV) = $self->env || \%ENV;
  56
  57     $c->request->address( $ENV{REMOTE_ADDR} );
  58
  59   PROXY_CHECK:
  60     {
  61         unless ( $c->config->{using_frontend_proxy} ) {
  62             last PROXY_CHECK if $ENV{REMOTE_ADDR} ne '127.0.0.1';
  63             last PROXY_CHECK if $c->config->{ignore_frontend_proxy};
  64         }
  65         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_FOR};
  66
  67         # If we are running as a backend server, the user will always appear
  68         # as 127.0.0.1. Select the most recent upstream IP (last in the list)
  69         my ($ip) = $ENV{HTTP_X_FORWARDED_FOR} =~ /([^,\s]+)$/;
  70         $c->request->address($ip);
  71     }
  72
  73     $c->request->hostname( $ENV{REMOTE_HOST} );
  74     $c->request->protocol( $ENV{SERVER_PROTOCOL} );
  75     $c->request->user( $ENV{REMOTE_USER} );
  76     $c->request->method( $ENV{REQUEST_METHOD} );
  77
  78     if ( $ENV{HTTPS} && uc( $ENV{HTTPS} ) eq 'ON' ) {
  79         $c->request->secure(1);
  80     }
  81
  82     if ( $ENV{SERVER_PORT} == 443 ) {
  83         $c->request->secure(1);
  84     }
  85 }
  86
  87 =head2 $self->prepare_headers($c)
  88
  89 =cut
  90
  91 sub prepare_headers {
  92     my ( $self, $c ) = @_;
  93     local (*ENV) = $self->env || \%ENV;
  94
  95     # Read headers from %ENV
  96     foreach my $header ( keys %ENV ) {
  97         next unless $header =~ /^(?:HTTP|CONTENT|COOKIE)/i;
  98         ( my $field = $header ) =~ s/^HTTPS?_//;
  99         $c->req->headers->header( $field => $ENV{$header} );
 100     }
 101 }
 102
 103 =head2 $self->prepare_path($c)
 104
 105 =cut
 106
 107 sub prepare_path {
 108     my ( $self, $c ) = @_;
 109     local (*ENV) = $self->env || \%ENV;
 110
 111     my $scheme = $c->request->secure ? 'https' : 'http';
 112     my $host      = $ENV{HTTP_HOST}   || $ENV{SERVER_NAME};
 113     my $port      = $ENV{SERVER_PORT} || 80;
 114     my $base_path;
 115     if ( exists $ENV{REDIRECT_URL} ) {
 116         $base_path = $ENV{REDIRECT_URL};
 117         $base_path =~ s/$ENV{PATH_INFO}$//;
 118     }
 119     else {
 120         $base_path = $ENV{SCRIPT_NAME} || '/';
 121     }
 122
 123     # If we are running as a backend proxy, get the true hostname
 124   PROXY_CHECK:
 125     {
 126         unless ( $c->config->{using_frontend_proxy} ) {
 127             last PROXY_CHECK if $host !~ /localhost|127.0.0.1/;
 128             last PROXY_CHECK if $c->config->{ignore_frontend_proxy};
 129         }
 130         last PROXY_CHECK unless $ENV{HTTP_X_FORWARDED_HOST};
 131
 132         $host = $ENV{HTTP_X_FORWARDED_HOST};
 133
 134         # backend could be on any port, so
 135         # assume frontend is on the default port
 136         $port = $c->request->secure ? 443 : 80;
 137     }
 138
 139     # set the request URI
 140     my $path = $base_path . ( $ENV{PATH_INFO} || '' );
 141     $path =~ s{^/+}{};
 142
 143     # Using URI directly is way too slow, so we construct the URLs manually
 144     my $uri_class = "URI::$scheme";
 145
 146     # HTTP_HOST will include the port even if it's 80/443
 147     $host =~ s/:(?:80|443)$//;
 148
 149     if ( $port !~ /^(?:80|443)$/ && $host !~ /:/ ) {
 150         $host .= ":$port";
 151     }
 152
 153     # Escape the path
 154     $path =~ s/([^$URI::uric])/$URI::Escape::escapes{$1}/go;
 155     $path =~ s/\?/%3F/g; # STUPID STUPID SPECIAL CASE
 156
 157     my $query = $ENV{QUERY_STRING} ? '?' . $ENV{QUERY_STRING} : '';
 158     my $uri   = $scheme . '://' . $host . '/' . $path . $query;
 159
 160     $c->request->uri( bless \$uri, $uri_class );
 161
 162     # set the base URI
 163     # base must end in a slash
 164     $base_path .= '/' unless $base_path =~ m{/$};
 165
 166     my $base_uri = $scheme . '://' . $host . $base_path;
 167
 168     $c->request->base( bless \$base_uri, $uri_class );
 169 }
 170
 171 =head2 $self->prepare_query_parameters($c)
 172
 173 =cut
 174
 175 sub prepare_query_parameters {
 176     my ( $self, $c ) = @_;
 177     local (*ENV) = $self->env || \%ENV;
 178
 179     if ( $ENV{QUERY_STRING} ) {
 180         $self->SUPER::prepare_query_parameters( $c, $ENV{QUERY_STRING} );
 181     }
 182 }
 183
 184 =head2 $self->prepare_request($c, (env => \%env))
 185
 186 =cut
 187
 188 sub prepare_request {
 189     my ( $self, $c, %args ) = @_;
 190
 191     if ( $args{env} ) {
 192         $self->env( $args{env} );
 193     }
 194 }
 195
 196 =head2 $self->prepare_write($c)
 197
 198 Enable autoflush on the output handle for CGI-based engines.
 199
 200 =cut
 201
 202 sub prepare_write {
 203     my ( $self, $c ) = @_;
 204
 205     # Set the output handle to autoflush
 206     *STDOUT->autoflush(1);
 207
 208     $self->NEXT::prepare_write($c);
 209 }
 210
 211 =head2 $self->write($c, $buffer)
 212
 213 Writes the buffer to the client.
 214
 215 =cut
 216
 217 sub write {
 218     my ( $self, $c, $buffer ) = @_;
 219
 220     # Prepend the headers if they have not yet been sent
 221     if ( my $headers = delete $self->{_header_buf} ) {
 222         $buffer = $headers . $buffer;
 223     }
 224
 225     return $self->NEXT::write( $c, $buffer );
 226 }
 227
 228 =head2 $self->read_chunk($c, $buffer, $length)
 229
 230 =cut
 231
 232 sub read_chunk { shift; shift; *STDIN->sysread(@_); }
 233
 234 =head2 $self->run
 235
 236 =cut
 237
 238 sub run { shift; shift->handle_request(@_) }
 239
 240 =head1 SEE ALSO
 241
 242 L<Catalyst> L<Catalyst::Engine>.
 243
 244 =head1 AUTHORS
 245
 246 Sebastian Riedel, <sri@cpan.org>
 247
 248 Christian Hansen, <ch@ngmedia.com>
 249
 250 Andy Grundman, <andy@hybridized.org>
 251
 252 =head1 COPYRIGHT
 253
 254 This program is free software, you can redistribute it and/or modify it under
 255 the same terms as Perl itself.
 256
 257 =cut
 258
 259 1;